Как улучшить использование Delphi Frames

Question

Как улучшить использование Delphi Frames

Я использовал фреймы в Delphi в течение многих лет, и они являются одной из самых мощных функций VCL, но стандартное использование их, похоже, имеет некоторый риск, такой как:

Легко случайно переместить или отредактировать подкомпоненты фрейма в форме хоста фрейма, не осознавая, что вы "настраиваете" фрейм - я знаю, что это не влияет на исходный код фрейма, но обычно это не то, что вы хотели бы.
При работе с фреймом вы по-прежнему получаете доступ к его подкомпонентам для визуального редактирования, даже если этому фрейму уже несколько лет, и его не следует трогать.

Вот я и подумал....

Есть ли способ "сгруппировать" компоненты так, чтобы их позиции были "заблокированы"? Это было бы полезно для готовых форм, а также фреймов. Часто другие разработчики возвращают мне код, где изменились только границы формы, и даже они не намеревались ничего менять.
Есть ли способ превратить рамку и ее компоненты в один компонент Delphi? Если это так, внутренняя часть рамы будет полностью скрыта, и ее применимость еще больше возрастет.

Мне интересны любые мысли...

Брайан.

26

delphi components tframe

Источник

user47012 29 апр '10 в 07:40

5 ответов

Решение

Да, просто зарегистрируйте их как компоненты.:-)

Создайте свой фрейм нормально и после этого зарегистрируйте его. Также убедитесь, что у вас нет нежелательных зависимостей от разных модулей, так как они связаны, когда используется ваш "компонент". Также вы можете добавить published свойства, чтобы использовать их в инспекторе объектов позже. Посмотрите, например, следующий код, сгенерированный IDE (см. Также мои комментарии):

unit myUnit;

uses
 ...

type
  TmyComp = class(TFrame) //set your frame name to be the name your component 
    ToolBar1: TToolBar; //different components added in the form designer
    aliMain: TActionList;
    ...
  published //this section is added by hand
    property DataSource: TDataSource read FDataSource write SetDataSource; //some published properties added just for exemplification
    property DefFields: string read FDefFields write SetDefFields;
    ...
  end;


procedure Register; //added by hand

implementation

{$R *.DFM}

procedure Register;
begin
  RegisterComponents('MyFrames', [TmyComp]); //register the frame in the desired component category
end;

Скомпилируйте все вышеперечисленное в выбранный вами пакет, установите его и проверьте палитру компонентов.:-)

НТН

19

Источник

user22599 29 апр '10 в 08:28

Я почти всегда создаю фреймы в коде. Это легко и хорошо сработало для меня до сих пор.

9

Источник

user1431618 29 апр '10 в 08:21

Просто для увеличения вклада, обратите внимание, что если вы идете в Structure щелкните правой кнопкой мыши имя TFrame, которое вы выбрали, и нажмите на Add to Palete опция меню. Это сделает компонент из вашей рамки, и вам не нужно создавать какие-либо Register процедура.;-)

8

Источник

user1062933 04 июл '12 в 03:01

Я также столкнулся с этой проблемой при попытке использовать кадры в качестве компонентов. Существуют различные возможности для устранения очевидных проблем, но все они подрывают принцип сокрытия информации (все подкомпоненты фрейма представлены в виде опубликованных свойств, что означает, что каждый может получить к ним доступ).

Я решил это путем реализации общего компонента управления кадрами:

unit RttiBrow.Cbde.FrameControl;

interface

uses
  Classes, Controls, Forms, Messages, ExtCtrls;

type
  TFrameClass = class of TFrame;

  TComponentFrame = class (TFrame)
  private
    function GetClientHeight: Integer;
    function GetClientWidth: Integer;
    procedure SetClientHeight(const Value: Integer);
    procedure SetClientWidth(const Value: Integer);
    function GetOldCreateOrder: Boolean;
    procedure SetOldCreateOrder(const Value: Boolean);
    function GetPixelsPerInch: Integer;
    procedure SetPixelsPerInch(const Value: Integer);
    function GetTextHeight: Integer;
    procedure SetTextHeight(const Value: Integer);
  published
    { workarounds for IDE bug }
    property ClientWidth: Integer read GetClientWidth write SetClientWidth stored False;
    property ClientHeight: Integer read GetClientHeight write SetClientHeight stored False;
    property OldCreateOrder: Boolean read GetOldCreateOrder write SetOldCreateOrder stored False;
    property PixelsPerInch: Integer read GetPixelsPerInch write SetPixelsPerInch stored False;
    property TextHeight: Integer read GetTextHeight write SetTextHeight stored False;
  end;

  TComponentFrame<TFrameControl: class { TControl }> = class (TComponentFrame)
  private
    function GetController: TFrameControl; inline;
  protected
    property Controller: TFrameControl read GetController;
  public
    constructor Create (AOwner: TComponent); override;
  end;

  TFrameControl<T: TFrame> = class (TWinControl)
  private
    FFrame: T;
    function PlainFrame: TFrame;
  protected
    procedure CreateParams (var Params: TCreateParams); override;
    property Frame: T read FFrame;
  public
    constructor Create (AOwner: TComponent); override;
    property DockManager;
  published
    property Align;
    property Anchors;
    property BiDiMode;
    property Color;
    property Constraints;
    property Ctl3D;
    property UseDockManager default True;
    property DockSite;
    property DoubleBuffered;
    property DragCursor;
    property DragKind;
    property DragMode;
    property Enabled;
    property Font;
    property ParentBiDiMode;
    property ParentBackground;
    property ParentColor;
    property ParentCtl3D;
    property ParentDoubleBuffered;
    property ParentFont;
    property ParentShowHint;
    property ShowHint;
    property TabOrder;
    property TabStop;
    property Touch;
    property Visible;
    property OnAlignInsertBefore;
    property OnAlignPosition;
    property OnCanResize;
    property OnConstrainedResize;
    property OnDockDrop;
    property OnDockOver;
    property OnDragDrop;
    property OnDragOver;
    property OnEndDock;
    property OnEndDrag;
    property OnEnter;
    property OnExit;
    property OnGesture;
    property OnGetSiteInfo;
    property OnMouseActivate;
    property OnMouseDown;
    property OnMouseEnter;
    property OnMouseLeave;
    property OnMouseMove;
    property OnMouseUp;
    property OnResize;
    property OnStartDock;
    property OnStartDrag;
    property OnUnDock;
  end;


