Vbscript список всех файлов PDF в папке и подпапках

Question

Vbscript список всех файлов PDF в папке и подпапках

Ну вот мой код, но я просто не могу отфильтровать список с помощью objFile.Extension, я уверен, что это что-то глупо

Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "C:\dev"

Set objFolder = objFSO.GetFolder(objStartFolder)
Wscript.Echo objFolder.Path

Set colFiles = objFolder.Files

For Each objFile in colFiles
If objFile.Extension = "PDF" Then
    Wscript.Echo objFile.Name
    End If
Next
Wscript.Echo

ShowSubfolders objFSO.GetFolder(objStartFolder)

Sub ShowSubFolders(Folder)
    For Each Subfolder in Folder.SubFolders
        Wscript.Echo Subfolder.Path
        Set objFolder = objFSO.GetFolder(Subfolder.Path)
        Set colFiles = objFolder.Files
        For Each objFile in colFiles
            Wscript.Echo objFile.Name
        Next
        Wscript.Echo
        ShowSubFolders Subfolder
    Next
End Sub

При запуске возвращается с ошибкой

(11, 1) Ошибка времени выполнения Microsoft VBScript: объект не поддерживает это свойство или метод: 'objFile.Extension'

15

vbscript folder subfolder directory-listing

Источник

user356993 16 ноя '10 в 23:16

7 ответов

Другие вопросы по тегам vbscript folder subfolder directory-listing

user185117 17 ноя '10 в 02:58 2010-11-17 02:58 · Answer 1 · 2010-11-17 02:58

Вы захотите использовать метод GetExtensionName для объекта FileSystemObject.

Set x = CreateObject("scripting.filesystemobject")
WScript.Echo x.GetExtensionName("foo.pdf")

В вашем примере попробуйте использовать это

For Each objFile in colFiles
    If UCase(objFSO.GetExtensionName(objFile.name)) = "PDF" Then
        Wscript.Echo objFile.Name
    End If
Next

24

Источник

user185117 17 ноя '10 в 02:58

user288747 20 ноя '11 в 07:05 2011-11-20 07:05 · Answer 2 · 2011-11-20 07:05

(Для тех, кто наткнулся на это из выбранной вами поисковой системы)

Это просто рекурсивно отслеживает папку, поэтому вам не нужно дублировать код дважды. Также логика ОП неоправданно сложна.

Wscript.Echo "begin."
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objSuperFolder = objFSO.GetFolder(WScript.Arguments(0))
Call ShowSubfolders (objSuperFolder)

Wscript.Echo "end."

WScript.Quit 0

Sub ShowSubFolders(fFolder)
    Set objFolder = objFSO.GetFolder(fFolder.Path)
    Set colFiles = objFolder.Files
    For Each objFile in colFiles
        If UCase(objFSO.GetExtensionName(objFile.name)) = "PDF" Then
            Wscript.Echo objFile.Name
        End If
    Next

    For Each Subfolder in fFolder.SubFolders
        ShowSubFolders(Subfolder)
    Next
End Sub

user2574534 11 июл '13 в 22:31 2013-07-11 22:31 · Answer 3 · 2013-07-11 22:31

Расширение файла может быть чувствительным к регистру... но код работает.

Set objFSO = CreateObject("Scripting.FileSystemObject")
  objStartFolder = "C:\Dev\"

  Set objFolder = objFSO.GetFolder(objStartFolder)
  Wscript.Echo objFolder.Path

  Set colFiles = objFolder.Files

  For Each objFile in colFiles
  strFileName = objFile.Name

  If objFSO.GetExtensionName(strFileName) = "pdf" Then
      Wscript.Echo objFile.Name
  End If

  Next
  Wscript.Echo

  ShowSubfolders objFSO.GetFolder(objStartFolder)

  Sub ShowSubFolders(Folder)
     For Each Subfolder in Folder.SubFolders
          Wscript.Echo Subfolder.Path
          Set objFolder = objFSO.GetFolder(Subfolder.Path)
          Set colFiles = objFolder.Files
          For Each objFile in colFiles
              Wscript.Echo objFile.Name
          Next
          Wscript.Echo
          ShowSubFolders Subfolder
      Next
  End Sub

user6765454 27 авг '16 в 20:31 2016-08-27 20:31 · Answer 4 · 2016-08-27 20:31

Может не помочь OP, но, надеюсь, другие могут найти это полезным:

бежать

%ComSpec% /c cd/d StartPath & dir/s/b *.pdf

используя объект оболочки

StdOut будет содержать все файлы PDF

2

Источник

user6765454 27 авг '16 в 20:31

user1238858 28 фев '12 в 21:18 2012-02-28 21:18 · Answer 5 · 2012-02-28 21:18

Set objFSO = CreateObject("Scripting.FileSystemObject")
objStartFolder = "C:\Users\NOLA BOOTHE\My Documents\operating system"

Set objFolder = objFSO.GetFolder(objStartFolder)

Set colFiles = objFolder.Files
For Each objFile in colFiles
    Wscript.Echo objFile.Name
Next

2

Источник

user1238858 28 фев '12 в 21:18

user235218 04 июн '11 в 22:23 2011-06-04 22:23 · Answer 6 · 2011-06-04 22:23

На этот URL есть хорошо документированный ответ на ваш вопрос:

http://blogs.technet.com/b/heyscriptingguy/archive/2005/02/18/how-can-i-list-the-files-in-a-folder-and-all-its-subfolders.aspx

Ответ, показанный по этому URL, довольно сложный и использует WMI (инструментарий управления Windows) для перебора файлов и папок. Но если вы много занимаетесь администрированием Windows, то стоит изучить WMI.

Я публикую это сейчас, если вам что-то нужно прямо сейчас; но я думаю, что раньше использовал подход, основанный на объектах файловой системы, и я поищу некоторый пример, и я опубликую его позже, если найду его.

Я надеюсь, что это полезно.

user2704121 21 авг '13 в 14:51 2013-08-21 14:51 · Answer 7 · 2013-08-21 14:51

Проверьте этот код:

Set objFSO = CreateObject("Scripting.FileSystemObject") 

objStartFolder = "C:\Folder1\"

Set objFolder = objFSO.GetFolder(objStartFolder)

Set colFiles = objFolder.Files

For Each objFile in colFiles 
    strFileName = objFile.Name

    If objFSO.GetExtensionName(strFileName) = "pdf" Then 
        Wscript.Echo objFile.Name 
    End If
Next

ShowSubfolders objFSO.GetFolder(objStartFolder)

Sub ShowSubFolders(Folder)

    For Each Subfolder in Folder.SubFolders 
        Set objFolder = objFSO.GetFolder(Subfolder.Path) 
        Set colFiles = objFolder.Files 
        for each Files in colFiles 
            if LCase(InStr(1,Files, ".pdf")) > 1 then Wscript.Echo Files 
        next
        ShowSubFolders Subfolder 
    Next 
End Sub