Доступ к __DATA__ из суперкласса

Question

У меня есть супер класс под названием Response:

package Response;

use strict;
use warnings;

use HTML::Template;

sub response {
    my ( $class, $request ) = @_;
    return $request->new_response( $class->status, $class->headers, $class->body );
}

sub body {
    my $class = shift;
    my $template = HTML::Template->new( 'filehandle' => eval("$class::DATA") );
    return $template->output() . $class;
}

sub status {
    return 200;
}

sub headers {
    return [ 'Content-Type' => 'text/html' ];
}

1;

__DATA__
Default content

и подкласс под названием URIError:

package URIError;

use strict;
use warnings;

use Response;
our @ISA = qw(Response);

1;

__DATA__
Invalid URI

Когда вызывается URIError->response, строка

my $template = HTML::Template->new( 'filehandle' => eval("$class::DATA") );

в классе Response не принимает содержимое раздела DATA из класса URIError.

Какой синтаксис для этого?

Answer 1

Ваш код будет работать, если вы измените body метод, как это. Там нет необходимости eval: все, что вам нужно сделать, это отключить strict 'refs' и разыменовывать строку "${class}::DATA"

sub body {
   my $class = shift;

   my $data_fh = do {
      no strict 'refs';
      *{"${class}::DATA"};
   };

   my $template = HTML::Template->new( filehandle => $data_fh );

   $template->output . $class;
}