Android Gradle Protobufs: как скомпилировать полный protobuf, а не "облегченную" версию?

Question

Каждый пример настройки build.gradle для компиляции protobufs использует версию "lite" и выглядит примерно так:

protobuf {
    protoc {
        artifact = 'com.google.protobuf:protoc:3.6.0'
    }
    plugins {
        javalite {
            artifact = 'com.google.protobuf:protoc-gen-javalite:3.0.0'
        }
    }
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                remove java
            }
            task.plugins {
                javalite { }
            }
        }
    }
}

dependencies {
    implementation 'com.google.protobuf:protobuf-java:3.6.0'
    implementation fileTree(dir: 'libs', include: ['*.jar'])
    implementation 'com.android.support:appcompat-v7:28.0.0'
    implementation 'com.android.support:support-v4:28.0.0'
    implementation 'com.android.support:design:28.0.0'
    implementation 'com.android.support.constraint:constraint-layout:1.1.3'
    testImplementation 'junit:junit:4.12'
    androidTestImplementation 'com.android.support.test:runner:1.0.2'
    androidTestImplementation 'com.android.support.test.espresso:espresso-core:3.0.2'
}

Обратите внимание на " javalite ". В результате создаются сгенерированные Java-файлы, которые используют MessageLite, но мне нужен полный класс Message.

Как я могу изменить это, чтобы он не генерировал "облегченную" версию?

Answer 1

Нашел решение:

1) Удалить это:

plugins {
    javalite {
        artifact = 'com.google.protobuf:protoc-gen-javalite:3.0.0'
    }
}

2) Удалить это:

task.plugins {
    javalite { }
}

3) Измените раздел task.builtins на этот:

task.builtins {
    java { }
}

Теперь он будет генерировать полнофункциональные протобуфы.