Генерация функции заданной арности в Haskell, используя номера типов

Question

Предположим, что я закодировал натуральные числа в типах Haskell, и у меня есть способ сложения и вычитания из них:

data Zero
data Succ n
-- ...

Я видел различные фрагменты кода, которые создают внешний вид функций с переменными числами, таких как эта, что позволяет следующее:

buildList "polyvariadic" "function" "wut?" :: [String]
-- ["polyvariadic","function","wut?"]

Что мне интересно, так это то, могу ли я построить из этого функцию, которая будет принимать только количество аргументов, соответствующее экземпляру номера типа. То, что я пытаюсь сделать, выглядело бы примерно так:

one = Succ Zero
two = Succ one
three = Succ two

threeStrings :: String -> String -> String -> [String]
threeStrings = buildList three

threeStrings "asdf" "asdf" "asdf"
-- => ["asdf","asdf","asdf"]

threeStrings "asdf"
-- type checker is all HOLY CHRIST TYPE ERROR

threeStrings "asdf" "asdf" "asdf" "asdf"
-- type checker is all SWEET JESUS WHAT YOU ARE DOING

Я знаю, что это довольно глупо и что это, вероятно, пустая трата моего времени, но это казалось чем-то, что было бы весело на выходные.

Answer 1

ХОРОШО. Да. Определенно, путем потокового числового типа вокруг рекурсивных экземпляров.

Во-первых, несколько шаблонов:

{-# LANGUAGE FunctionalDependencies #-}
{-# LANGUAGE MultiParamTypeClasses  #-}
{-# LANGUAGE EmptyDataDecls         #-}
{-# LANGUAGE FlexibleInstances      #-}
{-# LANGUAGE FlexibleContexts       #-}
{-# LANGUAGE ScopedTypeVariables    #-}

Ваш нац:

data Zero
data Succ n

Рекурсивный конструктор для функций с переменным числом, теперь с аргументом n:

class BuildList n a r | r -> a where
    build' :: n -> [a] -> a -> r

Базовый случай: остановитесь, когда мы доберемся до Zero:

instance BuildList Zero a [a] where
    build' _ l x = reverse $ x:l

В противном случае уменьшите на единицу и рекурсивно:

instance BuildList n a r => BuildList (Succ n) a (a->r) where
    build' (_ :: Succ n) l x y = build' (undefined :: n) (x:l) y

Теперь мы хотим сделать цикл только 3 раза, поэтому запишите это:

build :: BuildList (Succ (Succ Zero)) a r => a -> r
build x = build' (undefined :: Succ (Succ Zero)) [] x

Готово.

Тестирование:

> build "one" "two" "three" :: [[Char]]
["one","two","three"]

Меньше или больше ошибок:

*Main> build "one" "two" "three" "four" :: [[Char]]

<interactive>:1:1:
    No instance for (BuildList Zero [Char] ([Char] -> [[Char]]))

*Main> build "one" "two" :: [[Char]]

<interactive>:1:1:
    No instance for (BuildList (Succ Zero) [Char] [[Char]])

Answer 2

Я вижу твои многопараметрические функционально-зависимые переменные типа empty-datatype с гибкой областью видимости и поднимаю тебе версию для Haskell 98! Это использует HoleyMonoid, который доступен на взломе:

{-# LANGUAGE NoMonomorphismRestriction #-}

import Prelude hiding (id, (.))
import Control.Category
import Data.HoleyMonoid

suc n = later (:[]) . n

zero  = id
one   = suc zero
two   = suc one
three = suc two

buildList = run

Тестирование (не стесняйтесь опускать подписи любого типа):

> run three "one" "two" "three"
["one","two","three"]

Answer 3

О, мой... FlexibleContexts??? NoMonomorphismRestriction??? Да ладно, ребята, разве не для этого нужны TypeFamilies?

{-# LANGUAGE TypeFamilies #-}
data Zero = Zero
newtype Succ n = Succ n
zero = Zero
one = Succ zero
two = Succ one
three = Succ two
class BuildList n where
    type BL n
    buildListPrefix :: n -> ([String] -> [String]) -> BL n
instance BuildList Zero where
    type BL Zero = [String]
    buildListPrefix Zero h = h []
instance BuildList n => BuildList (Succ n) where
    type BL (Succ n) = String -> BL n
    buildListPrefix (Succ n) h s = buildListPrefix n (h . (s:))
buildList:: BuildList n => n -> BL n
buildList n = buildListPrefix n id

Answer 4

Встраивание кода Martijn дает очень простое решение:

zero xs = xs
suc n xs x = n (xs ++ [x])
buildList n = n []