Inno Setup: Как автоматически удалить предыдущую установленную версию?
Я использую Inno Setup для создания установщика.
Я хочу, чтобы установщик автоматически удалял предыдущую установленную версию, а не перезаписывал ее. Как я могу это сделать?
13 ответов
Вы должны быть в состоянии прочитать строку удаления из реестра, учитывая AppId (т.е. значение, которое вы использовали для AppID в [Setup]-раздел). Это можно найти под Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\ (может быть HKLM или же HKCUтак что лучше всего проверить оба) где {AppId} должно быть заменено фактическим значением, которое вы использовали. Ищите UninstallString или же QuietUninstallString значения и использовать Exec функция, чтобы запустить его из вашего InitializeSetup() функция события.
Обновление: удалено нерабочее альтернативное решение с использованием [Run]вход с {uninstallexe} - Спасибо всем комментаторам, которые указали на это!
Я использовал следующее. Я не уверен, что это самый простой способ сделать это, но это работает.
Это использует {#emit SetupSetting("AppId")} который опирается на препроцессор установки Inno. Если вы не используете это, скопируйте и вставьте свой идентификатор приложения напрямую.
[Code]
/////////////////////////////////////////////////////////////////////
function GetUninstallString(): String;
var
sUnInstPath: String;
sUnInstallString: String;
begin
sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
sUnInstallString := '';
if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
Result := sUnInstallString;
end;
/////////////////////////////////////////////////////////////////////
function IsUpgrade(): Boolean;
begin
Result := (GetUninstallString() <> '');
end;
/////////////////////////////////////////////////////////////////////
function UnInstallOldVersion(): Integer;
var
sUnInstallString: String;
iResultCode: Integer;
begin
// Return Values:
// 1 - uninstall string is empty
// 2 - error executing the UnInstallString
// 3 - successfully executed the UnInstallString
// default return value
Result := 0;
// get the uninstall string of the old app
sUnInstallString := GetUninstallString();
if sUnInstallString <> '' then begin
sUnInstallString := RemoveQuotes(sUnInstallString);
if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
Result := 3
else
Result := 2;
end else
Result := 1;
end;
/////////////////////////////////////////////////////////////////////
procedure CurStepChanged(CurStep: TSetupStep);
begin
if (CurStep=ssInstall) then
begin
if (IsUpgrade()) then
begin
UnInstallOldVersion();
end;
end;
end;
альтернативы
См. Также этот пост в блоге "Образец сценария установки Inno для сравнения версий", в котором идет еще один шаг вперед, читается номер версии любой ранее установленной версии и сравнивается этот номер версии с номером текущего установочного пакета.
Если вы "просто хотите удалить старые значки" (потому что ваши изменились / обновились), вы можете использовать это:
; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;
Он запускается "в начале установки", поэтому в основном удаляет старые значки, и ваши новые будут по-прежнему устанавливаться там после того, как это будет полностью сделано.
Я просто делаю это с каждой установкой "на случай, если что-то изменилось", значок мудрый (все равно переустанавливается).
При использовании Inno Setup нет причин удалять предыдущую версию, если только эта версия не была установлена другой программой установки. В противном случае обновления обрабатываются автоматически.
Вот упрощенная версия, основанная на ответе Крейга Маккуина :
const
UninstallRegisterPath = 'Software\Microsoft\Windows\CurrentVersion\Uninstall\' + '{#emit SetupSetting("AppName")}' + '_is1';
function GetUninstallerPath(): String;
begin
result := '';
if (not RegQueryStringValue(HKLM, UninstallRegisterPath, 'UninstallString', result)) then
RegQueryStringValue(HKCU, UninstallRegisterPath, 'UninstallString', result);
end;
procedure UninstallOldVersion();
var
UninstallerPath: String;
ResultCode: Integer;
begin
UninstallerPath := GetUninstallerPath();
if (UninstallerPath <> '') then begin
Exec(UninstallerPath, '/VERYSILENT /NORESTART /SUPPRESSMSGBOXES', '', SW_HIDE, ewWaitUntilTerminated, ResultCode);
end;
end;
procedure CurStepChanged(CurStep: TSetupStep);
begin
if (CurStep = ssInstall) then
begin
UninstallOldVersion();
end;
end;
Примечание: в моем случае я использую
AppName вместо того
AppId.
Ответ, предоставленный Крейгом МакКуином, полностью жизнеспособен. Хотя я бы добавил эти комментарии:
{#emit SetupSetting("AppId")}код не работает для меня, поэтому я просто добавляю свой идентификатор приложения.- Я не хотел запускать свою программу удаления, потому что у меня есть файл конфигурации INI, сохраненный в папке AppData/, который удаляется программой удаления, и я не хочу, чтобы он удалялся при установке новой версии. Итак, я немного изменил код, предоставленный Крейгом МакКуином, чтобы удалить каталог, в котором установлена программа, после получения ее пути.
Итак, что касается кода Крейга МакКуина, изменения таковы:
- Получить
InstallLocationключ вместоUninstallStringключ. - Использовать
DelTreeфункция вместоExec(sUnInstallString, ...)
Для тех, кто заинтересован, я написал DLL для Inno Setup 6 и более поздних версий, которая предоставляет простой механизм для поддержки автоматического удаления.
DLL предоставляет способ определить, установлен ли уже устанавливаемый вами пакет (через
AppId) и решить на основе установленной версии, хотите ли вы автоматически удалить ее (например, вы можете захотеть автоматически удалить ее, если пользователь переходит на более раннюю версию).
Я отредактировал код @Crain Mc-Queen, я думаю, что этот код лучше, потому что не нужно изменять в другом проекте:
[Code]
function GetNumber(var temp: String): Integer;
var
part: String;
pos1: Integer;
begin
if Length(temp) = 0 then
begin
Result := -1;
Exit;
end;
pos1 := Pos('.', temp);
if (pos1 = 0) then
begin
Result := StrToInt(temp);
temp := '';
end
else
begin
part := Copy(temp, 1, pos1 - 1);
temp := Copy(temp, pos1 + 1, Length(temp));
Result := StrToInt(part);
end;
end;
function CompareInner(var temp1, temp2: String): Integer;
var
num1, num2: Integer;
begin
num1 := GetNumber(temp1);
num2 := GetNumber(temp2);
if (num1 = -1) or (num2 = -1) then
begin
Result := 0;
Exit;
end;
if (num1 > num2) then
begin
Result := 1;
end
else if (num1 < num2) then
begin
Result := -1;
end
else
begin
Result := CompareInner(temp1, temp2);
end;
end;
function CompareVersion(str1, str2: String): Integer;
var
temp1, temp2: String;
begin
temp1 := str1;
temp2 := str2;
Result := CompareInner(temp1, temp2);
end;
function InitializeSetup(): Boolean;
var
oldVersion: String;
uninstaller: String;
ErrorCode: Integer;
vCurID :String;
vCurAppName :String;
begin
vCurID:= '{#SetupSetting("AppId")}';
vCurAppName:= '{#SetupSetting("AppName")}';
//remove first "{" of ID
vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
//
if RegKeyExists(HKEY_LOCAL_MACHINE,
'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
begin
RegQueryStringValue(HKEY_LOCAL_MACHINE,
'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
'DisplayVersion', oldVersion);
if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then
begin
if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
mbConfirmation, MB_YESNO) = IDYES then
begin
Result := False;
end
else
begin
RegQueryStringValue(HKEY_LOCAL_MACHINE,
'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
'UninstallString', uninstaller);
ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
Result := True;
end;
end
else
begin
MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
mbInformation, MB_OK);
Result := False;
end;
end
else
begin
Result := True;
end;
end;
Для тех, кто использует GetUninstallString() предложенный выше, чтобы вызвать удаление внутри CurStepChanged() и имеет проблемы с кэшированием на диске, см. ниже соответствующее решение, которое фактически ждет некоторое время после удаления деинсталлятора exe для удаления!
Вы можете выполнить деинсталлятор в разделе [code]. Вы должны выяснить, как получить путь к существующей программе удаления. Для простоты, когда я устанавливаю свои приложения, я добавляю значение строки реестра, которое указывает на папку, содержащую деинсталлятор, и просто запускаю деинсталлятор в обратном вызове InitializeWizard.
Имейте в виду, что имена деинсталляторов Inno setup имеют форму uninsnnn.exe, это необходимо учитывать в своем коде.
Я должен что-то упустить. Новые файлы копируются в целевой каталог перед удалением старой установки.Затем приходит программа удаления, удаляет их и удаляет каталог.
Перейдите по этой ссылке: http://news.jrsoftware.org/news/innosetup/msg55323.html
В функции InitializeSetup() вы можете вызвать "MSIEXEC /x {идентификатор вашей программы}" после того, как пользователь предложит удалить старую старую версию
Не используйте раздел [Run], но [UninstallRun]. На самом деле, программа под [Выполнить] выполняется после установки, в результате чего ваша программа удаляется сразу после установки:-| Вместо этого раздел [UninstallRun] оценивается перед установкой.