Извлечение файлов из ZIP-файла с помощью VBScript

Question

Извлечение файлов из ZIP-файла с помощью VBScript

При извлечении файлов из ZIP-файла я использовал следующее.

Sub Unzip(strFile)
' This routine unzips a file. NOTE: The files are extracted to a folder '
' in the same location using the name of the file minus the extension.  '
' EX. C:\Test.zip will be extracted to C:\Test '
'strFile (String) = Full path and filename of the file to be unzipped. '
Dim arrFile
    arrFile = Split(strFile, ".")
    Set fso = CreateObject("Scripting.FileSystemObject")
    fso.CreateFolder(arrFile(0) & "\ ")
    pathToZipFile= arrFile(0) & ".zip"
    extractTo= arrFile(0) & "\ "
    set objShell = CreateObject("Shell.Application")
    set filesInzip=objShell.NameSpace(pathToZipFile).items
    objShell.NameSpace(extractTo).CopyHere(filesInzip)
    fso.DeleteFile pathToZipFile, True
    Set fso = Nothing
    Set objShell = Nothing
End Sub 'Unzip

Это работало, но теперь я получаю сообщение об ошибке "Файл существует".

Что является причиной этого? Есть ли альтернативы?

12

vbscript zip

Источник

14 ноя '08 в 21:03

5 ответов

Другие вопросы по тегам vbscript zip

user1031929 29 мар '12 в 23:08 2012-03-29 23:08 · Answer 1 · 2012-03-29 23:08

Все вышеперечисленные решения точны, но они не являются окончательными.

Если вы пытаетесь извлечь заархивированный файл во временную папку, папка, которая отображает "Временная папка для YOURFILE.zip", будет немедленно создана (в C:\Documents а также Settings\USERNAME\Local Settings\Temp) для КАЖДОГО ФАЙЛА, содержащегося в вашем ZIP-файле, который вы пытаетесь извлечь.

Это верно, если у вас есть 50 файлов, он создаст 50 папок в вашем временном каталоге.

Но если у вас есть 200 файлов, он остановится на 99 и вылетает с сообщением - Файл существует.

..

По-видимому, это не происходит в Windows 7 с вкладами, которые я рассматриваю выше. Но, тем не менее, у нас все еще могут быть чеки. Хорошо, вот как это исправить:

    '========================
    'Sub: UnzipFiles
    'Language: vbscript
    'Usage: UnzipFiles("C:\dir", "extract.zip")
    'Definition: UnzipFiles([Directory where zip is located & where files will be extracted], [zip file name])
    '========================
    Sub UnzipFiles(folder, file)
        Dim sa, filesInzip, zfile, fso, i : i = 1
        Set sa = CreateObject("Shell.Application")
            Set filesInzip=sa.NameSpace(folder&file).items
        For Each zfile In filesInzip
            If Not fso.FileExists(folder & zfile) Then
                sa.NameSpace(folder).CopyHere(zfile), &H100 
                i = i + 1
            End If
            If i = 99 Then
            zCleanup(file, i)
            i = 1
            End If
        Next
        If i > 1 Then 
            zCleanup(file, i)
        End If
        fso.DeleteFile(folder&file)
    End Sub

    '========================
    'Sub: zCleanup
    'Language: vbscript
    'Usage: zCleanup("filename.zip", 4)
    'Definition: zCleanup([Filename of Zip previously extracted], [Number of files within zip container])
    '========================
    Sub zCleanUp(file, count)   
        'Clean up
        Dim i, fso
        Set fso = CreateObject("Scripting.FileSystemObject")
        For i = 1 To count
           If fso.FolderExists(fso.GetSpecialFolder(2) & "\Temporary Directory " & i & " for " & file) = True Then
           text = fso.DeleteFolder(fso.GetSpecialFolder(2) & "\Temporary Directory " & i & " for " & file, True)
           Else
              Exit For
           End If
        Next
    End Sub

И это все, скопируйте и вставьте эти две функции в свою программу, размещенную на VBScript, и вы должны хорошо работать на Windows XP и Windows 7.

Спасибо!

