Преобразование базового ActionScript 2 в ActionScript 3 для анимации ролловера

Question

Итак, то, что я пытаюсь сделать, должно быть простым. Это просто анимация ролловера, которая переворачивается, когда пользователь выключает мышь. Дело в том, что это в AS2, но я думаю, что для завершения проекта он мне понадобится в AS3. Может кто-нибудь дать несколько советов по преобразованию этого...

stop();

this.onEnterFrame = function(){
if(rewind == true){
prevFrame();
}
}

this.onRollOver = function(){
rewind = false;
play();
}

this.onRollOut = function(){
rewind = true;
}

this.onRelease = function(){
getURL("http://www.google.com","_blank");
}

... в AS3? Я был бы СЕРЬЕЗНО благодарен.

Answer 1

Если ваши потребности кода ограничены этим, вы должны научиться делать это в AS3 раз и навсегда.

Здесь точно такая же вещь в AS3

import flash.events.Event;
import flash.events.MouseEvent;
import flash.net.navigateToURL;
import flash.net.URLRequest;

stop();
addEventListener(Event.ENTER_FRAME, onEnterFrame);
addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);
addEventListener(MouseEvent.CLICK, onClick);

var rewind:Boolean = false;

function onEnterFrame(event:Event):void
{
    if (rewind == true) {
        prevFrame();
    }
}

function onMouseOver(event:MouseEvent):void
{
    rewind = false;
    play();
}

function onMouseOut(event:MouseEvent):void
{
    rewind = true;
}

function onClick(event:MouseEvent):void
{
    navigateToURL(new URLRequest("http://www.google.com"),"_blank");
}

Обратите внимание, что вместо создания слушателя события (например, пролонгации), написав this.onRollOver = function()Вы действительно должны позвонить addEventListener (что довольно логично), укажите событие, которое вы хотите прослушать, и создайте функцию, вызываемую при обнаружении этого события.

Есть и еще одно отличие в getURL->navigateToURL, но я думаю, что вам не нужно дальнейшее объяснение этого:)

В качестве благодарности, я очень признателен вам за то, что вы прочитали этот код и попытаетесь извлечь из него урок, а не копировать / вставлять его грубо Но ты свободен!