Как вы можете запускать исполняемые файлы других правил в правиле Bazel?

Question

Скажем, у меня есть собственное правило, my_object. Это выглядит как:

my_object(
  name = "foo",
  deps = [
    //services/image-A:push,
    //services/image-B:push,
  ]
)

Где ярлыки в deps находятся rules_dockerс container_push правила.

Я хочу иметь возможность bazel run //:foo и пусть он помещает образы Docker в depsсписок. Как мне это сделать?

Похоже, что это частный случай простого желания запускать исполняемые файлы других правил внутри исполняемого файла настраиваемого правила.

Answer 1

Здесь нужно иметь my_object вывести исполняемый файл, который выполняет другие исполняемые файлы.

Рассмотрим этот пример:

def _impl1(ctx):
  ctx.actions.write(
    output = ctx.outputs.executable,
    is_executable = True,
    content = "echo %s 123" % ctx.label.name)
  return DefaultInfo(executable = ctx.outputs.executable)


exec_rule1 = rule(
  implementation = _impl1,
  executable = True,
)


def _impl2(ctx):

  executable_paths = []
  runfiles = ctx.runfiles()
  for dep in ctx.attr.deps:
    # the "./" is needed if the executable is in the current directory
    # (i.e. in the workspace root)
    executable_paths.append("./" + dep.files_to_run.executable.short_path)
    # collect the runfiles of the other executables so their own runfiles
    # will be available when the top-level executable runs
    runfiles = runfiles.merge(dep.default_runfiles)

  ctx.actions.write(
    output = ctx.outputs.executable,
    is_executable = True,
    content = "\n".join(executable_paths))

  return DefaultInfo(
    executable = ctx.outputs.executable,
    runfiles = runfiles)


exec_rule2 = rule(
  implementation = _impl2,
  executable = True,
  attrs = {
    "deps": attr.label_list(),
  },
)

BUILD.bazel:

load(":defs.bzl", "exec_rule1", "exec_rule2")

exec_rule1(name = "foo")
exec_rule1(name = "bar")
exec_rule2(name = "baz", deps = [":foo", ":bar"])

а затем запустите его:

$ bazel run //:baz
INFO: Analyzed target //:baz (4 packages loaded, 19 targets configured).
INFO: Found 1 target...
Target //:baz up-to-date:
  bazel-bin/baz
INFO: Elapsed time: 0.211s, Critical Path: 0.01s
INFO: 0 processes.
INFO: Build completed successfully, 6 total actions
INFO: Build completed successfully, 6 total actions
foo 123
bar 123

Answer 2

Мне удалось добиться этого, внедривDefaultInfoв правиле.

      def build_all_impl(ctx):
    targets = ctx.attr.targets
    run_files = []
    for target in targets:
        run_files = run_files + target.files.to_list()
    DefaultInfo(
        runfiles = ctx.runfiles(run_files),
    )

build_all = rule(
    implementation = build_all_impl,
    attrs = {
        "targets": attr.label_list(
            doc = "target to build",
        ),
    },
)

А затем, запустив правило build_all

      build_all(
    name = "all",
    targets = [
        ":target-1",
        ":target-2",
        ...
    ],
)