FizzBuzz с активными шаблонами

Question

Я пытаюсь понять активные шаблоны, поэтому я играю с FizzBuzz:

let (|Fizz|_|) i = if i % 3 = 0 then Some Fizz else None
let (|Buzz|_|) i = if i % 5 = 0 then Some Buzz else None
let (|FizzBuzz|_|) i = if i % 5 = 0 && i % 3 = 0 then Some FizzBuzz else None

let findMatch = function
    | Some Fizz -> "Fizz"
    | Some Buzz -> "Buzz"
    | Some FizzBuzz -> "FizzBuzz"
    | _ -> ""

let fizzBuzz = seq {for i in 0 .. 100 -> Some i}
                |> Seq.map (fun i -> i, findMatch i)

Это в основном правильный подход, или есть лучший способ использовать активные шаблоны здесь? Должен ли я быть в состоянии сделать findMatch взять int вместо параметра int?

Answer 1

Ваш findMatch функция должна быть:

let findMatch = function
    | FizzBuzz -> "FizzBuzz" (* should be first, as pad pointed out *)
    | Fizz -> "Fizz"
    | Buzz -> "Buzz"
    | _ -> ""

Вы можете переписать последние несколько строк:

let fizzBuzz = Seq.init 100 (fun i -> i, findMatch i)

Ваши активные шаблоны в порядке. Одна альтернатива - использовать полный активный шаблон:

let (|Fizz|Buzz|FizzBuzz|Num|) i = 
    match i % 3, i % 5 with
    | 0, 0 -> FizzBuzz
    | 0, _ -> Fizz
    | _, 0 -> Buzz
    | _ -> Num i

Answer 2

Первое решение Даниэля может быть упрощено, потому что вам на самом деле не нужно определять отдельный активный шаблон для FizzBuzz, Случай можно описать как Fizz а также Buzz сопоставление, которое может быть красиво выражено на языке шаблона:

let findMatch = function 
  | Fizz & Buzz -> "FizzBuzz" 
  | Fizz -> "Fizz" 
  | Buzz -> "Buzz" 
  | _ -> "" 

let fizzBuzz = [ for i in 0 .. 100 -> findMatch i ]

Шаблон Fizz & Buzz соответствует, если оба Fizz а также Buzz матч. Это основывается на том факте, что шаблон сопоставляется первым, поэтому в данном случае порядок имеет значение. Я также немного сократил вашу последнюю строчку до стиля, который я предпочитаю, и немного короче (но мнения разные).

В качестве альтернативы, если вы не хотите определять слишком много одноразовых активных шаблонов, вы также можете написать параметризованный активный шаблон, который проверяет, делится ли вход на любое указанное число:

let (|DivisibleBy|_|) by n = if n%by=0 then Some DivisibleBy else None

let findMatch = function 
  | DivisibleBy 3 & DivisibleBy 5 -> "FizzBuzz" 
  | DivisibleBy 3 -> "Fizz" 
  | DivisibleBy 5 -> "Buzz" 
  | _ -> "" 

Answer 3

Удалить (ненужно) Some чтобы findMatch функция занимает int как его параметр:

let findMatch = function
    | FizzBuzz -> "FizzBuzz" (* Should be the first pattern *)
    | Fizz -> "Fizz"
    | Buzz -> "Buzz"
    | _ -> ""

let fizzBuzz = seq { for i in 0..100 -> i, findMatch i }