Номер преобразования XSLT 1.0, заключенный в скобки в строке

Question

Я пытаюсь преобразовать строки заполнителей, которые выглядят так:

<param>Hello {0}</param>

выводить

Hello <%- {0} ->

<ini>
    <params>
        <param name=hello">Hello {0}</param>
    </params>
</ini>

Какие-либо предложения?

Answer 1

Я забыл опубликовать свое решение, на случай, если кто-нибудь столкнется с этим. В итоге я изменил определение моих заполнителей на {%token%}.

<xsl:template name="tokenReplacer">
    <xsl:param name="strToConvert" />
    <xsl:variable name="after" select="substring-after($strToConvert,'{%')"/>
    <xsl:choose>
        <xsl:when test="contains($after,'%}')">
            <xsl:value-of select="substring-before($strToConvert, '{%')" />
            <xsl:text>&lt;%=</xsl:text>
            <xsl:value-of select="substring-before($after,'%}')"/>
            <xsl:text>%&gt;</xsl:text>
            <xsl:call-template name="tokenReplacer">
                <xsl:with-param name="strToConvert" select="substring-after($after,'%}')"/>
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$strToConvert"/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 2

Это следует делать, если есть только один токен, в противном случае он становится намного жестче.

<xsl:template match="param">
  <xsl:value-of select="substring-before(.,'{')"/>
  <xsl:text>&lt;%- </xsl:text>
  <xsl:value-of select="substring-after(substring-before(.,'}'),'{')"/>
  <xsl:text> -&gt;</xsl:text>
  <xsl:value-of select="substring-after(.,'}')"/>
</xsl:template>