implementation

uses
  Windows;

{ TFrameControl<T> }

constructor TFrameControl<T>.Create(AOwner: TComponent);
begin
  inherited;
  FFrame := T (TFrameClass (T).Create (Self));
  PlainFrame.Parent := Self;
  PlainFrame.Align := alClient;
end;

procedure TFrameControl<T>.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.Style := Params.Style or WS_CLIPCHILDREN;
  Params.ExStyle := Params.ExStyle or WS_EX_CONTROLPARENT;
end;

function TFrameControl<T>.PlainFrame: TFrame;
begin
  Result := FFrame; // buggy compiler workaround
end;


{ TComponentFrame }

function TComponentFrame.GetOldCreateOrder: Boolean;
begin
  Result := False;
end;

function TComponentFrame.GetPixelsPerInch: Integer;
begin
  Result := 0;
end;

function TComponentFrame.GetTextHeight: Integer;
begin
  Result := 0;
end;

procedure TComponentFrame.SetClientHeight(const Value: Integer);
begin
  Height := Value;
end;

procedure TComponentFrame.SetClientWidth(const Value: Integer);
begin
  Width := Value;
end;

procedure TComponentFrame.SetOldCreateOrder(const Value: Boolean);
begin
end;

procedure TComponentFrame.SetPixelsPerInch(const Value: Integer);
begin
end;

procedure TComponentFrame.SetTextHeight(const Value: Integer);
begin
end;

function TComponentFrame.GetClientHeight: Integer;
begin
  Result := Height;
end;

function TComponentFrame.GetClientWidth: Integer;
begin
  Result := Width;
end;


{ TComponentFrame<TFrameControl> }

constructor TComponentFrame<TFrameControl>.Create(AOwner: TComponent);
begin
  inherited;
  Assert (AOwner <> nil);
  Assert (AOwner.InheritsFrom (TFrameControl));
end;

function TComponentFrame<TFrameControl>.GetController: TFrameControl;
begin
  Result := TFrameControl (Owner);
end;


end.

С помощью этого класса добавление фрейма в качестве компонента становится двухэтапным процессом:

  // frame unit
type
  TFilteredList = class;

  TFrmFilteredList = class (TComponentFrame<TFilteredList>)
    // lots of published sub-components and event methods like this one:
    procedure BtnFooClick(Sender: TObject);
  end;

  TFilteredList = class (TFrameControl<TFrmFilteredList>)
  private
    procedure Foo;
  public
    // the component's public interface
  published
    // the component's published properties
  end;

procedure Register;
...
procedure Register;
begin
  RegisterComponents ('CBDE Components', [TFilteredList]);
end;

procedure TFrmFilteredList.BtnFooClick(Sender: TObject);
begin
  Controller.Foo;
end;

procedure TFilteredList.Foo;
begin
end;
...

При использовании этого подхода пользователь вашего компонента не будет видеть ваши подкомпоненты.

4

Источник

user80565 29 апр '10 в 13:05

Другие вопросы по тегам delphi components tframe

user29290 29 апр '10 в 10:27 2010-04-29 10:27 · Accepted Answer · 2010-04-29 10:27

Регистрация ваших кадров в качестве компонента решает как 1., так и 2.:

компоненты на фрейме блокируются, когда вы помещаете этот элемент управления фрейма в форму или другой фрейм
вы получите компонент (фактически: контроль), который вы можете создать визуально

Но: есть несколько уловов (которые можно решить, см. Ссылку на статью), из которых наиболее важной является эта:

Когда вы помещаете компоненты в свой фрейм, а затем удаляете этот фрейм как компонент в форме или фрейме Delphi, компоненты отображаются на панели структуры.

Проблема в том, что, поскольку они видны на панели структуры, их можно удалить, что приведет к нарушениям доступа.

Хитрость, чтобы решить это, чтобы не забыть "веточку".
Я получил этот ценный урок от Рэя Конопки во время DelphiLive 2009.

Поскольку урок очень ценный, я написал в нем пост, в котором подробно описан.

Основная часть - это маленький кусочек кода (более подробно в сообщении в блоге):

procedure RegisterFramesAsComponents(const Page: string; const FrameClasses: array of TFrameClass);
var
  FrameClass: TFrameClass;
begin
  for FrameClass in FrameClasses do
  begin
    RegisterComponents(Page, [FrameClass]);
    RegisterSprigType(FrameClass, TComponentSprig);
  end;
end;

Надеюсь это поможет.

--jeroen