Эффективный предикат для палиндрома в миницинке

Question

Чтобы помочь мне изучить Minizinc, я пытаюсь решить легкую проблему. Мой код находит ответ, но я удивлен, что для такой простой задачи требуется около 10 секунд.

Проблема в том, "Какое наименьшее палиндромное целое число> 10, так что сумма его цифр> 10 и палиндромная тоже?". И я хочу, чтобы код делал только большие предположения: ответ имеет максимум 8 цифр.

Мой код (предикат toNum взят с сайта hakank):

predicate toNum(array[int] of var int: a, var int: n,  int: base) =
          let { int: len = length(a) }
          in
          n = sum(i in 1..len) (
            ceil(pow(int2float(base), int2float(len-i))) * a[i]
          )
          /\ forall(i in 1..len) (a[i] >= 0 /\ a[i] < base)
;

predicate toNum10(array[int] of var 0..9: a, var int: n) = toNum(a, n, 10);

predicate palindrome_array(array[int] of var int: t) =
   let { int: l = length(t), var 1..l: d } in (
   forall(j in 1..d-1) (t[j] = 0) /\
   t[d] != 0 /\
   forall(j in d..(l+d-1) div 2) (t[j] = t[l+d-j])
   )
;
predicate palindrome_int(var int: n) =
   let { int: size = ceil(log10(int2float(ub(n))))+1,
         array[1..size] of var 0..9: digits } in (
   toNum10(digits, n) /\
   palindrome_array(digits)
   )
;

var int: n;
array[1..8] of var 0..9: t;
constraint toNum10(t, n);
constraint palindrome_int(n);
constraint n>10;  
var int: s = sum(t);
constraint palindrome_int(s);
constraint s>10;
constraint alldifferent([n, s]);
solve minimize n;

Полная версия имеет следующие дополнительные ограничения:

var int: s2 = sum(i in 1..8) (t[i]*t[i]);
constraint palindrome_int(s2);
constraint s2 > 10;

var int: s3 = sum(i in 1..8) (t[i]*t[i]*t[i]);
constraint palindrome_int(s3);
constraint s3 > 10;

constraint alldifferent([n, s, s2, s3]);

Что не так / медленно с моим кодом?

Answer 1

Попробуйте заменить "решить свести к минимуму;" со следующей стратегией маркировки:

solve :: int_search(t, first_fail, indomain_min, complete) minimize n;

На моей машине это занимает < 0.1с.