Методы связи с внешним ключом отложены и никогда не создаются в RDBO

Question

Я играю с RoseDB::Object в наборе тестовых данных сотрудников, и по какой-то причине я не могу заставить мои отношения с внешними ключами ("отдел" и "сотрудник") работать с объектом DeptEmp. (Структура класса ниже).

Когда я пытаюсь $e->dept_emp->[0]->department, Я получил:

Can't locate object method "department" via package "My::FakeEmployees::DeptEmp"

Methods for the following relationships and foreign keys were deferred and
then never actually created in the class My::FakeEmployees::DeptEmp.

TYPE            NAME
----            ----
Foreign Key     department
Foreign Key     employee

Я уверен, что что-то неправильно настроено в структуре моего класса, но что?

СТРУКТУРА КЛАССА (некоторые классы для ясности опущены):

Я создал различные объекты, используя инструкции в руководстве по RDBO:

package My::FakeEmployees::Employee;

use strict;

use base qw(My::FakeEmployees::DB::Object);

__PACKAGE__->meta->setup(
    table => 'employees',

    columns => [
        emp_no     => { type => 'serial',  not_null => 1 },
        birth_date => { type => 'date',    not_null => 1 },
        first_name => { type => 'varchar', length   => 14, not_null => 1 },
        last_name  => { type => 'varchar', length   => 16, not_null => 1 },
        gender     => { type => 'enum',    check_in => [ 'M', 'F' ], not_null => 1 },
        hire_date  => { type => 'date',    not_null => 1 },
    ],

    primary_key_columns => ['emp_no'],
    'relationships'     => [
        'departments' => {
            'type'      => 'many to many',
            'map_class' => 'My::FakeEmployees::DeptEmp',
        },
        'dept_emp' => {
            'type' => 'one to many',
            'class' => 'My::FakeEmployees::DeptEmp',
            'column_map' => { 'emp_no' => 'emp_no' },
        },
        'dept_manager' => {
            'type' => 'one to many',
            'class' => 'My::FakeEmployees::DeptManager',
            'column_map' => { 'emp_no' => 'emp_no' },
        },
        'salaries' => {
            'type' => 'one to many',
            'class' => 'My::FakeEmployees::Salary',
            'column_map' => { 'emp_no' => 'emp_no' },
        },
        'titles' => {
            'type' => 'one to many',
            'class' => 'My::FakeEmployees::Title',
            'column_map' => { 'emp_no' => 'emp_no' },
        },
    ],
);

__PACKAGE__->meta->make_manager_class('employees');

1;

package My::FakeEmployees::DeptEmp;

use strict;

use base qw(My::FakeEmployees::DB::Object);

__PACKAGE__->meta->setup(
    table => 'dept_emp',

    columns => [
        dept_no   => { type => 'character', not_null => 1 },
        emp_no    => { type => 'integer',   not_null => 1 },
        from_date => { type => 'date' },
        to_date   => { type => 'date' },
    ],

    primary_key_columns => [ 'emp_no', 'dept_no' ],

    foreign_keys => [
        department => {
            class       => 'My::FakeEmployees::Departments',
            key_columns => { dept_no => 'dept_no' },
        },

        employee => {
            class       => 'My::FakeEmployees::Employees',
            key_columns => { emp_no => 'emp_no' },
        },
    ],
);
__PACKAGE__->meta->make_manager_class('dept_emp');


1;

package My::FakeEmployees::Department;

use strict;

use base qw(My::FakeEmployees::DB::Object);

__PACKAGE__->meta->setup(
    table => 'departments',

    columns => [
        dept_no   => { type => 'character', length => 4,  not_null => 1 },
        dept_name => { type => 'varchar',   length => 40, not_null => 1 },
    ],

    primary_key_columns => ['dept_no'],

    unique_key => ['dept_name'],

    'relationships'     => [
        'employees' => {
            'type'      => 'many to many',
            'map_class' => 'My::FakeEmployees::DeptEmp',
        },
    ],
);
__PACKAGE__->meta->make_manager_class('departments');

1;

Answer 1

Ваш внешний ключ имеет опечатку:

foreign_keys => [
    department => {
        class       => 'My::FakeEmployees::Departments',

Это должно быть "Отдел", а не "Отделы"

Answer 2

Это оказалось ошибкой в ​​моем коде. Эти строки в DeptEmp.pm:

foreign_keys => [
    department => {
        class       => 'My::FakeEmployees::Departments',
        key_columns => { dept_no => 'dept_no' },
    },

    employee => {
        class       => 'My::FakeEmployees::Employees',
        key_columns => { emp_no => 'emp_no' },
    },
],

Неправильные имена классов. Это должен быть My:: FakeEmployees::Employee и My:: FakeEmployees::Department. Единственное число, а не множественное число.