Загрузка файла с помощью Inno Setup только тогда, когда пользователь выбирает

Вопрос: Я хотел бы знать, как создать сценарий для загрузки второго файла, который представляет собой zip-файл, но изначально дает выбор между двумя zip-файлами; скачайте, распакуйте и удалите zip. Каждый zip-файл имеет разные имена, но содержимое имеет другое имя, чем zip-файлы (каждый с тем же именем); переименование не требуется. Этот вопрос немного похож на условие Apply Download file in inno-setup

Указанные файлы загружаются через веб-сайт SourceForge. Программы (клоны), для которых эти файлы предназначены, либо не указаны в SF, либо изменили назначение.

После исправления PChar ошибка: InnoTools Downloader не работает с Inno 5.5 Теперь я могу повторно использовать этот скрипт установки Inno с 2011 года, но хочу немного его расширить, но с трудом.

#include ReadReg(HKEY_LOCAL_MACHINE,'Software\Sherlock Software\InnoTools\Downloader','ScriptPath','');

[Code]
procedure InitializeWizard();
begin
  itd_init;

  { Set download source.. }
  itd_addfile('http://www.example.com/Textfile.txt', ExpandConstant('{tmp}\Textfile.txt'));
  itd_setoption('UI_AllowContinue','1');
  itd_setoption('UI_DetailedMode','1');
  { Start the download after the "Ready to install" screen is shown }
  itd_downloadafter(wpReady);
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssInstall then { Lets install the downloaded files }
  begin 
    FileCopy(ExpandConstant('{tmp}\Textfile.txt'), ExpandConstant('{userappdata}\program_name\Textfile.txt'), false);
  end;
end;

Рабочий код основан на ответе:

#pragma include __INCLUDE__ + ";" + "c:\lib\InnoDownloadPlugin"
[Setup]
...
CreateUninstallRegKey=no
#include <idp.iss>
...

[Types]
Name: full;    Description: "Full installation"
Name: compact; Description: "Compact installation"
Name: custom;  Description: "Custom installation"; Flags: iscustom

[Components]
Name: abc;  Description: "C File";  Types: full compact custom; Flags: fixed
Name: hlnj;  Description: "HL (Recommended)"; Types: custom; Flags: exclusive
Name: hnj; Description: "HF";  Types: custom; Flags: exclusive

[Files]
Source: "{tmp}\text.net";  DestDir: "{userappdata}\ccc"; Flags: external; Components: abc
Source: "{tmp}\HLNJ.zip";  DestDir: "{userappdata}\ccc"; Flags: external; Components: hlnj
Source: "{tmp}\HNJ.zip"; DestDir: "{userappdata}\ccc"; Flags: external; Components: hnj

[Code]
procedure InitializeWizard;
begin
  idpAddFileComp('http://www.example.com/text.net', ExpandConstant('{tmp}\text.net'), 'abc');
  idpAddFileComp('http://www.example.com/SecurityUpdates/HLNJ.zip', ExpandConstant('{tmp}\HLNJ.zip'), 'hlnj');
  idpAddFileComp('http://www.example.com/SecurityUpdates/HNJ.zip', ExpandConstant('{tmp}\HNJ.zip'), 'hnj');

  idpDownloadAfter(wpReady);
end;

procedure CurStepChanged(CurStep: TSetupStep);
begin
  if CurStep = ssPostInstall then 
  begin
    FileCopy(ExpandConstant('{tmp}\text.net'), ExpandConstant('{userappdata}\ccc\text.net'), false);
    FileCopy(ExpandConstant('{tmp}\HLNJ.zip'), ExpandConstant('{userappdata}\ccc\HLNJ.txt'), false);
    FileCopy(ExpandConstant('{tmp}\HNJ.zip'), ExpandConstant('{userappdata}\ccc\HNJ.txt'), false);
  end;
end;
Источник

1 ответ

Решение

Только после публикации моего ответа я заметил, что, несмотря на пометку вопроса inno-download-plugin, вы фактически используете InnoTools Downloader. Не - InnoTools Downloader мертв и не поддерживается.

в examples Папка установки плагинов Inno Download, есть components1.iss а также components2.iss Примеры.

Первый показывает, как использовать idpAddFileComp условно скачать файл, когда выбран компонент.

Я публикую полный пример:

; Uncomment one of following lines, if you haven't checked "Add IDP include path to ISPPBuiltins.iss" option during IDP installation:
;#pragma include __INCLUDE__ + ";" + ReadReg(HKLM, "Software\Mitrich Software\Inno Download Plugin", "InstallDir")
;#pragma include __INCLUDE__ + ";" + "c:\lib\InnoDownloadPlugin"

[Setup]
AppName          = My Program
AppVersion       = 1.0
DefaultDirName   = {pf}\My Program
DefaultGroupName = My Program
OutputDir        = userdocs:Inno Setup Examples Output

#include <idp.iss>

[Types]
Name: full;    Description: "Full installation"
Name: compact; Description: "Compact installation"
Name: custom;  Description: "Custom installation"; Flags: iscustom

[Components]
Name: app;  Description: "My Program";  Types: full compact custom; Flags: fixed
Name: help; Description: "Help files";  Types: full
Name: src;  Description: "Source code"; Types: full

[Files]
Source: "{tmp}\app.exe";  DestDir: "{app}"; Flags: external; ExternalSize: 1048576; Components: app
Source: "{tmp}\help.chm"; DestDir: "{app}"; Flags: external; ExternalSize: 1048576; Components: help
Source: "{tmp}\src.zip";  DestDir: "{app}"; Flags: external; ExternalSize: 1048576; Components: src

[Icons]
Name: "{group}\My Program"; Filename: "app.exe";  Components: app
Name: "{group}\Help file";  Filename: "help.chm"; Components: help
Name: "{group}\{cm:UninstallProgram,My Program}"; Filename: "{uninstallexe}"

[Code]
procedure InitializeWizard;
begin
    idpAddFileComp('http://127.0.0.1/app.exe',  ExpandConstant('{tmp}\app.exe'),  'app');
    idpAddFileComp('http://127.0.0.1/help.chm', ExpandConstant('{tmp}\help.chm'), 'help');
    idpAddFileComp('http://127.0.0.1/src.zip',  ExpandConstant('{tmp}\src.zip'),  'src');

    idpDownloadAfter(wpReady);
end;

Предупреждение: имя компонента передается idpAddFileComp должен быть в нижнем регистре (фактическое имя компонента может использовать верхний регистр).

Источник

Inno Setup 6.1.2 имеет новый DownloadTemporaryFile функция поддержки для загрузки файлов без использования сторонних инструментов:

  • Поддерживает HTTPS (но без просроченных или самозаверяющих сертификатов) и HTTP.
  • Перенаправления выполняются автоматически, и автоматически используются настройки прокси.
  • Безопасно использовать из сервисов в отличие от существующих сторонних инструментов.
  • Поддерживает проверку хэша SHA-256 загруженного файла.
  • Поддерживает базовую аутентификацию.

Я добавил этот ответ, потому что даже плагин IDP, упомянутый в принятом ответе, последний раз обновлялся в 2016 году и сейчас у меня не работал, и мне пришлось перейти на новую функцию, предоставляемую Inno Setup 6.1.2.

Источник
Другие вопросы по тегам