Аргументы недостаточно проработаны в прологе

Question

Я пытаюсь запустить этот код, но я получаю эту ошибку каждый раз, когда я использую этот запрос: gp174(P, S). ERROR: >=/2: Arguments are not sufficiently instantiated.

и это мой код:

call_option(B,S,C,E,P) :- 
    0 =< S, 
    S =< E / 100, 
    P = -C * B.

call_option(B,S,C,E,P) :- 
    S >= E / 100, 
    P = (100 * S - E - C) * B.

gp173(P) :- 
    call_option(1, 7, 200, 300, P).

% butterfly strike p174.
butterfly(S, H) :- 
    H = P1 + 2*P2 + P3,
    Buy = 1, Sell = -1,
        call_option(Buy, S, 100, 500, P1),
        call_option(Sell, S, 200, 300, P2),
        call_option(Buy, S, 400, 100, P3).

% goal for butterfly strike

gp174(P,S) :- 
    P >= 0, 
    butterfly(S,P).

Что я должен делать?
Где мне загрузить библиотеку clpr?

Answer 1

Я попытался изменить с помощью документированной библиотеки:

:- [library(clpr)].

call_option(B,S,C,E,P) :-
    {0 =< S},
    {S =< E / 100},
    {P = -C * B}.

call_option(B,S,C,E,P) :-
    {S >= E / 100},
    {P = (100 * S - E - C) * B}.

gp173(P) :-
    call_option(1, 7, 200, 300, P).

% butterfly strike p174.
butterfly(S, H) :-
    {H = P1 + 2*P2 + P3,
    Buy = 1, Sell = -1},
        call_option(Buy, S, 100, 500, P1),
        call_option(Sell, S, 200, 300, P2),
        call_option(Buy, S, 400, 100, P3).

% goal for butterfly strike

gp174(P,S) :-
    {P >= 0},
    butterfly(S,P).

и вот результат:

?- gp174(P,S).
{S=2.0+0.01*P, P=<100.0, _G56405= -300.0+P, P>=0.0} ;
{S=4.0-0.01*P, P=<100.0, _G59475= -100.0-P, _G59488=100.0+P, P>=0.0} ;
false.

НТН