Могу ли я загрузить общие правила из файла .bzl?

Question

Нам часто нужны общие комбинации правил для каждого стека технологий. В настоящее время это занимает много места в WORKSPACE - и они должны синхронизироваться в нескольких репозиториях. Это 50+ строк после сборщика и содержит слишком много URL-адресов, версий и хешей.

Теперь предположим, что у меня есть репозиторий "стек технологий", и я сделаю что-то вроде

load("@techstack_repo//mylang.bzl", "load_rules")
load_rules()

где load_rules загрузит и инициализирует закрепленные версии, например, rules_go, bazel-gazelle, rules_docker, rules_proto, и инициализирует их все в правильном порядке, чтобы они были видны в WORKSPACE?

Я не смог заставить это работать в моих тестах, потому что load очевидно, не может быть запущен в функции в файле bzl - это не сама функция.

Есть ли способ сделать это?

Вот пример того, что я тестировал для Java:

load("@io_bazel_rules_docker//repositories:repositories.bzl", container_repositories = "repositories")
load("@io_bazel_rules_docker//repositories:deps.bzl", container_deps = "deps")
load("@io_bazel_rules_docker//container:container.bzl", "container_pull")
load("@rules_proto//proto:repositories.bzl", "rules_proto_dependencies", "rules_proto_toolchains")
load(
    "@io_grpc_grpc_java//:repositories.bzl",
    "IO_GRPC_GRPC_JAVA_ARTIFACTS",
    "IO_GRPC_GRPC_JAVA_OVERRIDE_TARGETS",
    "grpc_java_repositories",
)
load("@rules_jvm_external//:defs.bzl", "maven_install")

def prepare_stack(maven_deps = []):
    container_repositories()
    container_deps()
    container_pull(
        name = "java_base",
        # https://console.cloud.google.com/gcr/images/distroless/GLOBAL/java-debian10
        # tag = "11", # OpenJDK 11 as of 2020-03-04
        digest = "sha256:eda9e5ae2facccc9c7016f0c2d718d2ee352743bda81234783b64aaa402679b6",
        registry = "gcr.io",
        repository = "distroless/java-debian10",
    )
    rules_proto_dependencies()
    rules_proto_toolchains()
    maven_install(
        artifacts = maven_deps + IO_GRPC_GRPC_JAVA_ARTIFACTS,
        # for improved debugging in IDE
        fetch_sources = True,
        generate_compat_repositories = True,
        override_targets = IO_GRPC_GRPC_JAVA_OVERRIDE_TARGETS,
        repositories = [
            "https://repo.maven.apache.org/maven2/",
            "https://repo1.maven.org/maven2",
        ],
        strict_visibility = True,
    )
    grpc_java_repositories()

... все http_archive запросы на репо правила находятся в WORKSPACEи я хочу переместить их сюда, но это совсем не сработало. Как есть, я получаю эту ошибку:

ERROR: Failed to load Starlark extension '@rules_python//python:pip.bzl'.
Cycle in the workspace file detected. This indicates that a repository is used prior to being defined.
The following chain of repository dependencies lead to the missing definition.
 - @rules_python
This could either mean you have to add the '@rules_python' repository with a statement like `http_archive` in your WORKSPACE file (note that transitive dependencies are not added automatically), or move an existing definition earlier in your WORKSPACE file.

также добавление rules_python тоже не помогает.

Answer 1

Я нашел решение:

Разделите его на два файла. Один с таким импортом:

load("@bazel_tools//tools/build_defs/repo:git.bzl", "git_repository")
load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")
load("@bazel_tools//tools/build_defs/repo:utils.bzl", "maybe")

def declare():
    maybe(
        git_repository,
        name = "rules_cc",
        commit = "34ca16f4aa4bf2a5d3e4747229202d6cb630ebab",
        remote = "https://github.com/bazelbuild/rules_cc.git",
        shallow_since = "1584036492 -0700",
    )
    # ... for me requires at least rules_cc, rules_python, bazel_skylib
    # for later proto, docker, go, java support

и другой с использованием заявленных внешних источников:

# go
load("@io_bazel_rules_go//go:deps.bzl", "go_register_toolchains", "go_rules_dependencies")
load("@bazel_gazelle//:deps.bzl", "gazelle_dependencies")

# protobuf
load("@rules_proto//proto:repositories.bzl", "rules_proto_dependencies", "rules_proto_toolchains")

# container
load("@io_bazel_rules_docker//container:container.bzl", "container_pull")
load("@io_bazel_rules_docker//repositories:repositories.bzl", container_repositories = "repositories")
load("@io_bazel_rules_docker//repositories:deps.bzl", container_deps = "deps")
load("@io_bazel_rules_docker//go:image.bzl", go_image_repositories = "repositories")

def init_rules():
    go_rules_dependencies()
    go_register_toolchains()
    gazelle_dependencies()
    rules_proto_dependencies()
    rules_proto_toolchains()
    container_repositories()
    container_deps()
    go_image_repositories()
    container_pull(
        name = "go_static",
        digest = "sha256:9b60270ec0991bc4f14bda475e8cae75594d8197d0ae58576ace84694aa75d7a",
        registry = "gcr.io",
        repository = "distroless/static",
    )

Это немного хлопотно, но загрузите это репо с помощью http_archive или git_repository, загрузите первый файл и вызовите declare и загрузите второй для init_rules и назовите это.

Это может быть немного запутанным, но все же помогает унифицировать стек и упростить WORKSPACE.