user48082 28 мар '09 в 09:27 2009-03-28 09:27 · Answer 2 · 2009-03-28 09:27

Вы можете использовать DotNetZip из VBScript.

Чтобы распаковать существующий zip-файл, перезаписав все файлы, которые могут существовать:

WScript.echo("Instantiating a ZipFile object...")
Dim zip 
Set zip = CreateObject("Ionic.Zip.ZipFile")

WScript.echo("Initialize (Read)...")
zip.Initialize("C:\Temp\ZipFile-created-from-VBScript.zip")

WScript.echo("setting the password for extraction...")
zip.Password = "This is the Password."

' set the default action for extracting an existing file
' 0 = throw exception
' 1 = overwrite silently
' 2 = don't overwrite (silently)
' 3 = invoke the ExtractProgress event
zip.ExtractExistingFile = 1

WScript.echo("extracting all files...")
Call zip.ExtractAll("extract")

WScript.echo("Disposing...")
zip.Dispose()

WScript.echo("Done.")

Чтобы создать новый zipfile:

dim filename 
filename = "C:\temp\ZipFile-created-from-VBScript.zip"

WScript.echo("Instantiating a ZipFile object...")
dim zip2 
set zip2 = CreateObject("Ionic.Zip.ZipFile")

WScript.echo("using AES256 encryption...")
zip2.Encryption = 3

WScript.echo("setting the password...")
zip2.Password = "This is the Password."

WScript.echo("adding a selection of files...")
zip2.AddSelectedFiles("*.js")
zip2.AddSelectedFiles("*.vbs")

WScript.echo("setting the save name...")
zip2.Name = filename

WScript.echo("Saving...")
zip2.Save()

WScript.echo("Disposing...")
zip2.Dispose()

WScript.echo("Done.")

user308709 15 июл '11 в 16:42 2011-07-15 16:42 · Answer 3 · 2011-07-15 16:42

Выше приведены ответы, которые совершенно верны, но я подумал, что все это оберну в полное решение, которое я использую:

strZipFile = "test.zip"     'name of zip file
outFolder = "."             'destination folder of unzipped files (must exist)
'If using full paths rather than relative to the script, comment the next line
pwd = Replace(WScript.ScriptFullName, WScript.ScriptName, "")

Set objShell = CreateObject( "Shell.Application" )
Set objSource = objShell.NameSpace(pwd+strZipFile).Items()
Set objTarget = objShell.NameSpace(pwd+outFolder)
intOptions = 256
objTarget.CopyHere objSource, intOptions

'Clean up
Set WshShell = CreateObject("Wscript.Shell")
tempfolder = WshShell.ExpandEnvironmentStrings("%temp%")
Set fso = CreateObject("Scripting.FileSystemObject")
Call fso.DeleteFolder(tempfolder + "\Temporary Directory 1 for " + strZipFile, True )

03 дек '08 в 18:53 2008-12-03 18:53 · Answer 4 · 2008-12-03 18:53

Я добавил следующий код в начало процедуры распаковки, чтобы удалить эти каталоги перед распаковкой:

For i = 1 To 99
  If aqFileSystem.Exists(GetAppPath("Local Settings", "") & "\Temp\Temporary Directory " & i & " for DialogState.zip") = True Then
      result = aqFileSystem.ChangeAttributes(GetAppPath("Local Settings", "") & "\Temp\Temporary Directory " & i & " for DialogState.zip", 1 OR 2, aqFileSystem.fattrFree) 
      Call DelFolder(GetAppPath("Local Settings", "") & "\Temp\Temporary Directory " & i & " for DialogState.zip")  
   Else
      Exit For
   End If
Next

user28643 14 ноя '08 в 21:33 2008-11-14 21:33 · Answer 5 · 2008-11-14 21:33

http://www.experts-exchange.com/Programming/Languages/Visual_Basic/VB_Script/Q_23022290.html

Проверьте ваш временный каталог. Если у вас есть 99 папок, связанных с этим процессом разархивирования, попробуйте удалить их.

2

Источник

user28643 14 ноя '08 в 21:33