Как мне связать latexmk с одним ключом в Emacs и показать ошибки, если они есть

Question

Я использую AUCTeX и хочу связать ключ, например C-0, что делает следующее:

1. Сохраняет активный файл, не запрашивая меня.
2. Запускается latexmk на активный файл без запроса меня.
3. Показывает мне ошибки, если latexmk сталкивается с любым путем.

Моя проблема не в том, как связать ключ (для которого Тайлер разместил ссылку в комментарии ниже), а в том, как придумать функцию, которая выполняет пункт 1-3.

---

Я называю Latexmk

(add-hook 'LaTeX-mode-hook (lambda ()
  (push 
    '("Latexmk" "latexmk %s" TeX-run-TeX nil t
      :help "Run Latexmk on file")
    TeX-command-list)))

Это мой.latexmkrc

$pdf_mode = 1;
$recorder = 1;
$latex = 'latex -recorder -halt-on-error -interaction=nonstopmode -shell-escape';
$pdflatex = 'pdflatex -recorder -halt-on-error -interaction=nonstopmode -shell-escape';

Я использую Emacs 23.3 и AUCTeX 11.86.

Answer 1

Что-то вроде этого?

(require 'tex-buf)

(defun run-latexmk ()
  (interactive)
  (let ((TeX-save-query nil)
        (TeX-process-asynchronous nil)
        (master-file (TeX-master-file)))
    (TeX-save-document "")
    (TeX-run-TeX "latexmk" "latexmk" master-file)
    (if (plist-get TeX-error-report-switches (intern master-file))
        (TeX-next-error t)
      (minibuffer-message "latexmk done"))))

(add-hook 'LaTeX-mode-hook
          (lambda () (local-set-key (kbd "C-0") #'run-latexmk)))

Редактировать:TeX-save-document сохраняет ваш главный файл и любые вложенные файлы (если у вас есть только один файл, это ваш главный файл), и когда TeX-save-query ноль, он не спрашивает у вас подтверждения. затем TeX-run-TeX запускает latexmk, используя механизм, обычно используемый для запуска TeX, который включает в себя разбор сообщения об ошибке, но поскольку он обычно запускает асинхронный процесс, мы устанавливаем TeX-process-asynchronous до нуля, чтобы дождаться его окончания. Странный вид plist-get Форма - это документированный способ проверки ошибок от TeX-run-TeX (см. комментарии в tex-buf.el), и если есть ошибки, мы переходим к первой; если ошибок нет, мы показываем сообщение в минибуфере просто для удовольствия.

Наконец, local-set-key это один из способов привязать ключ к функции.

Answer 2

Делает ли это то, что вы хотите?

(defun my-tex ()
"Saves the current buffer and runs LaTeX, all with no prompts or further interaction."
  (interactive)
  (save-buffer)
  (TeX-command "LaTeX" 'TeX-master-file -1))

Я не использую latexmk, но для этого все, что вам нужно сделать, это переключить строку "LaTeX" на строку имени, которую вы используете для latexmk в TeX-command-list (что, вероятно, просто "latexmk" или "Latexmk").

Я рад, что вы спросили, как это будет полезно для меня сейчас!

Answer 3

Предполагая, что вы уже использовали ответ в Как вызвать latexmk в emacs, и перейдите к следующей ошибке, чтобы добавить latexmk в список команд для AUCTeX вы можете использовать следующую функцию:

(defun run-latexmk ()
  (interactive)
  (save-buffer)
  (TeX-command "Latexmk" 'TeX-master-file 0)
  (if (plist-get TeX-error-report-switches (intern (TeX-master-file)))
      (next-error))) ;; 0 -> suppress confirmation

И использовать любой из методов привязки клавиш, чтобы связать его с C-0; вот тот, который является локальным для режима TeX:

(define-key TeX-mode-map (kbd "C-0") 'run-latexmk)

run-latexmk функция основана на копании TeX-command-masterи упрощая его для ваших нужд. Обратите внимание, что призыв к (next-error) может случиться не всегда, потому что LaTeX может запутаться из-за вашей ошибки и сделать паузу в ожидании ввода