Обратитесь к / выбрать диск только на основе его метки? (т.е. не буква диска)

Я пытаюсь сослаться на диск, буква которого может измениться. Я бы хотел сослаться на него по его метке (например, MyLabel (v:) в пакетном файле). На него может ссылаться V:\ . Я бы хотел сослаться на него с помощью MyLabel.

(Это сообщение было опубликовано в Экспертном обмене в течение месяца без ответа. Посмотрим, как быстро SO ответит на него)

Источник

4 ответа

Решение

Этот bat-файл даст вам букву диска из метки диска:

Option Explicit
Dim num, args, objWMIService, objItem, colItems

set args = WScript.Arguments
num = args.Count

if num <> 1 then
   WScript.Echo "Usage: CScript DriveFromLabel.vbs <label>"
   WScript.Quit 1
end if

Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
Set colItems = objWMIService.ExecQuery("Select * from Win32_LogicalDisk")

For Each objItem in colItems
  If strcomp(objItem.VolumeName, args.Item(0), 1) = 0 Then
    Wscript.Echo objItem.Name
  End If
Next

WScript.Quit 0

Запустите это как:

 cscript /nologo DriveFromLabel.vbs label
Источник

Предыдущие ответы кажутся слишком сложными и / или не особенно подходят для пакетного файла.

Этот простой однострочник должен поместить нужную букву диска в переменную myDrive. Очевидно, измените "My Label" на ваш фактический ярлык.

for /f %%D in ('wmic volume get DriveLetter^, Label ^| find "My Label"') do set myDrive=%%D

При запуске из командной строки (не в пакетном файле), %%D должен быть изменен на% D в обоих местах.

Как только переменная установлена, вы можете обратиться к диску, используя %myDrive%, Например

dir %myDrive%\someFolder
Источник

Для этого вы можете использовать язык запросов WMI. Посмотрите на http://msdn.microsoft.com/en-us/library/aa394592(VS.85).aspx примеры. Информация, которую вы ищете, доступна, например, через свойство VolumeName класса Win32_LogicalDisk, http://msdn.microsoft.com/en-us/library/aa394173(VS.85).aspx

SELECT * FROM Win32_LogicalDisk WHERE VolumeName="MyLabel"

Источник

Вот простой пакетный скрипт getdrive.cmd для поиска буквы диска по метке тома. Просто назовите "getdrive MyLabel" или getdrive "My Label".

@echo off
setlocal

:: Initial variables
set TMPFILE=%~dp0getdrive.tmp
set driveletters=abcdefghijklmnopqrstuvwxyz
set MatchLabel_res=

for /L %%g in (2,1,25) do call :MatchLabel %%g %*

if not "%MatchLabel_res%"=="" echo %MatchLabel_res%

goto :END


:: Function to match a label with a drive letter. 
::
:: The first parameter is an integer from 1..26 that needs to be 
:: converted in a letter. It is easier looping on a number
:: than looping on letters.
::
:: The second parameter is the volume name passed-on to the script
:MatchLabel

:: result already found, just do nothing 
:: (necessary because there is no break for for loops)
if not "%MatchLabel_res%"=="" goto :eof

:: get the proper drive letter
call set dl=%%driveletters:~%1,1%%

:: strip-off the " in the volume name to be able to add them again further
set volname=%2
set volname=%volname:"=%

:: get the volume information on that disk
vol %dl%: > "%TMPFILE%" 2>&1

:: Drive/Volume does not exist, just quit
if not "%ERRORLEVEL%"=="0" goto :eof

set found=0
for /F "usebackq tokens=3 delims=:" %%g in (`find /C /I "%volname%" "%TMPFILE%"`) do set found=%%g

:: trick to stip any whitespaces
set /A found=%found% + 0


if not "%found%"=="0" set MatchLabel_res=%dl%:
goto :eof








:END

if exist "%TMPFILE%" del "%TMPFILE%"
endlocal
Источник
Другие вопросы по тегам