AS3 - Масштабирование BitmapData

Question

Я хотел бы масштабировать BitmapData до различных размеров, таких как 200, 400, 600 и 800.

Какой хороший способ сделать это?

Answer 1

Вы не можете напрямую масштабировать BitmapData но вы можете сделать его масштабным клоном. Вот быстрый пример для масштабирования BitmapData:

package {
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.geom.Matrix;

import mx.core.BitmapAsset;

public class Test extends Sprite {


    [Embed(source="test.jpg")]
    private var Image:Class;

    public function Test() {

        var originalBitmapData:BitmapData = BitmapAsset(new Image()).bitmapData;

        function scaleBitmapData(bitmapData:BitmapData, scale:Number):BitmapData {
            scale = Math.abs(scale);
            var width:int = (bitmapData.width * scale) || 1;
            var height:int = (bitmapData.height * scale) || 1;
            var transparent:Boolean = bitmapData.transparent;
            var result:BitmapData = new BitmapData(width, height, transparent);
            var matrix:Matrix = new Matrix();
            matrix.scale(scale, scale);
            result.draw(bitmapData, matrix);
            return result;
        }

        var bitmapA:Bitmap = new Bitmap(originalBitmapData);
        addChild(bitmapA);

        var bitmapB:Bitmap = new Bitmap(scaleBitmapData(originalBitmapData, 0.5));
        addChild(bitmapB);

    }
}
}

Answer 2

Установка ширины и высоты растрового объекта масштабирует это изображение, поэтому создайте растровое изображение с помощью bitmapData, затем масштабируйте его с использованием ширины / высоты или используйте scaleX/Y, если вы хотите использовать значения масштабирования.

var bmp:Bitmap = new Bitmap(bmpData);
bmp.width = 400; //  or 600,800 etc.
bmp.height = 400;

Если вы не хотите использовать растровый объект и напрямую масштабировать BitmapData, посмотрите это. Каков наилучший способ изменить размер объекта BitmapData?