Как разделить вектор на разделитель

Question

У меня есть вектор, который содержит числа. Структура вектора следующая:

1. предметы произвольной длины
2. разделитель [0 0 0 0 0] (0 повторяется 5 раз) между элементами

Я хочу написать функцию split который извлекает список элементов (без разделителя): он похож на строку / разделение.

Например:

(split [123 0 1 0 0 0 0 0 1 1 0 0 0 0 0 1 0 1 0 0 0 0 0 0 0 1 199])
; => [[123 0 1] [1 1] [1 0 1] [0 0 1 199]]

Примечание: код должен быть эффективным, поскольку длина вектора составляет около 1 миллиона.

Спасибо за вашу помощь.

Answer 1

Вот:

(defn the-split [coll] 
  (let [part   (partition-by identity coll)
        ppart  (partition-by #(= [0 0 0 0 0] %) part)
        almost (map #(apply concat %) ppart)]
    (filter (partial not= [0 0 0 0 0]) almost)))


(the-split [123 0 1 0 0 0 0 0 1 1 0 0 0 0 0 1 0 1 0 0 0 0 0 1 199])
=> ((123 0 1) (1 1) (1 0 1) (1 199))

Answer 2

Вот один подход - с [0 0 0 0 0] разделитель встроен, но прост для обобщения:

(defn split5z [xs]
  (let [delim [0 0 0 0 0]
        step (fn step [xs seg]
               (lazy-seq
                (if-let [xs (seq xs)]
                  (let [window (take 5 xs)]
                    (if (= window delim)
                      (cons seg (step (drop 5 xs) []))
                      (step (rest xs) (conj seg (first xs)))))
                  (list seg))))]
    (step xs [])))

Применяя его к вашему примеру ввода:

(split5z [123 0 1 0 0 0 0 0 1 1 0 0 0 0 0 1 0 1 0 0 0 0 0 1 199])
;= ([123 0 1] [1 1] [1 0 1] [1 199])

Завернуть в vec если вы хотите, чтобы вывод был вектором, а не последовательностью векторов.

Другой подход - на этот раз нетерпеливо потребляя вход с loop/recur:

(defn split5z [sep xs]
  (let [scnt (count sep)]
    (loop [xs  (seq xs)
           out []
           seg []]
      (if xs
        (if (= (take scnt xs) sep)
          (recur (nthnext xs scnt)
                 (conj out seg)
                 [])
          (recur (next xs)
                 out
                 (conj seg (first xs))))
        (if (seq seg)
          (conj out seg)
          seg)))))

На REPL:

(split5z [0 0 0 0 0]
         [123 0 1 0 0 0 0 0 1 1 0 0 0 0 0 1 0 1 0 0 0 0 0 1 199])
;= [[123 0 1] [1 1] [1 0 1] [1 199]]

Answer 3

Ленивое решение:

(defn split [v]
  (let [delim (repeat 5 0)
        i (->> v (partition 5 1) (take-while #(not= delim %)) count)]
    (if (zero? i) [v] (lazy-seq (cons (subvec v 0 i)
                                      (split (subvec v (+ i 5))))))))

Например

(split [123 0 1 0 0 0 0 0 1 1 0 0 0 0 0 1 0 1 0 0 0 0 0 0 0 1 199])
; ([123 0 1] [1 1] [1 0 1] [0 0 1 199])