Как хранить данные и извлекать данные из файлов отображения памяти, используя CopyMemory в VBA?

Question

Как хранить данные и извлекать данные из файлов отображения памяти, используя CopyMemory в VBA?

Я пытаюсь создать распределенную вычислительную систему, которая использует файлы отображения памяти для координации работы между несколькими сетевыми ПК, все через VBA. Иными словами, я хочу, чтобы группа сетевых компьютеров одновременно работала согласованным образом над одним проектом, который можно легко разделить на несколько частей. Один компьютер занимает 13+ часов, чтобы завершить проект, что не практично для моего клиента.

Я хочу хранить информацию в файлах отображения памяти, которая поможет ПК работать над проектом скоординированным образом (т.е. не дублировать работу, избегать проблем с гонками и т. Д.). Я попытался использовать другие типы файлов для достижения этой цели, и это вызывает проблемы с гонкой файлов, или это занимает слишком много времени. Итак, как это предлагается на этом форуме, я пробую файлы отображения памяти.

Я новичок в файлах отображения памяти и распределительных вычислениях. Должно быть сделано в VBA. Насколько я знаю, я должен указать, что файл будет сохранен в каталоге в нашей сети (диск Z здесь), к которому имеют доступ все ПК. Я собрал код из разных мест:

Option Explicit

Private Const PAGE_READWRITE As Long = &H4
Private Const FILE_MAP_WRITE As Long = &H2
Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000
Private Const OPEN_ALWAYS = 4
Private Const FILE_ATTRIBUTE_NORMAL = &H80

Private Declare Function CreateFile Lib "kernel32" Alias "CreateFileA" (ByVal lpFileName As String, _
                                         ByVal dwDesiredAccess As Long, ByVal dwShareMode As Long, _
                                         ByVal lpSecurityAttributes As Long, ByVal dwCreationDisposition As Long, _
                                         ByVal dwFlagsAndAttributes As Long, ByVal hTemplateFile As Long) As Long

Private Declare Function CreateFileMapping Lib "kernel32.dll" Alias "CreateFileMappingA" ( _
     ByVal hFile As Long, _
     ByVal lpFileMappigAttributes As Long, _
     ByVal flProtect As Long, _
     ByVal dwMaximumSizeHigh As Long, _
     ByVal dwMaximumSizeLow As Long, _
     ByVal lpName As String) As Long

Private Declare Function MapViewOfFile Lib "kernel32.dll" ( _
     ByVal hFileMappingObject As Long, _
     ByVal dwDesiredAccess As Long, _
     ByVal dwFileOffsetHigh As Long, _
     ByVal dwFileOffsetLow As Long, _
     ByVal dwNumberOfBytesToMap As Long) As Long

#If VBA7 Then
Public Declare PtrSafe Sub CopyMemory Lib "kernel32" Alias _
    "RtlMoveMemory" (destination As Any, source As Any, _
    ByVal length As Long)
#Else
Public Declare Sub CopyMemory Lib "kernel32" Alias _
    "RtlMoveMemory" (destination As Any, source As Any, _
    ByVal length As Long)
    #End If

Private Declare Function UnmapViewOfFile Lib "kernel32.dll" ( _
     ByRef lpBaseAddress As Any) As Long

Private Declare Function CloseHandle Lib "kernel32.dll" ( _
     ByVal hObject As Long) As Long

Private hMMF As Long
Private pMemFile As Long

Sub IntoMemoryFileOutOfMemoryFile()

    Dim sFile As String
    Dim hFile As Long

    sFile = "Z:\path\test1.txt"

    hFile = CreateFile(sFile, GENERIC_READ Or GENERIC_WRITE, 0, 0, OPEN_ALWAYS, FILE_ATTRIBUTE_NORMAL, 0)
    hMMF = CreateFileMapping(hFile, 0, PAGE_READWRITE, 0, 1000000, "MyMemoryMappedFile")

    pMemFile = MapViewOfFile(hMMF, FILE_MAP_WRITE, 0, 0, 0)

    Dim buffer As String

    buffer = "testing1"
    CopyMemory pMemFile, ByVal buffer, 128

    hMMF = CreateFileMapping(-1, 0, PAGE_READWRITE, 0, 1000000, "MyMemoryMappedFile")
    pMemFile = MapViewOfFile(hMMF, FILE_MAP_WRITE, 0, 0, 0)

     Dim buffer2 As String

    buffer2 = String$(128, vbNullChar)

     CopyMemory ByVal buffer2, pMemFile, 128

     MsgBox buffer2 & " < - it worked?"

     UnmapViewOfFile pMemFile
     CloseHandle hMMF
End Sub

В качестве небольшого примера приведенный выше код пытается поместить строку "testing1" в файл test1.txt, затем извлечь эту строку, сохранить ее в переменной buffer2 и, наконец, отобразить эту строку через msgbox. Супер просто. Тем не менее, я понятия не имею, что я делаю.

