Антлр оставил рекурсивную проблему

Question

У меня есть левая рекурсивная проблема в моей грамматике Antlr. Хотя я думаю, что понимаю причину проблемы, я не могу придумать решение. Проблема связана с последней строкой для моего правила типа данных. Я включил всю грамматику, чтобы вы увидели:

grammar Test;

options {output=AST;ASTLabelType=CommonTree;}
tokens {FUNCTION; ATTRIBUTES; CHILDREN; COMPOSITE;}

program     :   function ;
function    :   ID (OPEN_BRACKET (attribute (COMMA? attribute)*)? CLOSE_BRACKET)? (OPEN_BRACE function* CLOSE_BRACE)? SEMICOLON? -> ^(FUNCTION ID ^(ATTRIBUTES attribute*) ^(CHILDREN function*)) ;

attribute   :   ID (COLON | EQUALS)  datatype -> ^(ID datatype);

datatype    :   ID      ->  ^(STRING["id"] ID)
            |   NUMBER  ->  ^(STRING["number"] NUMBER)
            |   STRING  ->  ^(STRING["string"] STRING)
            |   BOOLEAN ->  ^(STRING["boolean"] BOOLEAN)
            |   array   ->  ^(STRING["array"] array)
            |   lookup  ->  ^(STRING["lookup"] lookup)
            |   datatype PLUS datatype -> ^(COMPOSITE datatype datatype) ;

array       :   OPEN_BOX (datatype (COMMA datatype)*)? CLOSE_BOX -> datatype* ;
lookup      :   OPEN_BRACE (ID (PERIOD ID)*) CLOSE_BRACE -> ID* ;

NUMBER
    :   ('+' | '-')? (INTEGER | FLOAT)
    ;

STRING
    :  '"' ( ESC_SEQ | ~('\\'|'"') )* '"'
    ;

BOOLEAN
    :   'true' | 'TRUE' | 'false' | 'FALSE'
    ;

ID  :   (LETTER|'_') (LETTER | INTEGER |'_')*
    ;

COMMENT
    :   '//' ~('\n'|'\r')* '\r'? '\n' {$channel=HIDDEN;}
    |   '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;}
    ;

WHITESPACE  :   (' ' | '\t' | '\r' | '\n') {$channel=HIDDEN;} ;

COLON   :   ':' ;
SEMICOLON   :   ';' ;

COMMA   :   ',' ;
PERIOD  :   '.' ;
PLUS    :   '+' ;
EQUALS  :   '=' ;   

OPEN_BRACKET    :   '(' ;
CLOSE_BRACKET   :   ')' ;

OPEN_BRACE  :   '{' ;   
CLOSE_BRACE :   '}' ;

OPEN_BOX    :   '[' ;
CLOSE_BOX   :   ']' ;

fragment
LETTER
    :   'a'..'z' | 'A'..'Z' 
    ;

fragment
INTEGER
    :   '0'..'9'+
    ;

fragment
FLOAT
    :   INTEGER+ '.' INTEGER*
    ;

fragment
ESC_SEQ
    :   '\\' ('b'|'t'|'n'|'f'|'r'|'\"'|'\''|'\\')
    ;

Я занимаюсь разработкой с использованием Antlr works, которая предоставляет функцию для решения этой проблемы, но, к сожалению, она не работает:s

Любая помощь будет отличной.

Благодарю.

РЕДАКТИРОВАТЬ:

Вот пример языка, который я пытаюсь реализовать / разобрать

<FunctionName> <OptionalAttributes> <OptionalChildFunctions>

Так, например:

ForEach(in:[1,2,3,4,5] as:"i") {
  Switch(value:{i}) {
    Case(value:3) {
      Print(message:"This is the number 3")
    }

    Default {
       Print(message:"This isn't the number 3")
    }
 }
}

Answer 1

Хорошо, это должно сработать:

grammar Test;

/************************************** PARSER **************************************/
program
    :   function EOF 
    ;

function
    :   ID (OPEN_PAREN (attribute (COMMA attribute)*)? CLOSE_PAREN)?
        (OPEN_BRACE function* CLOSE_BRACE)?
        SEMICOLON?
    ;

attribute
    :   ID (COLON | EQUALS)? expression
    ;

expression
    :   atom (PLUS atom)*
    ;

atom
    :   ID
    |   STRING
    |   BOOLEAN
    |   NUMBER
    |   array
    |   lookup
    ;

array
    :   OPEN_BOX (expression (COMMA expression)*)? CLOSE_BOX
    ;

lookup
    :   OPEN_BRACE (ID (PERIOD ID)*) CLOSE_BRACE
    ;

/************************************** LEXER **************************************/
NUMBER          :   ('+' | '-')? (INTEGER | FLOAT)
                ;

STRING          :  '"' ( ESC_SEQ | ~('\\'|'"') )* '"'
                ;

BOOLEAN         :   'true' | 'TRUE' | 'false' | 'FALSE'
                ;

ID              :   (LETTER|'_') (LETTER | INTEGER |'_')*
                ;

COMMENT         :   '//' ~('\n'|'\r')* ('\r'? '\n'| EOF) {$channel=HIDDEN;}
                |   '/*' ( options {greedy=false;} : . )* '*/' {$channel=HIDDEN;}
                ;

WHITESPACE      :   (' ' | '\t' | '\r' | '\n') {$channel=HIDDEN;} ;

COLON           :   ':' ;
SEMICOLON       :   ';' ;

COMMA           :   ',' ;
PERIOD          :   '.' ;
PLUS            :   '+' ;
EQUALS          :   '=' ;   

OPEN_PAREN      :   '(' ;
CLOSE_PAREN     :   ')' ;

OPEN_BRACE      :   '{' ;   
CLOSE_BRACE     :   '}' ;

OPEN_BOX        :   '[' ;
CLOSE_BOX       :   ']' ;

fragment 
LETTER          :   'a'..'z' | 'A'..'Z' ;
fragment
INTEGER         :   '0'..'9'+ ;
fragment
FLOAT           :   INTEGER+ '.' INTEGER* ;
fragment
ESC_SEQ         :   '\\' ('b'|'t'|'n'|'f'|'r'|'\"'|'\''|'\\') ;

Обратите внимание, что я изменил имя OPEN_BRACKET а также CLOSE_BRACKET в OPEN_PAREN а также CLOSE_PAREN, Круглые, ( а также ), круглые скобки, квадратные, [ а также ], называются скобками (те, которые вы назвали блоками, но называя их блоками, не повредит IMO).