Подпишитесь на устройство Mindsphere IoTExtension с помощью MQTT

Question

Я работаю над небольшим проектом в демонстрационных целях.

Я использую ESP8266 публиковать данные в расширение IoT с помощью MQTT функциональность, как описано здесь. Я публикую в теме s/us, и она отлично работает.

Теперь я хочу другой ESP8266 подписаться на тот же канал.

Это возможно? Если да, то как правильно это сделать? Я уже пытался подписаться на тему s/us (используя arduino pubsubclient lib) но это не работает, и я не могу найти какую-либо информацию по этому вопросу.

Вот запрашиваемый код:

#include <ESP8266WiFi.h>
#include <PubSubClient.h>

const char* ssid = "ssid";
const char* password = "Password"; 

const char* mqtt_Server = "mciotextension.eu-central.mindsphere.io";
const int mqtt_Port = 1883;
const char* mqtt_user = "User";
const char* mqtt_password = "Password";

WiFiClient espClient;
PubSubClient client(espClient);

void callback(char* topic, byte* payload, unsigned int length) {

  Serial.print("Message arrived in topic: ");
  Serial.println(topic);

  Serial.print("Message:");
  for (int i = 0; i < length; i++) {
    Serial.print((char)payload[i]);
  }

  Serial.println();
  Serial.println("-----------------------");

}

void reconnect() {
  // Loop until reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    String clientId = "0da4cfbb-4ea2-488d-8a89-739ec04acf1e";
    // Attempt to connect
    if (client.connect(clientId.c_str(), mqtt_user, mqtt_password)) {
      Serial.println("connected");
    } else {
      Serial.print("failed, rc= ");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      delay(5000);
    }
  }
}


void setup() {

  Serial.begin(115200);
  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Connecting to WiFi..");
  }
  Serial.println("Connected to WiFi network");

  client.setServer(mqtt_Server, mqtt_Port);
  reconnect();
  client.setCallback(callback);
  client.subscribe("s/us"); //I also tryed s/ds

}

void loop() {
  client.loop();
  delay(1000);
  reconnect();
}   

Answer 1

Теперь я хочу, чтобы другой ESP8266 подписался на тот же канал.

Это возможно?

Да, вы можете подтвердить правильность настройки клиента публикации и посредника, подключив автономный клиент MQTT, работающий на вашем ПК. Затем клиент MQTT подписывается на канал.

Ваш код подписки имеет как минимум одну потенциальную проблему. Подписывается только на тему самого первого подключения к брокеру. Соединение PubSubClient по умолчанию будет использовать Чистый сеанс - любые предыдущие подписки не сохраняются, когда клиент отключается и повторно подключается.

Таким образом, если подписчик теряет свое первоначальное соединение с брокером, он не будет подписан на тему о последующих соединениях.

Это можно исправить, переместив код подписки в функцию переподключения, как показано во фрагменте ниже.

  if (client.connect(clientId.c_str(), mqtt_user, mqtt_password)) {
    Serial.println("connected");
    client.subscribe("s/us");
  } else {

Я бы также рекомендовал вам вызвать setCallback() до первого подключения в настройке. например, в setup()

  client.setServer(mqtt_Server, mqtt_Port);
  client.setCallback(callback);
  reconnect();