Как избежать наследования при использовании схемы JAXB?

Question

Я использую аннотации JAXB и плагин schemagen maven для создания xsd. Мне нужно обработать этот xsd с помощью wsdl2py для создания клиента Python. Но поскольку у меня есть наследование в моих классах, schemagen создает что-то вроде этого:

<xs:complexType name="b">
  <xs:complexContent>
    <xs:extension base="a">
      <xs:sequence>
        <xs:element name="field1" type="xs:string"/>
      </xs:sequence>
    </xs:extension>
  </xs:complexContent>
</xs:complexType>

для класса:

class B extends A{
  @XmlElement(required="true")
  private String field1;
}

Проблема в том, что wsdl2py не понимает xs:complexContent и xs:extension. Поэтому я хотел бы создать xsd без этого наследования.

заранее спасибо

Answer 1

Это недостаток wsdl2py а не JAXB, но это так легко исправить, используя XSLT или XQuery. Быстрая попытка исправить это в XSLT:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    <xsl:template match="xsd:complexType[xsd:complexContent/xsd:extension]">

        <xsd:complexType>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates select="xsd:annotation" />

            <xsd:sequence>

                <xsl:variable name="typeQName" select="string(xsd:complexContent/xsd:extension/@base)" />
                <xsl:variable name="typeName"><xsl:choose>
                        <xsl:when test="contains($typeQName, ':')">
                            <xsl:value-of select="substring-after($typeQName, ':')" />
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="$typeQName" />
                        </xsl:otherwise>
                    </xsl:choose></xsl:variable>
                <xsl:comment>Included from <xsl:value-of select="$typeQName" />):
                </xsl:comment>
                <xsl:apply-templates select="//xsd:complexType[@name=$typeName]/*" />
                <xsl:comment>Original extension:</xsl:comment>
                <xsl:apply-templates select="xsd:complexContent/xsd:extension/*" />
            </xsd:sequence>

            <xsl:apply-templates
                select="xsd:attribute | xsd:attributeGroup | xsd:attributeGroup" />
        </xsd:complexType>

    </xsl:template>

    <!-- General copy rule -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

Пара замечаний: это работает только для расширения, а не для ограничений, и использует вложенную последовательность, которая wsdl2py может поддерживать или не поддерживать (должно быть легко исправить). В настоящее время он поддерживает только модель содержимого, но его можно легко расширить для копирования атрибутов и attributeGroups.

Кроме того, таблица стилей работает только тогда, когда расширенный элемент существует в том же файле схемы, что и базовый.

Удачи!