Все наши компьютеры 64-битные, Windows 7, Office/Excel 2013.

Проблемы / вопросы:

При запуске IntoMemoryFileOutOfMemoryFile поле msgbox будет пустым
После завершения подпрограммы я открываю test1.txt и получаю: "Процесс не может получить доступ к файлу, потому что он используется другим процессом". Что говорит мне, что я не использую UnmapViewOfFile и / или CloseHandle правильно.
Я хотел бы, чтобы эти файлы памяти были постоянными, поэтому, если все компьютеры будут прерваны, я могу перезапустить процесс и выполнить пикап с того места, где я остановился.

Вот некоторые ссылки, которые я использовал, чтобы получить то, где я сейчас нахожусь:

Интересная, но не важная информация: "Проект" предназначен для клиента хедж-фонда. Я финансовый парень, ставший фундаментальным квантом. Мы ежедневно анализируем более 2000 акций и более 1250 полей данных, чтобы сделать макроэкономические сигналы / прогнозы на покупку и продажу акций, фьючерсов и опционов.

ОБНОВЛЕНИЕ: Если я изменю две строки CopyMemory, как это (передать значение pMemFile по значению) соответственно:

CopyMemory ByVal pMemFile, buffer, 128

а также...

CopyMemory buffer2, ByVal pMemFile, 128

Я получаю кучу сумасшедших символов в файле test1.txt и вылетает Excel.

8

excel vba excel-vba distributed-computing memory-mapping

Источник

user3524158 13 май '15 в 15:08

1 ответ

Решение

Другие вопросы по тегам excel vba excel-vba distributed-computing memory-mapping

user4088852 14 май '15 в 23:57 2015-05-14 23:57 · Accepted Answer · 2015-05-14 23:57

Что касается вашей первой проблемы (не рассматривал ее слишком много), это связано с тем, как вы пытаетесь передать buffer в RtlMoveMemory. Он ожидает указатель, но вы передаете ему копию BSTR. Также помните, что String в VBA - это Unicode, поэтому вы получите переплетенные нулевые символы. Я обычно использую либо байтовые массивы, либо варианты (они передаются в CSTR).

Для вашей второй проблемы файл блокируется, потому что вы никогда не отпускаете дескриптор hFile, На самом деле, как только вы передадите его CreateFileMappingA, ты можешь позвонить CloseHandle на hFile,

Для третьего вопроса вы переписываете свою ручку hMMF и указатель pMemFile когда вы делаете второй звонок. Теоретически, они должны возвращать тот же дескриптор и указатель, что и вы в том же процессе, но это на самом деле не проверяет, получили ли вы вид карты.

Что касается доступа к памяти, я бы, вероятно, рекомендовал бы обернуть все это в класс и отобразить указатель на что-то более полезное, чем вызовы RtlMoveMemory, Я адаптировал свой код, который вы связали в этом вопросе, в класс, который должен сделать его немного более безопасным, более надежным и удобным в использовании (хотя его все еще необходимо уточнять с помощью проверки ошибок):

'Class MemoryMap
Option Explicit

Private Type SafeBound
    cElements As Long
    lLbound As Long
End Type

Private Type SafeArray
    cDim As Integer
    fFeature As Integer
    cbElements As Long
    cLocks As Long
    pvData As Long
    rgsabound As SafeBound
End Type

Private Const VT_BY_REF = &H4000&
Private Const FILE_ATTRIBUTE_NORMAL = &H80
Private Const OPEN_ALWAYS = &H4
Private Const GENERIC_READ = &H80000000
Private Const GENERIC_WRITE = &H40000000
Private Const PAGE_READWRITE = &H4
Private Const FILE_MAP_WRITE = &H2
Private Const FADF_FIXEDSIZE = &H10

Private cached As SafeArray
Private buffer() As Byte
Private hFileMap As Long
Private hMM As Long
Private mapped_file As String
Private bound As Long

Public Property Get FileName() As String
    FileName = mapped_file
End Property

Public Property Get length() As Long
    length = bound
End Property

Public Sub WriteData(inVal As String, offset As Long)
    Dim temp() As Byte
    temp = StrConv(inVal, vbFromUnicode)

    Dim index As Integer
    For index = 0 To UBound(temp)
        buffer(index + offset) = temp(index)
    Next index
End Sub

Public Function ReadData(offset, length) As String
    Dim temp() As Byte
    ReDim temp(length)

    Dim index As Integer
    For index = 0 To length - 1
        temp(index) = buffer(index + offset)
    Next index

    ReadData = StrConv(temp, vbUnicode)
End Function

