Схема бесконечной последовательности, чтобы сделать бесконечную последовательность

Question

У меня есть проект в схеме, в которой мне нужно реализовать бесконечную последовательность чисел. Я не могу использовать какие-либо встроенные в схему сложные функции, и я просто не знаю, как сделать мою последовательность бесконечной без сбоя программы в бесконечном цикле. Я не должен действительно выводить это, но я должен быть в состоянии использовать это.

(seq n)   ;;output: n,n+1,n+2,n+3.... to infinity (seq 5) ->5,6,7,8,9...

Прямо сейчас я сделал последовательность до n+7, но мне нужно это до бесконечности:

(define (seq n)
   (define (asc-order LIST counter)
     (cond ((= counter (+ n 7)) LIST)
           (else (asc-order (append LIST (cons (+ counter 1) '()))  
           (+ counter 1)))))
(asc-order '() (- n 1))
)

Пример IO (работает, но мне нужна бесконечная последовательность):

>(define s (seq 3)) 
>(car s)   
3

Answer 1

Вы можете представить бесконечную последовательность как функцию, которая производит один элемент за раз. Пользователь (потребитель) может затем вызывать функцию каждый раз, когда необходим новый элемент последовательности.

Пример:

(define (f x) (* x x))

(define seq
  (let ()
    (define n 0)        ; current index
    (lambda ()          ; the function that is to be called repeatedly
      (define a (f n))  ;   compute the new element
      (set! n (+ n 1))  ;   compute new index
      a)))              ;   return the new element

(seq)  ; compute element 0
(seq)  ; compute element 1
(seq)  ; ...
(seq)
(seq)
(seq)

Это оценивает:

0
1
4
9
16
25

Для того, чтобы написать (sequence->list s n) который вычисляет первый n элементы последовательности sсделать цикл, который вызывает s в целом n раз - и собрать результаты в виде списка.

Answer 2

Ключ заключается в том, чтобы отложить оценку списка, обернув процедуру вокруг него.

Вот самая простая реализация, о которой я могу подумать.
Это только "ленивый" в хвосте.

(define (seq n)
  (cons n (lambda () (seq (+ n 1)))))

(define (seq-car s)
  (car s))

(define (seq-cdr s)
  ((cdr s)))

Пример использования:

; Get the 'n' first elements of 's'.
(define (seq-take n s)
  (if (<= n 0)
      '()
      (cons (seq-car s) (seq-take (- n 1) (seq-cdr s)))))


> (define s (seq 10))
> s
'(10 . #<procedure>)
> (seq-take 5 s)
'(10 11 12 13 14)

Answer 3

Вот еще одно решение с использованием отложенной оценки:

(use-modules (ice-9 receive))


(define (seq f)
  (let loop ((n 0))
    (lambda ()
      (values (f n) (loop (1+ n))))))


(define squares (seq (lambda (x) (* x x))))

(receive (square next) (squares)
  (pk square) ;; => 0
  (receive (square next) (next)
    (pk square) ;; => 1
    (receive (square next) (next)
      (pk square) ;; => 4
      (receive (square next) (next)
        (pk square))))) ;; => 9