Откройте один из серии файлов, используя командный файл

Question

У меня до 4 файлов на основе этой структуры (обратите внимание, что префиксы даты)

• 0830filename.txt
• 0907filename.txt
• 0914filename.txt
• 0921filename.txt

Я хочу открыть самый последний (0921filename.txt). Как я могу сделать это в командном файле?

Благодарю.

Answer 1

Этот метод использует фактическую дату модификации файла, чтобы выяснить, какая из них является самой последней:

@echo off
for /F %%i in ('dir /B /O:-D *.txt') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

Этот метод, однако, выбирает последний файл в алфавитном порядке (или первый, в обратном алфавитном порядке), поэтому, если имена файлов совпадают - он будет работать:

@echo off
for /F %%i in ('dir /B *.txt^|sort /R') do (
    call :open "%%i"
    exit /B 0
)
:open
    start "dummy" "%~1"
exit /B 0

Вы на самом деле должны выбрать, какой метод лучше для вас.

Answer 2

Извините, что рассылаю спам на этот вопрос, но я просто очень хочу опубликовать Реальный ответ. Если вы хотите, чтобы ваш BATCH-скрипт анализировал и сравнивал даты в именах файлов, вы можете использовать что-то вроде этого:

@echo off

rem Enter the ending of the filenames.
rem Basically, you must specify everything that comes after the date.
set fn_end=filename.txt

rem Do not touch anything bellow this line.
set max_month=00
set max_day=00

for /F %%i in ('dir /B *%fn_end%') do call :check "%%i"
call :open %max_month% %max_day%
exit /B 0

:check
    set name=%~1
    set date=%name:~0,4%
    set month=%date:~0,2%
    set day=%date:~2,2%
    if /I %month% GTR %max_month% (
        set max_month=%month%
        set max_day=%day%
    ) else if /I %month% EQU %max_month% (
        set max_month=%month%
        if /I %day% GTR %max_day% (
            set max_day=%day%
        )
    )
exit /B 0

:open
    set date=%~1
    set month=%~2
    set name=%date%%month%%fn_end%
    start "dummy" "%name%"
exit /B 0

Answer 3

Один лайнер, используя трюк EXIT:

FOR /F %%I IN ('DIR *.TXT /B /O:-D') DO NOTEPAD %%I & EXIT

РЕДАКТИРОВАТЬ:

@pam: вы правы, я предполагал, что файлы были в порядке дат, но вы можете изменить команду на:

FOR /F %%I IN ('DIR *.TXT /B /O:-N') DO NOTEPAD %%I & EXIT

тогда у вас есть список файлов, отсортированный по имени в обратном порядке.

Answer 4

Вот, пожалуйста... (надеюсь, никто меня не побил...) (Вам нужно сохранить файл как lasttext.bat или что-то в этом роде). Это откроет / запустит самый старый файл.txt.

dir *.txt /b /od > systext.bak 
FOR /F %%i in (systext.bak) do set sysRunCommand=%%i 
call %sysRunCommand%
del systext.bak /Y

Вероятно, только XP. ВЗГЛЯДА Могучая сила ДОС.
Хотя для этого требуется последнее имя файла по дате, а НЕ по имени файла.

Если вы хотите получить последнее имя файла, измените / od на / on.
Если вы хотите отсортировать что-то еще, добавьте команду "sort" во вторую строку.

Answer 5

Используйте регулярное выражение, чтобы разобрать соответствующее целое число и сравнить их.