Public Function OpenMapView(file_path As String, size As Long, mapName As String) As Boolean
    bound = size
    mapped_file = file_path

    Dim hFile As Long
    hFile = CreateFile(file_path, GENERIC_READ Or GENERIC_WRITE, 0, 0, OPEN_ALWAYS, FILE_ATTRIBUTE_NORMAL, 0)
    hFileMap = CreateFileMapping(hFile, 0, PAGE_READWRITE, 0, size, mapName)
    CloseHandle hFile
    hMM = MapViewOfFile(hFileMap, FILE_MAP_WRITE, 0, 0, 0)

    ReDim buffer(2)
    'Cache the original SafeArray structure to allow re-mapping for garbage collection.
    If Not ReadSafeArrayInfo(buffer, cached) Then
        'Something's wrong, close our handles.
        CloseOpenHandles
        Exit Function
    End If

    Dim temp As SafeArray
    If ReadSafeArrayInfo(buffer, temp) Then
        temp.cbElements = 1
        temp.rgsabound.cElements = size
        temp.fFeature = temp.fFeature And FADF_FIXEDSIZE
        temp.pvData = hMM
        OpenMapView = SwapArrayInfo(buffer, temp)
    End If    
End Function

Private Sub Class_Terminate()
    'Point the member array back to its own data for garbage collection.
    If UBound(buffer) = 2 Then
        SwapArrayInfo buffer, cached
    End If
    SwapArrayInfo buffer, cached
    CloseOpenHandles
End Sub

Private Sub CloseOpenHandles()
    If hMM > 0 Then UnmapViewOfFile hMM
    If hFileMap > 0 Then CloseHandle hFileMap
End Sub

Private Function GetBaseAddress(vb_array As Variant) As Long
    Dim vtype As Integer
    'First 2 bytes are the VARENUM.
    CopyMemory vtype, vb_array, 2
    Dim lp As Long
    'Get the data pointer.
    CopyMemory lp, ByVal VarPtr(vb_array) + 8, 4
    'Make sure the VARENUM is a pointer.
    If (vtype And VT_BY_REF) <> 0 Then
        'Dereference it for the actual data address.
        CopyMemory lp, ByVal lp, 4
        GetBaseAddress = lp
    End If
End Function

Private Function ReadSafeArrayInfo(vb_array As Variant, com_array As SafeArray) As Boolean
    If Not IsArray(vb_array) Then Exit Function

    Dim lp As Long
    lp = GetBaseAddress(vb_array)
    If lp > 0 Then
        With com_array
            'Copy it over the passed structure
            CopyMemory .cDim, ByVal lp, 16
            'Currently doesn't support multi-dimensional arrays.
            If .cDim = 1 Then
                CopyMemory .rgsabound, ByVal lp + 16, LenB(.rgsabound)
                ReadSafeArrayInfo = True
            End If
        End With
    End If
End Function

Private Function SwapArrayInfo(vb_array As Variant, com_array As SafeArray) As Boolean
    If Not IsArray(vb_array) Then Exit Function
    Dim lp As Long
    lp = GetBaseAddress(vb_array)

    With com_array
        'Overwrite the passed array with the SafeArray structure.
        CopyMemory ByVal lp, .cDim, 16
        If .cDim = 1 Then
            CopyMemory ByVal lp + 16, .rgsabound, LenB(.rgsabound)
            SwapArrayInfo = True
        End If
    End With    
End Function

Использование это так:

Private Sub MMTest()
    Dim mm As MemoryMap

    Set mm = New MemoryMap
    If mm.OpenMapView("C:\Dev\test.txt", 1000, "TestMM") Then
        mm.WriteData "testing1", 0
        Debug.Print mm.ReadData(0, 8)
    End If

    Set mm = Nothing
End Sub

Вам также понадобятся следующие объявления где-нибудь:

Public Declare Function MapViewOfFile Lib "kernel32.dll" ( _
    ByVal hFileMappingObject As Long, _
    ByVal dwDesiredAccess As Long, _
    ByVal dwFileOffsetHigh As Long, _
    ByVal dwFileOffsetLow As Long, _
    ByVal dwNumberOfBytesToMap As Long) As Long

Public Declare Sub CopyMemory Lib "kernel32" Alias _
    "RtlMoveMemory" (Destination As Any, Source As Any, _
    ByVal length As Long)

Public Declare Function CloseHandle Lib "kernel32.dll" ( _
    ByVal hObject As Long) As Long

Public Declare Function UnmapViewOfFile Lib "kernel32.dll" ( _
    ByVal lpBaseAddress As Any) As Long

Следует помнить еще одну вещь: поскольку вы используете сетевой диск, вам нужно убедиться, что механизмы кэширования не мешают доступу к файлу. В частности, вы должны убедиться, что на всех клиентах отключено кэширование сетевых файлов. Вы также можете захотеть очистить карту памяти детерминистически, вместо того чтобы полагаться на ОС (см. FlushViewOfFile).