Найти элемент с самой высокой валентностью в документе XML

Question

У меня есть XML-структура, как это:

<TR>
    <Zeile status="done">
        <Typ>FUNCTION</Typ>
        <Name>PressKey</Name>
    </Zeile>
    <Zeile status="failed">
        <Typ>FUNCTION</Typ>
        <Name>PressKey</Name>
    </Zeile>
    <Zeile status="warn">
        <Typ>FUNCTION</Typ>
        <Name>PressKey</Name>
    </Zeile>
    <Zeile status="done">
        <Typ>FUNCTION</Typ>
        <Name>PressKey</Name>
    </Zeile>
</TR>

Теперь я хочу получить Элемент с худшим status,

Порядок status значения от лучшего к худшему:

done
ignoreFailed
ignoreExpected
passed
unknown
warn
failed

Как мне подойти к этому? В конце хочу худшего status как целое число в переменной с именем worst_status и как строка в переменной worst_status_string

---

Это то, что я пытался (но не удалось из-за запрещенной перезаписи переменных):

<xsl:variable name="statusMapping">
    <statusMap>
        <status key="done" value="1"/>
        <status key="ignoreFailed" value="2"/>
        <status key="ignoreExpected" value="3"/>
        <status key="passed" value="4"/>
        <status key="unknown" value="5"/>
        <status key="warn" value="6"/>
        <status key="failed" value="7"/>
    </statusMap>
</xsl:variable>




<xsl:template match="//TR">
    <xsl:variable name="worst_status" select="1"/>

    <xsl:for-each select="Zeile">
        <xsl:variable name="current_status" select="@status"/>
        <xsl:for-each select="exslt:node-set($statusMapping)/statusMap/status">
            <xsl:if test="@key = $current_status">
                <xsl:if test="@value > $worst_status">
                    <xsl:variable name="worst_status" select="@value"/>
                </xsl:if>
            </xsl:if>
        </xsl:for-each>

        WorstStatus: <xsl:value-of select="$worst_status"/>
    </xsl:for-each>
</xsl:template>

Answer 1

Сортировать и взять первое в порядке убывания:

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:exsl="http://exslt.org/common"
  exclude-result-prefixes="exsl">

<xsl:variable name="statusMapping-rtf">
        <status key="done" value="1"/>
        <status key="ignoreFailed" value="2"/>
        <status key="ignoreExpected" value="3"/>
        <status key="passed" value="4"/>
        <status key="unknown" value="5"/>
        <status key="warn" value="6"/>
        <status key="failed" value="7"/>
</xsl:variable>

<xsl:variable name="statusMapping" select="exsl:node-set($statusMapping-rtf)"/>




<xsl:template match="TR">
    <xsl:variable name="worst_status">
      <xsl:for-each select="Zeile">
          <xsl:sort select="$statusMapping/status[@key = current()/@status]/@value" data-type="number" order="descending"/>
          <xsl:if test="position() = 1">
              <xsl:value-of select="$statusMapping/status[@key = current()/@status]/@value"/>
          </xsl:if>
      </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="worst_status_string" select="$statusMapping/status[@value = $worst_status]/@key"/>

    <xsl:value-of select="concat($worst_status_string, ': ', $worst_status)"/>
</xsl:template>

</xsl:transform>

Если вам действительно нужно, чтобы одна переменная была числовым значением, добавьте <xsl:variable name="worst_status_number" select="number($worst_status)"/>,