Получение exsl:node-set для работы в PHP

У меня есть следующий код PHP, но он не работает. Я не вижу никаких ошибок, но, возможно, я просто слепой. Я запускаю это на PHP 5.3.1.

<?php
$xsl_string = <<<HEREDOC
<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0"
                xmlns="http://www.w3.org/1999/xhtml"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">
  <xsl:template match="/">
    <p>Hello world</p>
    <xsl:variable name="person">
      <firstname>Foo</firstname>
      <lastname>Bar</lastname>
      <email>test@example.com</email>
    </xsl:variable>
    <xsl:value-of select="exsl:node-set(\$person)/email"/>
  </xsl:template>
</xsl:stylesheet>
HEREDOC;

$xml_dom = new DOMDocument("1.0", "utf-8");
$xml_dom->appendChild($xml_dom->createElement("dummy"));

$xsl_dom = new DOMDocument();
$xsl_dom->loadXML($xsl_string);

$xsl_processor = new XSLTProcessor();
$xsl_processor->importStyleSheet($xsl_dom);
echo $xsl_processor->transformToXML($xml_dom);
?>

Этот код должен выводить "Hello world", за которым следует "test@example.com", но часть электронной почты не отображается. Есть идеи, что случилось?

Джеффри Ли

Источник

1 ответ

Решение

Проблема заключается в том, что предоставленный код XSLT имеет пространство имен по умолчанию.

Следовательно <firstname>, <lastname> а также <email> элементы находятся в пространстве имен xhtml. Но email указывается без префикса в:

exsl:node-set($person)/email

XPath считает, что все имена без префиксов находятся в "пространстве имен". Он пытается найти ребенка exsl:node-set($person) называется email то есть в "нет пространства имен", и это неуспешно, потому что его email child находится в пространстве имен xhtml. Таким образом, нет email узел выбран и выведен.

Решение:

Это преобразование:

<xsl:stylesheet version="1.0"
  xmlns="http://www.w3.org/1999/xhtml"
  xmlns:x="http://www.w3.org/1999/xhtml"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="exsl x">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>

  <xsl:template match="/">
    <html>
     <p>Hello world</p>
     <xsl:variable name="person">
      <firstname>Foo</firstname>
      <lastname>Bar</lastname>
      <email>test@example.com</email>
     </xsl:variable>
     <xsl:text>&#xA;</xsl:text>
     <xsl:value-of select="exsl:node-set($person)/x:email"/>
     <xsl:text>&#xA;</xsl:text>
    </html>
  </xsl:template>
</xsl:stylesheet>

при применении к любому документу XML (не используется), дает желаемый результат:

<html xmlns="http://www.w3.org/1999/xhtml" xmlns:x="http://www.w3.org/1999/xhtml">
   <p>Hello world</p>
test@example.com
</html>

Сделать примечание:

  1. Добавлено определение пространства имен с префиксом x

  2. Измененный select атрибут <xsl:value-of>:

exsl:node-set($person)/x:email

Источник
Другие вопросы по тегам