Группы смежных узлов с помощью xslt

Я знаю, что вопросы, касающиеся функции смежности с группой, уже задавались. По какой-то причине я не могу заставить это работать.

Я унаследовал проект на работе, который использует xslt, и мой начальник не понимает, насколько крута кривая обучения для изучения xslt и насколько она отличается от процедурного программирования.

Тем не менее я полон решимости выучить это так хорошо, как только смогу, но мне все равно придется с этим работать, пока я учусь. Любая помощь в решении нижеприведенной проблемы будет чрезвычайно признательна.

У меня есть документ XML, который отформатирован так:

<document xml:lang="EN">
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <Section/> <!--section marker-->
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <TOCChap>chapter title</TOCChap>
  <TOCAu>chapter author</TOCAu>
  <Section/> <!--section marker-->
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
</document>

В настоящее время у него практически нет иерархии, и маркеры включены для придания ему структуры и включены в файл. Я пытаюсь сгруппировать все элементы оглавления и вложить их в содержащий элемент:

<document xml:lang="EN">
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <CRPg>text</CRPg>
  <Section/> <!--section marker-->
  <Wrapper> <!-- create new element to wrap around TOC and TOCAuth -->
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
   <TOCChap>chapter title</TOCChap>
   <TOCAu>chapter author</TOCAu>
  </Wrapper>
  <Section/> <!--section marker-->
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
  <Txt>body text</Txt>
</document>

Это оказывается сложнее, чем я ожидал. Я пробовал много разных версий приведенного ниже кода, и я вставил в ту, которая кажется наименее неправильной. Я понимаю, что это все еще довольно плохо

<xsl:template match="*">
<xsl:for-each-group select="TOCChap | TOCAuth" group-adjacent="self::TOCChap | self::TOCAuth">
  <xsl:choose>
    <xsl:when test="current-grouping-key()">
      <wrapper>
        <xsl:apply-templates select="current-group()"/>

      </wrapper>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates select="current-group()"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:for-each-group>

Заранее спасибо.

Источник

3 ответа

Решение

Есть три причины, по которым ваша попытка не работает:

  1. Вы выбираете неправильный набор узлов;

  2. Вы используете оператор объединения | вместо логического оператора or;

  3. Там нет элемента с именем TOCAuth в вашем документе.

Как только вы исправите эти три проблемы, изменив инструкцию на:

<xsl:for-each-group select="*" group-adjacent="self::TOCChap or self::TOCAu">

вы увидите именно тот результат, который вы ищете - смотрите полную демонстрацию здесь: http://xsltransform.net/jyH9rME

-
Кстати, ваш случай почти точно совпадает с примером, приведенным в спецификации XSLT 2.0 для использования group-adjacent - см. последний пример здесь: http://www.w3.org/TR/xslt20/

PS

Я не могу не задаться вопросом, почему вы не пользуетесь <Section/> маркеры для размещения всех ваших групп внутри оболочки - например, применяя:

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/document">
    <xsl:copy>
        <xsl:apply-templates select="@*" />
        <xsl:for-each-group select="*" group-starting-with="Section">
            <wrapper>
                <xsl:apply-templates select="current-group()" />
            </wrapper>  
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

<xsl:template match="Section"/>

</xsl:stylesheet>

на ваш вклад приведет:

:<?xml version="1.0" encoding="utf-8"?>
<document xml:lang="EN">
   <wrapper>
      <CRPg>text</CRPg>
      <CRPg>text</CRPg>
      <CRPg>text</CRPg>
   </wrapper>
   <wrapper>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
      <TOCChap>chapter title</TOCChap>
      <TOCAu>chapter author</TOCAu>
   </wrapper>
   <wrapper>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
      <Txt>body text</Txt>
   </wrapper>
</document>
Источник

Вам нужен XSLT что-то вроде этого (если нет иерархии):

<xsl:stylesheet version="2.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="node() | @*">
        <xsl:copy>
            <xsl:apply-templates select="@* , node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/*">
        <xsl:copy>
            <xsl:attribute name="xml:lang">EN</xsl:attribute>
            <xsl:for-each-group select="*" group-adjacent="name() = ('TOCChap','TOCAu')">
                <xsl:choose>
                    <xsl:when test="current-grouping-key()">
                        <Wrapper>
                            <xsl:apply-templates select="current-group()"/>
                        </Wrapper>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="current-group()"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>
Источник 

<xsl:template match="document">
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:for-each-group select="*" group-adjacent="boolean(self::TOCChap | self::TOCAu)">
            <xsl:choose>
                <xsl:when test="current-grouping-key()">
                    <wrapper>
                        <xsl:apply-templates select="current-group()"/>
                    </wrapper>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="current-group()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each-group>
    </xsl:copy>

</xsl:template>
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

Источник
Другие вопросы по тегам