VBS для запуска пользовательского окна Firefox и URL

Question

Я разработал некоторый скрипт для запуска переносной версии Firefox с URL-адресом, связанным с веб-камерами. Моя цель - иметь 2 скрипта, использующих один и тот же FF.exe, но использующих 2 разных URL /IP. Я пытаюсь ограничить функцию браузера, удалив скролл бары.меню и статус, чтобы можно было видеть только элементы управления и вид веб-камеры.

Это текущий код, но я, кажется, допустил ошибку, так как теперь URL не отображается, только по умолчанию при запуске. Размер идеален.

dim wshshell

FirefoxProfile = "Profile"
FirefoxPath = "C:\ADMIN\FF\FF.exe"
webappurl = "http://Domain.com"
Height = "870"
Width = "920"

Set wshshell = WScript.CreateObject("WScript.Shell")

wshshell.run """" & FirefoxPath & """ -P """ & FirefoxProfile & """ -Height """ & Height & """ -Width """ & Width & "" & webappurl

Set wshshell = Nothing
wscript.quit

Любая помощь, которую вы можете оказать, или просто толчок в правильном направлении, была бы очень ценной. Это еще кое-что, что я нашел, так что, может быть, это можно использовать, к сожалению, я не думаю, что само по себе это какое-либо применение.

window.open('Domain.com',null,"height=100px,width=100px,status=0,toolbar=0,menubar=0,location=0");

Рабочий код:

dim wshshell

Function qq(str)
qq = Chr(34) & str & Chr(34)
End Function

FirefoxProfile = "Profile"
FirefoxPath = "C:\ADMIN\FF\FF.exe"
webappurl = "172.22.111.8"
Height = "700"
Width = "920"
Status ="0"
Toolbar = "0"
Menubar = "0"

Set wshshell = WScript.CreateObject("WScript.Shell")

wshshell.run qq(FirefoxPath) & " -P " & qq(FirefoxProfile) _
& " -status " & qq(status) & " -Toolbar " & qq(toolbar) & " -menubar " & qq(menubar) _
& " -Height " & qq(Height) & " -Width " & qq(Width) _
& " " & webappurl

Set wshshell = Nothing
wscript.quit

Answer 1

Я подозреваю, что ваша проблема лежит здесь:

wshshell.run ... & """ -Width """ & Width & "" & webappurl

Последний "" в этой инструкции просто пустая строка, когда вам, вероятно, нужна закрывающая двойная кавычка, за которой следует пробел:

wshshell.run ... & """ -Width """ & Width & """ " & webappurl

Я обычно рекомендую использовать функцию цитирования, чтобы избежать цитирования:

Function qq(str)
  qq = Chr(34) & str & Chr(34)
End Function

'...

wshshell.run qq(FirefoxPath) & " -P " & qq(FirefoxProfile) _
  & " -Height " & qq(Height) & " -Width " & qq(Width) _
  & " " & webappurl