Получите обратный порядок узлов-предков с помощью XQuery/XPath

Question

Я ищу хорошее решение (короткое выражение, лучшая производительность), чтобы получить обратный порядок всех узлов-предков с XQuery 3.1 на BaseX.

Теперь я использую этот код, чтобы получить dirA/dirA3/dirA31 для данного примера XML:

xquery version "3.1" encoding "utf-8";

declare variable $files := 
  <dir name="dirA">
    <file name="fileA_F1"/>
    <file name="fileA_F2"/>
    <dir name="dirA1">
      <file name="fileA1_F1"/>
      <file name="fileA1_F2"/>
    </dir>
    <dir name="dirA2">
      <file name="fileA2_F1"/>
      <file name="fileA2_F2"/>
    </dir>
    <dir name="dirA3">
      <file name="fileA3_F1"/>
      <file name="fileA3_F2"/>
      <file name="fileA3_F3"/>
       <dir name="dirA31">
        <file name="fileA31_F1"/>
        <file name="fileA31_F2"/>
        <file name="fileA31_F3"/>
      </dir>
    </dir>
  </dir>;


let $path := trace(string-join($files//file[@name='fileA31_F2']/ancestor::dir/@name,'/'))

return()

и этот код, чтобы получить обратный порядок dirA31 / dirA3 / dirA:

let $reversepath := trace(string-join(reverse(tokenize(string-join($files//file[@name='fileA31_F2']/ancestor::dir/@name,'/'),'/')),'/'))

Я имею в виду, есть ли другое выражение XPath или XQuery, которое пересекает предков в обратном порядке?

Аннотация: значения атрибутов имени файловых узлов уникальны

Answer 1

Другое предложение:

declare function f:reverse-path($n as node()) {
  if (exists($n/../@name))
  then $n || '/' || f:reverse-path($n/..)
  else @name
};
f:reverse-path($files//file[@name='fileA31_F2'])

или, в более общем смысле, вы запросили функцию, которая просматривает предков в обратном порядке (сначала самый внутренний предок):

declare function f:reverse-ancestors($n as node()) {
  $n ! (., ..!f:reverse-ancestors(.))
};

Answer 2

Используя XPath 3.1 новый синтаксис с =>оператор (https://www.w3.org/TR/xpath-31/)

let $file := $files//file[@name='fileA31_F2']
return 
    $file/ancestor::dir/@name => reverse() => string-join('/')

должен быть более компактным и читаемым, но к нему нужно время, чтобы привыкнуть.

Answer 3

Чтобы подытожить предыдущие ответы полностью или частично. (Большое спасибо авторам!):

xquery version "3.1" encoding "utf-8";

declare namespace f="myfunc";

declare default element namespace "f";

declare variable $files := 
  <dir name="dirA">
    <file name="fileA_F1"/>
    <file name="fileA_F2"/>
    <dir name="dirA1">
      <file name="fileA1_F1"/>
      <file name="fileA1_F2"/>
    </dir>
    <dir name="dirA2">
      <file name="fileA2_F1"/>
      <file name="fileA2_F2"/>
    </dir>
    <dir name="dirA3">
      <file name="fileA3_F1"/>
      <file name="fileA3_F2"/>
      <file name="fileA3_F3"/>
      <dir name="dirA31">
        <file name="fileA31_F1"/>
        <file name="fileA31_F2"/>
        <dir name="dirA311"/>
        <dir name="dirA312">
          <file name="fileA312_F1"/>
          <file name="fileA312_F2"/>
          <file name="fileA312_F3"/>
        </dir>
      </dir>
    </dir>
  </dir>;


declare function f:traverse-ancestors($n as node()) {
    (: do it from the farthest to the nearest ancestor node :)
    f:doItF2N($n),
    (: Using 'Simply map operator' (XQuery 3.0) :)
    $n ! (., ..!f:traverse-ancestors(.)),
    (: do it from the nearest to the farthest ancestor node :)
    f:doItN2F($n)
};

declare function f:doItF2N($n as node()) {
  trace($n!@name)
};

declare function f:doItN2F($n as node()) {
  trace($n!@name)
};

(: Examples :)

let $childNode := $files//dir[file!@name='fileA312_F3']

(: Ex.1 :)
(: traverse ancestors 'normally' or in reverse order  :)

let $x := f:traverse-ancestors($childNode)

(: Ex.2 - Concatenation of the ancestors name attribute in reverse order, using '/' as separator :)

(: Solution with "=>" - "Arrow operator" (XPath 3.1) :)

let $x := trace($childNode/ancestor::dir/@name => reverse() => string-join('/'))

(: Solution with nested function calls (XPath 3.0) :)

let $x := trace(string-join(reverse($childNode/ancestor::dir/@name),'/'))

let $res := ()

return($res)

Оценивает в BaseX v9.2.4:

name="dirA312"
name="dirA31"
name="dirA3"
name="dirA"
name="dirA"
name="dirA3"
name="dirA31"
name="dirA312"
"dirA31/dirA3/dirA"
"dirA31/dirA3/dirA"