Ошибка при создании ответа интеграции шлюза API: NotFoundException: указан недопустимый идентификатор интеграции

Question

Задача

Решение или обходной путь проблемы.

Проблема

Интеграция Terraform API Gateway с Firehose ниже работает, если Firehose заранее создан отдельно.

resource "aws_api_gateway_integration" "click_put" {
  rest_api_id = data.aws_api_gateway_rest_api.mysfit.id
  resource_id = aws_api_gateway_resource.click.id
  type        = "AWS"
  uri         = "arn:aws:apigateway:${var.REGION}:firehose:action/PutRecord"
  credentials = aws_iam_role.api_click.arn

  http_method = aws_api_gateway_method.click_put.http_method
  integration_http_method = "POST"
  request_parameters = {
    "integration.request.header.Content-Type" = "'application/x-amz-json-1.1'"
  }
  passthrough_behavior = "NEVER"
  request_templates = {
    "application/json" = <<EOF
{
  "DeliveryStreamName": "${local.firehose_name}",
  "Record": {
    "Data": "$util.base64Encode($input.json('$'))"
  }
}
EOF
  }
}
...
resource "aws_api_gateway_integration_response" "click_put" {
  rest_api_id = data.aws_api_gateway_rest_api.mysfit.id
  resource_id = aws_api_gateway_resource.click.id
  http_method = aws_api_gateway_method.click_put.http_method
  status_code = aws_api_gateway_method_response.click_put.status_code
  response_parameters = {
    "method.response.header.Access-Control-Allow-Origin" = "'*'"
  }
}

Однако, если они созданы в одном корневом модуле, это вызывает ошибку.

Error creating API Gateway Integration Response: NotFoundException: Invalid Integration identifier specified

  on api_click.tf line 185, in resource "aws_api_gateway_integration_response" "click_put":
 185: resource "aws_api_gateway_integration_response" "click_put" {

Answer 1

Обходной путь / решение

Установите зависимость от aws_api_gateway_integration из ресурса, вызывающего "NotFoundException: указан недопустимый идентификатор интеграции".

resource "aws_api_gateway_integration_response" "click_put" {
  rest_api_id = data.aws_api_gateway_rest_api.mysfit.id
  resource_id = aws_api_gateway_resource.click.id
  http_method = aws_api_gateway_method.click_put.http_method
  status_code = aws_api_gateway_method_response.click_put.status_code
  response_parameters = {
    "method.response.header.Access-Control-Allow-Origin" = "'*'"
  }

  depends_on = [
    aws_api_gateway_integration.click_put
  ]
}

Ссылки

Есть указания на то, что " зависит_на aws_api_gateway_integration" или "ожидание" будет подходящим вариантом.

Вероятно, рекомендуется дождаться полного завершения ресурса aws_api_gateway_integration.

• https://www.terraform.io/docs/providers/aws/r/api_gateway_integration_response.html

  Примечание: зависит от наличия aws_api_gateway_integration в вашем rest api. Чтобы гарантировать это, вам может потребоваться добавить явное значение depends_on для чистых прогонов.

• Проблема интеграции шлюза API - Указан недопустимый идентификатор метода Ошибка № 4001

  Я использую следующий обходной путь для решения аналогичной проблемы. Я получаю ошибку идентификатора недопустимого метода при первом запуске, когда все ресурсы создаются во время одного применения. Создан прокси API для Lambda:

resource "aws_api_gateway_resource" "proxy" {
  rest_api_id = aws_api_gateway_rest_api.rest-api.id
  parent_id   = aws_api_gateway_rest_api.rest-api.root_resource_id
  path_part   = "{proxy+}"
}

resource "null_resource" "method-delay" {
  provisioner "local-exec" {
    command = "sleep 5"
  }
  triggers = {
    response = aws_api_gateway_resource.proxy.id
  }
}

resource "aws_api_gateway_method_response" "response" {
  depends_on = [null_resource.method-delay]
  http_method = "ANY"
  resource_id = aws_api_gateway_resource.proxy.id
  rest_api_id = aws_api_gateway_rest_api.rest-api.id
}

Answer 2

Вы можете просто добавить depends_on. Должно быть что-то вроде:

resource "aws_api_gateway_integration" "create-oauth-lambda" {
  rest_api_id             = aws_api_gateway_rest_api.create-oauth-token-api-gw.id
  resource_id             = aws_api_gateway_resource.auth-token-resource.id
  http_method             = aws_api_gateway_method.method.http_method
  integration_http_method = "POST"
  type                    = "AWS_PROXY"
  uri                     = "some URI"

}

resource "aws_api_gateway_method_response" "response-200" {
  depends_on  = [aws_api_gateway_integration.create-oauth-lambda]
  rest_api_id = aws_api_gateway_rest_api.create-oauth-token-api-gw.id
  resource_id = aws_api_gateway_resource.auth-token-resource.id
  http_method = aws_api_gateway_method.method.http_method
  status_code = "200"
  response_models = {
    "application/json" = "Empty"
  }
}