Комплексная сортировка и группировка XSLT

Question

У меня XML-файл выглядел так:

<components>
       <comp>
      <ref>q7</ref>
      <partnumber>foo</partnumber>
   </comp>
   <comp>
      <ref>q1</ref>
      <partnumber>foo</partnumber>
   </comp>
   <comp>
      <ref>q6</ref>
      <partnumber>bar</partnumber>
   </comp>
   <comp>
      <ref>q3</ref>
      <partnumber>bar</partnumber>
   </comp>
</components>

И мне нужно сгруппировать по partnumber и отсортировать по ref, так что выходной файл будет выглядеть так:

q1 q7, foo
q3 q6, bar

Но я получаю этот вывод:

q3 q6, bar
q1 q7, foo

Вот мой XSL:

<!DOCTYPE xsl:stylesheet [
  <!ENTITY nl  "&#xd;&#xa;">    <!--new line CR, LF, or LF, your choice -->
]>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text"/>
    <xsl:key name='compspec' match="comp" use="partnumber" />
    <xsl:template match="/components">
        <xsl:for-each select="comp[generate-id(.)=generate-id(key('compspec',partnumber)[1])]">
            <xsl:sort select="ref"/>
            <xsl:for-each select="key('compspec',partnumber)">
                <xsl:sort select="ref"/>
                <xsl:value-of select="ref"/>
                <xsl:text> </xsl:text>
            </xsl:for-each>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="partnumber"/>
            <xsl:text>&nl;</xsl:text>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet> 

Я понимаю, почему я получаю эту последовательность, но я довольно новый для XSLT, и я не знаю, как это исправить. Что я должен исправить в своем коде? Я использую XSLT 1.0. Спасибо!

Answer 1

Мне нужно отсортировать группы с одинаковым номером детали по минимальному значению comp/ref

Чтобы сделать это в XSLT 1.0, вам нужно будет сделать два прохода:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:key name='compspec' match="comp" use="partnumber" />

<xsl:template match="/components">
    <!-- first pass -->
    <xsl:variable name="groups">
        <xsl:for-each select="comp[generate-id(.)=generate-id(key('compspec',partnumber)[1])]">
            <group name="{partnumber}">
                <xsl:for-each select="key('compspec', partnumber)">
                    <xsl:sort select="ref"/>
                    <value>
                        <xsl:value-of select="ref"/>
                    </value>
                </xsl:for-each>
            </group>
        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
    <xsl:for-each select="exsl:node-set($groups)/group">
        <xsl:sort select="value[1]"/>
        <xsl:for-each select="value">
            <xsl:value-of select="."/>
            <xsl:if test="position()!=last()">
                <xsl:text> </xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>, </xsl:text>
        <xsl:value-of select="@name"/>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet> 

Примечание:
В вашем примере ref содержит текстовые значения и в приведенном выше коде сортируется как текст. Поэтому минимальное значение comp/ref на самом деле является первым ref значение в алфавитном порядке.

Answer 2

Вы получите желаемый результат, если просто удалите эту строку:

 <xsl:sort select="partnumber"/>

в вашем первом for-each цикл, потому что вы сортируете по алфавиту partnumber (bar а также foo).