Как переименовать Node под управлением базы данных mnesia

Question

Я создал базу данных / схему Mnesia на машине1. Узел был назван mypl@machine1. Затем я переместил все файлы на machine2, потому что machine1 сломался. Все работает нормально, пока код работает с именем "mypl @ machine1". Очевидно, это несколько сбивает с толку, потому что теперь он работает на машине2.

Если я запускаю Erlang с именем узла "mypl@machine2", база данных Mnesia окажется пустой.

Как переименовать узел в базе данных Mnesia с machine1 на machine2?

Answer 1

Я не думаю, что это можно сделать онлайн на одном узле (кто-нибудь?), Но это можно сделать с помощью резервного копирования / восстановления в дополнение к запуску двух узлов и добавлению копий таблиц. В разделе руководства пользователя Mnesia 6.9.1 вы найдете код, который использует mnesia:traverse_backup для изменения имен узлов в таблице схемы (показано ниже) в файле резервной копии mnesia. Имя модуля, которое вы, вероятно, должны использовать: mnesia_backup,

С этим кодом вам нужно:

%% On mypl@machine1
mnesia:backup("/path/to/mnesia.backup").
change_node_name(mnesia_backup, mypl@machine1, mypl@machine2,
                 "/path/to/mnesia.backup", "/path/to/new.mnesia.backup").
%% On mypl@machine2
mnesia:restore("/path/to/new.mnesia.backup", []).

Я не уверен, если вам нужно сначала создать схему mypl@machine2,

Код изменения имени узла из руководства пользователя:

change_node_name(Mod, From, To, Source, Target) ->
    Switch =
        fun(Node) when Node == From -> To;
           (Node) when Node == To -> throw({error, already_exists});
           (Node) -> Node
        end,
    Convert =
        fun({schema, db_nodes, Nodes}, Acc) ->
                {[{schema, db_nodes, lists:map(Switch,Nodes)}], Acc};
           ({schema, version, Version}, Acc) ->
                {[{schema, version, Version}], Acc};
           ({schema, cookie, Cookie}, Acc) ->
                {[{schema, cookie, Cookie}], Acc};
           ({schema, Tab, CreateList}, Acc) ->
                Keys = [ram_copies, disc_copies, disc_only_copies],
                OptSwitch =
                    fun({Key, Val}) ->
                            case lists:member(Key, Keys) of
                                true -> {Key, lists:map(Switch, Val)};
                                false-> {Key, Val}
                            end
                    end,
                {[{schema, Tab, lists:map(OptSwitch, CreateList)}], Acc};
           (Other, Acc) ->
                {[Other], Acc}
        end,
    mnesia:traverse_backup(Source, Mod, Target, Mod, Convert, switched).

Answer 2

Обходной путь - миграция. Просто запустите кластер mnesia и перенесите все свои таблицы и схемы на другой узел. Чем удалить из оригинала и забыл.