Несвязанная структура Int при компиляции с использованием CM.make

Question

Я собираю лексер, используя CM и ML-Lex. Когда я пытаюсь скомпилировать с использованием CM.make "sources.cm", он выдает ошибки.

errormsg.sml:7.24-7.39 Error: unbound structure: TextIO in path TextIO.instream
errormsg.sml:21.26-21.38 Error: unbound structure: TextIO in path TextIO.stdIn
errormsg.sml:27.18-27.30 Error: unbound structure: TextIO in path TextIO.stdIn
errormsg.sml:36.12-36.24 Error: unbound structure: Int in path Int.toString

и еще пара, как и предыдущие. Если я пытаюсь использовать "errormsg.sml", все работает отлично. Я попытался переместить errormsg.sml в sources.cm.

sources.cm:

Group is

$/smlnj-lib.cm
driver.sml
tokens.sig
tokens.sml
errormsg.sml
tiger.lex

errormsg.sml:

signature ERRORMSG =
sig
    val anyErrors : bool ref
    val fileName : string ref
    val lineNum : int ref
    val linePos : int list ref
    val sourceStream : TextIO.instream ref
    val error : int -> string -> unit
    exception Error
    val impossible : string -> 'a   (* raises Error *)
    val reset : unit -> unit
end

structure ErrorMsg : ERRORMSG =
struct

  val anyErrors = ref false
  val fileName = ref ""
  val lineNum = ref 1
  val linePos = ref [1]
  val sourceStream = ref TextIO.stdIn

  fun reset() = (anyErrors:=false;
                 fileName:="";
                 lineNum:=1;
                 linePos:=[1];
                 sourceStream:=TextIO.stdIn)

  exception Error

  fun error pos (msg:string) =
      let fun look(a::rest,n) =
            if a<pos then app print [":",
                               Int.toString n,
                                       ".",
                                       Int.toString (pos-a)]
               else look(rest,n-1)
            | look _ = print "0.0"
       in anyErrors := true;
          print (!fileName);
          look(!linePos,!lineNum);
          print ":";
          print msg;
          print "\n"
      end

  fun impossible msg =
      (app print ["Error: Compiler bug: ",msg,"\n"];
       TextIO.flushOut TextIO.stdOut;
       raise Error)

end

Answer 1

Вам нужно добавить $/basis.cm на ваш sources.cm, Это импортирует стандартную библиотеку ML:

Group is

$/basis.cm
$/smlnj-lib.cm
driver.sml
tokens.sig
tokens.sml
errormsg.sml
tiger.lex