Peg.js различает отсутствующие значения и пробелы

Question

У меня есть следующий скрипт peg.js:

start = name* 

name = '** name ' var ws 'var:' vr:var ws 'len:' n:num? ws 'label:' lb:label? 'type:' ws t:type? '**\n'
  {return {NAME: vr,
           LENGTH: n, 
           LABEL:lb,
           TYPE: t
  }}

type = 'CHAR'/'NUM'    
var = $([a-zA-Z_][a-zA-Z0-9_]*)
label = p:labChar* { return p.join('')}
labChar = [^'"<>|\*\/]
ws = [\\t\\r ]
num  = n:[0-9]+ {return n.join('')}

разобрать:

** name a1 var:a1 len:9 label:The is the label for a1 type:NUM **
** name a2 var:a2 len: label:The is the label for a2 type:CHAR **
** name a3 var:a3 len:67 label: type: **

и я столкнулся с парой проблем.

Во-первых, в тексте, который я анализирую, я ожидаю определенных меток значений, таких как 'var:', 'len:', 'label:' & 'type:'. Я хотел бы использовать эти метки, поскольку я знаю, что они фиксированы, для разграничения значений.

Во-вторых, мне нужно учесть пропущенные значения.

Я иду об этом правильным путем? В настоящее время мой сценарий объединяет значение метки с типом, а затем я получаю сообщение об ошибке:

Line 1, column 64: Expected "type:" or [^'"<>|*/] but "*" found.

Кроме того, я могу сделать это с блоками текста тоже? Я попытался разобрать:

** name a1 var:a1 len:9 label:The is the label for a1 type:NUM **
** name a2 var:a2 len: label:The is the label for a2 type:CHAR **

randomly created text ()= that I would like to keep

** name b1 var:b1 len:9 label:This is the label for b1 type:NUM **
** name b2 var:b2 len: label:This is the label for b2 type:CHAR **

more text 

изменив первую строку, добавив следующее:

start = (name/random)* 

random = r:.+ (!'** name')
    {return {RANDOM: r.join('')}}

Я после окончательного результата:

[
   [{
      "NAME": "a1",
      "LENGTH": "9",
      "LABEL": "The is the label for a1",
      "TYPE": "NUM"
   },
   {
      "NAME": "a2",
      "LENGTH": null,
      "LABEL": "The is the label for a2",
      "TYPE": "CHAR"
   },
   {"RANDOM":"randomly created text ()= that I would like to keep"}]
[{
      "NAME": "b1",
      "LENGTH": "9",
      "LABEL": "This is the label for b1",
      "TYPE": "NUM"
   },
   {
      "NAME": "b2",
      "LENGTH": null,
      "LABEL": "This is the label for b2",
      "TYPE": "CHAR"
   },
   {"RANDOM":"more text "}]
] 

Answer 1

Вы будете хотеть негативного взгляда !(ws 'type:') в противном случае правило метки будет слишком жадным и будет занимать весь ввод до конца строки.

В качестве примечания вы можете использовать $() синтаксис для объединения текста элементов вместо {return n.join('')},

start = name*

name = '** name ' var ws 'var:' vr:var ws 'len:' n:num? ws 'label:' lb:label? ws 'type:' t:type? ws '**' '\n'?
  {return {NAME: vr,
           LENGTH: n, 
           LABEL:lb,
           TYPE: t
  }}

var = $([a-zA-Z_][a-zA-Z0-9_]*)

num  = $([0-9]+)

label = $((!(ws 'type:') [^'"<>|\*\/])*)

type = 'CHAR'/'NUM'

ws = [\\t\\r ]

Выход:

[
   {
      "NAME": "a1",
      "LENGTH": "9",
      "LABEL": "The is the label for a1",
      "TYPE": "NUM"
   },
   {
      "NAME": "a2",
      "LENGTH": null,
      "LABEL": "The is the label for a2",
      "TYPE": "CHAR"
   },
   {
      "NAME": "a3",
      "LENGTH": "67",
      "LABEL": "",
      "TYPE": null
   }
]

Answer 2

Наконец получил следующее для работы:

random = r: $(!('** name').)+ {return {"RANDOM": r}}

Я не уверен, что полностью понимаю синтаксис, но он работает.