Как сделать автоматическое дифференцирование по сложным типам данных?

Question

Учитывая очень простое определение матрицы на основе вектора:

import Numeric.AD
import qualified Data.Vector as V

newtype Mat a = Mat { unMat :: V.Vector a }

scale' f = Mat . V.map (*f) . unMat
add' a b = Mat $ V.zipWith (+) (unMat a) (unMat b)
sub' a b = Mat $ V.zipWith (-) (unMat a) (unMat b)
mul' a b = Mat $ V.zipWith (*) (unMat a) (unMat b)
pow' a e = Mat $ V.map (^e) (unMat a)

sumElems' :: Num a => Mat a -> a
sumElems' = V.sum . unMat

(в демонстрационных целях... Я использую Hmatrix, но думал, что проблема была как-то)

И функция ошибки (eq3):

eq1' :: Num a => [a] -> [Mat a] -> Mat a
eq1' as φs = foldl1 add' $ zipWith scale' as φs

eq3' :: Num a => Mat a -> [a] -> [Mat a] -> a
eq3' img as φs = negate $ sumElems' (errImg `pow'` (2::Int))
  where errImg = img `sub'` (eq1' as φs)

Почему компилятор не может вывести правильные типы в этом?

diffTest :: forall a . (Fractional a, Ord a) => Mat a -> [Mat a] -> [a] -> [[a]]
diffTest m φs as0 = gradientDescent go as0
  where go xs = eq3' m xs φs

Точное сообщение об ошибке таково:

src/Stuff.hs:59:37:
    Could not deduce (a ~ Numeric.AD.Internal.Reverse.Reverse s a)
    from the context (Fractional a, Ord a)
      bound by the type signature for
                 diffTest :: (Fractional a, Ord a) =>
                             Mat a -> [Mat a] -> [a] -> [[a]]
      at src/Stuff.hs:58:13-69
    or from (reflection-1.5.1.2:Data.Reflection.Reifies
               s Numeric.AD.Internal.Reverse.Tape)
      bound by a type expected by the context:
                 reflection-1.5.1.2:Data.Reflection.Reifies
                   s Numeric.AD.Internal.Reverse.Tape =>
                 [Numeric.AD.Internal.Reverse.Reverse s a]
                 -> Numeric.AD.Internal.Reverse.Reverse s a
      at src/Stuff.hs:59:21-42
      ‘a’ is a rigid type variable bound by
          the type signature for
            diffTest :: (Fractional a, Ord a) =>
                        Mat a -> [Mat a] -> [a] -> [[a]]
          at src//Stuff.hs:58:13
    Expected type: [Numeric.AD.Internal.Reverse.Reverse s a]
                   -> Numeric.AD.Internal.Reverse.Reverse s a
      Actual type: [a] -> a
    Relevant bindings include
      go :: [a] -> a (bound at src/Stuff.hs:60:9)
      as0 :: [a] (bound at src/Stuff.hs:59:15)
      φs :: [Mat a] (bound at src/Stuff.hs:59:12)
      m :: Mat a (bound at src/Stuff.hs:59:10)
      diffTest :: Mat a -> [Mat a] -> [a] -> [[a]]
        (bound at src/Stuff.hs:59:1)
    In the first argument of ‘gradientDescent’, namely ‘go’
    In the expression: gradientDescent go as0

Answer 1

gradientDescent функция от ad имеет тип

gradientDescent :: (Traversable f, Fractional a, Ord a) =>
                   (forall s. Reifies s Tape => f (Reverse s a) -> Reverse s a) ->
                   f a -> [f a]

Его первый аргумент требует функции типа f r -> r где r является forall s. (Reverse s a), go имеет тип [a] -> a где a это тип, связанный в подписи diffTest, Эти a это то же самое, но Reverse s a не то же самое, что a,

Reverse Тип имеет экземпляры для ряда классов типов, которые могут позволить нам преобразовать a в Reverse s a или обратно. Наиболее очевидным является Fractional a => Fractional (Reverse s a) что позволило бы нам преобразовать a с в Reverse s a с realToFrac,

Для этого нам понадобится отобразить функцию a -> b через Mat a чтобы получить Mat b, Самый простой способ сделать это будет получить Functor экземпляр для Mat,

{-# LANGUAGE DeriveFunctor #-}

newtype Mat a = Mat { unMat :: V.Vector a }
    deriving Functor

Мы можем преобразовать m а также fs в любой Fractional a' => Mat a' с fmap realToFrac,

diffTest m fs as0 = gradientDescent go as0
  where go xs = eq3' (fmap realToFrac m) xs (fmap (fmap realToFrac) fs)

Но есть лучший способ скрыться в рекламном пакете. Reverse s a универсально квалифицирован по всем s но a та же a как тот, который связан в подписи типа для diffTest, Нам действительно нужна только функция a -> (forall s. Reverse s a), Эта функция auto от Mode класс, для которого Reverse s a есть экземпляр. auto имеет немного странный тип Mode t => Scalar t -> t но type Scalar (Reverse s a) = a, Специализируется на Reverseauto имеет тип

auto :: (Reifies s Tape, Num a) => a -> Reverse s a

Это позволяет нам конвертировать наши Mat a с в Mat (Reverse s a) без возни с конверсиями в и из Rational,

{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE TypeFamilies #-}

diffTest :: forall a . (Fractional a, Ord a) => Mat a -> [Mat a] -> [a] -> [[a]]
diffTest m fs as0 = gradientDescent go as0
  where
    go :: forall t. (Scalar t ~ a, Mode t) => [t] -> t
    go xs = eq3' (fmap auto m) xs (fmap (fmap auto) fs)