Delphi: как рисовать маленькие значки в виде списка на CustomDrawItem

Question

Как расширить этот код: ListView в режиме vsReport раскраски элементов и строк, чтобы нарисовать маленькие значки?

и почему у меня есть ошибка "Индекс списка вне границ (2)", если у меня есть 3 столбца?

Спасибо!

Answer 1

Существует множество способов рисования значков, в зависимости от того, откуда они появляются (файл, ресурс, значок системы и т. Д.), И в зависимости от того, должен ли быть один значок для всех элементов или если у каждого элемента есть свой значок., В любом случае, общая идея должна быть ясна из этой расширенной версии кода в предыдущем вопросе (и я также исправил ошибку "за пределами"...):

type
  TForm1 = class(TForm)
  ...
  private
    { Private declarations }
    bm: TBitmap;
  ...
  end;

...

implementation

...

procedure TForm1.FormCreate(Sender: TObject);
begin
  bm := TBitmap.Create;
  bm.LoadFromFile('C:\Users\Andreas Rejbrand\Desktop\img.bmp');
end;

procedure TForm1.ListView1DrawItem(Sender: TCustomListView; Item: TListItem;
  Rect: TRect; State: TOwnerDrawState);
var
  i: Integer;
  x1, x2: integer;
  r: TRect;
  S: string;
const
  DT_ALIGN: array[TAlignment] of integer = (DT_LEFT, DT_RIGHT, DT_CENTER);
begin
  if Odd(Item.Index) then
  begin
    Sender.Canvas.Font.Color := clBlack;
    Sender.Canvas.Brush.Color := $F6F6F6;
  end
  else
  begin
    Sender.Canvas.Font.Color := clBlack;
    Sender.Canvas.Brush.Color := clWhite;
  end;
  Sender.Canvas.Brush.Style := bsSolid;
  Sender.Canvas.FillRect(Rect);
  x1 := 0;
  x2 := 0;
  r := Rect;
  Sender.Canvas.Brush.Style := bsClear;
  Sender.Canvas.Draw(3, r.Top + (r.Bottom - r.Top - bm.Height) div 2, bm);
  for i := 0 to ListView1.Columns.Count - 1 do
  begin
    inc(x2, ListView1.Columns[i].Width);
    r.Left := x1;
    r.Right := x2;
    if i = 0 then
    begin
      S := Item.Caption;
      r.Left := bm.Width + 6;
    end
    else
      S := Item.SubItems[i - 1];
    DrawText(Sender.Canvas.Handle,
      S,
      length(S),
      r,
      DT_SINGLELINE or DT_ALIGN[ListView1.Columns[i].Alignment] or
        DT_VCENTER or DT_END_ELLIPSIS);
    x1 := x2;
  end;
end;

http://privat.rejbrand.se/TListViewCustomDrawIcon.png