TChromium: GetSourceProc и несовместимые типы: "обычная процедура и указатель метода"

Question

Мне нужно получить исходный HTML-код со страницы, загруженной в TChromium, но мне нужно хранить исходный код в переменной другого класса. Другими словами, функция обратного вызова должна быть внутри другого класса, и я не могу сделать это, потому что это исключение:

E2009 Несовместимые типы: "обычная процедура и указатель метода"

Вот мой код Работает только в том случае, если функция StringVisitor находится вне класса Form1.

Есть идеи?

unit simple1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, cefvcl, ceflib;

type
  TForm1 = class(TForm)
    Chromium1: TChromium;
    procedure FormCreate(Sender: TObject);
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
      httpStatusCode: Integer);
  public
  mySource : string;
  procedure StringVisitor(const str: ustring);
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;
  httpStatusCode: Integer);
begin
  Chromium1.Browser.MainFrame.GetSourceProc(StringVisitor);  // error on this line
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
chromium1.load('http://www.google.com');
end;

procedure TForm1.StringVisitor(const str: ustring);
begin
mySource := str;
end;

end.

Answer 1

Хорошо, используя Delphi 7, я смог воспроизвести проблему.

Покопавшись в проблеме, я обнаружил, что есть два различных способа получения источника загруженной страницы:

1) procedure GetSourceProc(const proc: TCefStringVisitorProc); как вы используете. Проблема с этим решением в Dlephi 2009: он принимает только автономную процедуру, которая создает проблемы, когда у вас есть несколько экземпляров вашего объекта, в котором вы хотите сохранить свой HTML.

2) procedure GetSource(const visitor: ICefStringVisitor);

Давайте начнем с рассмотрения ожидаемого интерфейса

  ICefStringVisitor = interface(ICefBase)
    ['{63ED4D6C-2FC8-4537-964B-B84C008F6158}']
    procedure Visit(const str: ustring);
  end;

Поэтому я начал изучать это. Корма копаться в unit ceflib; я нашел TCefStringVisitorOwn и это ключ к вашему решению.

Интерфейс TCefStringVisitorOwn довольно просто:

  TCefStringVisitorOwn = class(TCefBaseOwn, ICefStringVisitor)
  protected
    procedure Visit(const str: ustring); virtual;
  public
    constructor Create; virtual;
  end;

Итак, с этим в руке я создал потомка TCefStringVisitorOwn:

unit SourceContainerU;

interface

uses
  ceflib;

type
  ISourceContainer = interface(ICefStringVisitor)
    function Source: ustring;
  end;

  TSourceContainer = class(TCefStringVisitorOwn, ISourceContainer)
  private
    FSource: ustring;
  protected
    procedure Visit(const str: ustring); override;
  public
    function Source: ustring;
  end;

implementation

{ TSourceContainer }

function TSourceContainer.Source: ustring;
begin
  Result := FSource;
end;

procedure TSourceContainer.Visit(const str: ustring);
begin
  FSource := str;
end;

end.

Здесь нет ничего волшебного.

Осталось только создать демонстрационный проект с использованием этого класса. В моем примере я создаю TChromium во время выполнения. Форма содержит кнопку и памятку, а затем этот код:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls,
  cefvcl, ceflib, SourceContainerU;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
    Chromium1: TChromium;
    SourceContainer : ISourceContainer;
    procedure Chromium1LoadEnd(Sender: TObject; const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
  public
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

{ TForm1 }

procedure TForm1.Chromium1LoadEnd(Sender: TObject;  const browser: ICefBrowser; const frame: ICefFrame;  httpStatusCode: Integer);
begin
  if Frame = nil then
    exit;

  SourceContainer := TSourceContainer.Create;
  Frame.GetSource(SourceContainer);
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Chromium1 := TChromium.Create(self);
  Chromium1.Parent := self;
  Chromium1.OnLoadEnd := Chromium1LoadEnd;
  Chromium1.load('http://www.google.com');
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Assigned(SourceContainer) then
    Memo1.Lines.Text := SourceContainer.Source;
end;

end.

Это решение было протестировано с использованием последней версии Chromium, и я протестировал его в Delphi 7, Delphi XE и Delphi XE6. У меня нет какой-либо инсталляции Delphi 2007, но я верю, что в этом случае она должна работать в wotk.