Значения по умолчанию / заменяемые в Bread::Board

Question

Я обнаружил, что создаю экземпляры одних и тех же объектов в многочисленных тестах, поэтому я пытаюсь заменить эту константу с помощью Bread:: Board. Большую часть времени я хочу, чтобы зависимости имели одинаковую конфигурацию. Но иногда я могу захотеть создать экземпляр с параметрами, которые не являются параметрами по умолчанию. Я также хотел бы иметь возможность изменить это после того, как я создал экземпляр контейнера. например, я бы обычно хотел

my $c = Test::Container->new;

my $bar = $c->resolve( service => 'bar' ); # where bar depends on foo

но иногда то, что мне действительно нужно, это что-то вроде

my $bar = $c->resolve( service => 'bar', {
              services => {
                foo => { init => 'arg' }
              }
          }

так что служба foo инициализируется по-разному при создании экземпляра bar.

Answer 1

Это было предоставлено мне Джесси Люрсом (Дой) на #moose и похоже, что оно будет делать то, что я хочу.

#!/usr/bin/env perl
use v5.14;
use strict;
use warnings;

package Container {
use Moose;
use Bread::Board;

extends 'Bread::Board::Container';

has '+name' => (default => 'Container');

sub BUILD {
    my $self = shift;
    container $self => as {
        service foo => (
            block => sub {
                my $s = shift;
                $s->param('foo_val');
            },
            parameters => {
                foo_val => { isa => 'Str' },
            },
        );
        service bar => (
            block => sub {
                my $s = shift;
                $s->param('foo')->inflate(foo_val => $s->param('foo_val')) . 'BAR';
            },
            dependencies => ['foo'],
            parameters => {
                foo_val => { isa => 'Str', default => 'FOO' },
            },
        );
    };
}
}

my $c = Container->new;
warn $c->resolve(service => 'bar');
warn $c->resolve(service => 'bar', parameters => { foo_val => 'baz' });