Как сделать логический или в CLIPS?

Question

Обновленный код: где добавить чек для ?f<-(practice-is-on-off OFF)

 (defrule no-practice "Rules for when practice cannot be held"

        (or ?f <- (practice (number-of-paddlers ?p&:(< ?p 6)))
            ?f <- (practice (number-of-coaches ?c&:(< ?c 1))))

        =>
        (modify ?f (practice-is-on-off OFF)))

    ;end

---

Я определяю шаблон в CLIPS и использую логический оператор OR. Однако, когда я загружаю шаблон, он выдает ошибку, говорящую

[TMPLTDEF1] Invalid slot or not defined in corresponding deftemplate practice.

ERROR:
(defrule MAIN::no-practice "Rules for when practice cannot be held"
   ?f <- (practice (or

Вот что у меня есть: заранее спасибо за понимание. Спасибо

(deftemplate practice "structure of a practice"

    (slot number-of-paddlers (type NUMBER))
    (slot number-of-coaches (type NUMBER))
    (slot practice-is-on-off (type SYMBOL) (default ON))
    (slot practice-id (type NUMBER))

)


(defrule no-practice "Rules for when practice cannot be held"
    ?f <- (practice 
    (or
            (number-of-paddlers
                ?v_number-of-paddlers&:(
                    < ?v_number-of-paddlers 6))

            (number-of-coaches
                ?v_number-of-coaches&:(
                    < ?v_number-of-coaches 1))

    )
    )

    =>
        (modify ?f (practice-is-on-off OFF)
        )
)

Answer 1

Ошибка говорит вам, что вы пытаетесь сопоставить слот с именем "или" в practice deftemplate и этот слот не существует. Вот две альтернативные версии правила "не практиковать", которое выполнит то, что вы пытаетесь сделать:

Версия 1:

(defrule no-practice "Rules for when practice cannot be held"
    (or ?f <- (practice (practice-is-on-off ON)
                        (number-of-paddlers ?p&:(< ?p 6)))
        ?f <- (practice (practice-is-on-off ON)
                        (number-of-coaches ?c&:(< ?c 6))))
    =>
    (modify ?f (practice-is-on-off OFF)))

Обратите внимание, что правило выше может срабатывать дважды для practice если вы не проверите это practice-is-on-off включен в CE.

Версия 2:

(defrule no-practice "Rules for when practice cannot be held"
    ?f <- (practice (practice-is-on-off ON)
                    (number-of-paddlers ?p) (number-of-coaches ?c))
    (test (or (< ?p 6) (< ?c 6)))
    =>
    (modify ?f (practice-is-on-off OFF)))