CryptoAPI возвращает неверный результат для HMAC_SHA1
Я использую приведенный ниже код с Crypto API и не получаю ожидаемых результатов на основе тестирования с другими API и библиотеками.
Я использую ключ "ключ", а данные "сообщение"
Например, используя Инди TidHMACSHA1, я получаю 2088df74d5f2146b48146caf4965377e9d0be3a4
Я получаю тот же результат, используя онлайн-генераторы (например, http://www.freeformatter.com/hmac-generator.html).
С кодом, который я написал (см. Ниже), я получаю 4a52c3c0abc0a06049d1ab648bb4057e3ff5f359
Код ниже, я использую заголовок JEDI wcrypt2.pas
function Hashhmacsha1(const Key, Value: AnsiString): AnsiString;
var
hCryptProvider: HCRYPTPROV;
hHash: HCRYPTHASH;
hKey: HCRYPTKEY;
bHash: array[0..$7F] of Byte;
dwHashLen: dWord;
i: Integer;
hHmacHash: HCRYPTHASH;
bHmacHash: array[0..$7F] of Byte;
dwHmacHashLen: dWord;
hmac_info : Wcrypt2.HMAC_INFO;
begin
dwHashLen := 32;
dwHmacHashLen := 32;
{get context for crypt default provider}
if CryptAcquireContext(@hCryptProvider, nil, nil, PROV_RSA_FULL, CRYPT_VERIFYCONTEXT or CRYPT_MACHINE_KEYSET) then
begin
{create hash-object }
if CryptCreateHash(hCryptProvider, CALG_SHA1, 0, 0, @hHash) then
begin
{get hash from password}
if CryptHashData(hHash, @Key[1], Length(Key), 0) then
begin
// hHash is now a hash of the provided key, (SHA1)
// Now we derive a key for it
if CryptDeriveKey(hCryptProvider, CALG_RC4, hHash, 0, @hKey) then
begin
//hkey now holds our key. So we have do the whole thing over again
//ZeroMemory( hmac_info, SizeOf(hmac_info) );
hmac_info.HashAlgid := CALG_SHA1;
if CryptCreateHash(hCryptProvider, CALG_HMAC, hKey, 0, @hHmacHash) then
begin
{get hash from password}
if CryptSetHashParam( hHmacHash, HP_HMAC_INFO, @hmac_info, 0) then
begin
if CryptHashData(hHmacHash, @Value[1], Length(Value), 0) then
begin
if CryptGetHashParam(hHmacHash, HP_HASHVAL, @bHmacHash[0], @dwHmacHashLen, 0) then
begin
for i := 0 to dwHmacHashLen-1 do
Result := Result + IntToHex(bHmacHash[i], 2);
end
else
WriteLn( 'CryptGetHashParam ERROR --> ' + SysErrorMessage(GetLastError)) ;
end
else
WriteLn( 'CryptHashData ERROR --> ' + SysErrorMessage(GetLastError)) ;
{destroy hash-object}
CryptDestroyHash(hHmacHash);
CryptDestroyKey(hKey);
end
else
WriteLn( 'CryptSetHashParam ERROR --> ' + SysErrorMessage(GetLastError)) ;
end
else
WriteLn( 'CryptCreateHash ERROR --> ' + SysErrorMessage(GetLastError)) ;
end
else
WriteLn( 'CryptDeriveKey ERROR --> ' + SysErrorMessage(GetLastError)) ;
end;
{destroy hash-object}
CryptDestroyHash(hHash);
end;
{release the context for crypt default provider}
CryptReleaseContext(hCryptProvider, 0);
end;
Result := AnsiLowerCase(Result);
end;
Я явно что-то делаю неправильно, но я не знаю, что??
3 ответа
Итак, я нашел решение, которое при генерации HMAC_SHA1 для "сообщения" данных с ключом "ключ" генерирует ожидаемый хеш 2088df74d5f2146b48146caf4965377e9d0be3a4
Как видите, этот код использует CryptImportKey вместо CryptDeriveKey, который, кажется, решить проблему. Кажется, что использование CryptDeriveKey фактически генерирует хеш HMAC_SHA1, используя "сообщение" данных и хэш SHA1 ключа "ключ", закодированный как RC4, вместо ключа открытого текста, как первоначально предполагалось.
Код работает для ключей длиной до 16 символов, любой больше и использует только первые 16 символов. Я публикую второй вопрос, чтобы узнать об этом!!
Код размещен ниже.
function Hashhmacsha1(const Key, Value: AnsiString): AnsiString;
const
KEY_LEN_MAX = 16;
var
hCryptProvider: HCRYPTPROV;
hHash: HCRYPTHASH;
hKey: HCRYPTKEY;
bHash: array[0..$7F] of Byte;
dwHashLen: dWord;
i: Integer;
hPubKey : HCRYPTKey;
hHmacHash: HCRYPTHASH;
bHmacHash: array[0..$7F] of Byte;
dwHmacHashLen: dWord;
hmac_info : Wcrypt2.HMAC_INFO;
keyBlob: record
keyHeader: BLOBHEADER;
keySize: DWORD;
keyData: array[0..KEY_LEN_MAX-1] of Byte;
end;
keyLen : INTEGER;
begin
dwHashLen := 32;
dwHmacHashLen := 32;
{get context for crypt default provider}
if CryptAcquireContext(@hCryptProvider, nil, nil, PROV_RSA_FULL, CRYPT_VERIFYCONTEXT) then
begin
{create hash-object MD5}
if CryptCreateHash(hCryptProvider, CALG_SHA1, 0, 0, @hHash) then
begin
{get hash from password}
if CryptHashData(hHash, PByte(Key), Length(Key), 0) then
begin
// hHash is now a hash of the provided key, (SHA1)
// Now we derive a key for it
hPubKey := 0;
FillChar(keyBlob, SizeOf(keyBlob), 0);
keyBlob.keyHeader.bType := PLAINTEXTKEYBLOB;
keyBlob.keyHeader.bVersion := CUR_BLOB_VERSION;
keyBlob.keyHeader.aiKeyAlg := CALG_RC4;
KeyBlob.keySize := KEY_LEN_MAX;
if(Length(key) < (KEY_LEN_MAX))then
KeyLen := Length(key)
else
KeyLen := KEY_LEN_MAX;
Move(Key[1], KeyBlob.keyData[0], KeyLen );
if CryptImportKey(hCryptProvider, @keyBlob, SizeOf(KeyBlob), hPubKey, 0, @hKey) then
begin
//hkey now holds our key. So we have do the whole thing over again
ZeroMemory( @hmac_info, SizeOf(hmac_info) );
hmac_info.HashAlgid := CALG_SHA1;
if CryptCreateHash(hCryptProvider, CALG_HMAC, hKey, 0, @hHmacHash) then
begin
if CryptSetHashParam( hHmacHash, HP_HMAC_INFO, @hmac_info, 0) then
begin
if CryptHashData(hHmacHash, @Value[1], Length(Value), 0) then
begin
if CryptGetHashParam(hHmacHash, HP_HASHVAL, @bHmacHash[0], @dwHmacHashLen, 0) then
begin
for i := 0 to dwHmacHashLen-1 do
Result := Result + IntToHex(bHmacHash[i], 2);
end
else
WriteLn( 'CryptGetHashParam ERROR --> ' + SysErrorMessage(GetLastError)) ;
end
else
WriteLn( 'CryptHashData ERROR --> ' + SysErrorMessage(GetLastError)) ;
{destroy hash-object}
CryptDestroyHash(hHmacHash);
CryptDestroyKey(hKey);
end
else
WriteLn( 'CryptSetHashParam ERROR --> ' + SysErrorMessage(GetLastError)) ;
end
else
WriteLn( 'CryptCreateHash ERROR --> ' + SysErrorMessage(GetLastError)) ;
end
else
WriteLn( 'CryptDeriveKey ERROR --> ' + SysErrorMessage(GetLastError)) ;
end;
{destroy hash-object}
CryptDestroyHash(hHash);
end;
{release the context for crypt default provider}
CryptReleaseContext(hCryptProvider, 0);
end;
Result := AnsiLowerCase(Result);
end;
Мне удалось получить правильный результат для ключей длиннее 16 байт с помощью OpenSLL. Вместо примерно 10 вызовов Win32 Crypt это делалось в три этапа: init, HMAC и cleanup.
Я не работаю с вашими функциями, поэтому поправьте меня, если я ошибаюсь: я не вижу, где вы вычисляете HMACSHA1('message', 'key').
После CryptCreateHash(hCryptProvider, CALG_HMAC, hKey, 0, @hHmacHash) Я предполагаю, что вы вычисляете HMACSHA1('message', hkey), где производный ключ hkey каким-то образом вычисляется с помощью RC4.
Кстати: есть вводящий в заблуждение комментарий, связанный с MD5 (артефакт из старой версии?)