Lwt и Cohttp: `Фатальная ошибка: исключение Unix.Unix_error(Unix.ECONNRESET, "read", "")`

Question

У меня есть простой HTTP-сервер в Ocaml с Cohttp и Lwt. Когда я бегу wrk приложение падает примерно в 50% случаев, как только wrk отделки. Я полагаю, что сбой вызван неожиданным разрывом соединения.

Я вижу следующую ошибку на консоли:

Fatal error: exception Unix.Unix_error(Unix.ECONNRESET, "read", "")
Raised by primitive operation at file "src/unix/lwt_bytes.ml", line 130, characters 42-84
Called from file "src/unix/lwt_unix.ml", line 489, characters 13-24

Есть ли способ предотвратить это?

Мой полный исходный код:

(* server_test.ml *)
open Unix
open Lwt
open Cohttp
open Cohttp_lwt_unix
open Yojson
open Yojson.Basic.Util
open Core.Std

type create = {
username: string;
email: string;
password: string;
} [@@deriving yojson]

let insert coll doc =
    let _id = Core.Std.Uuid.to_string (Uuid.create ()) in
    let uri = Uri.make ~scheme:"http" ~host:"127.0.0.1" ~port:5984 ~path:(coll ^ "/" ^ _id) () in
    Cohttp_lwt_unix.Client.put ~body:(Cohttp_lwt_body.of_string (Yojson.Safe.to_string doc)) uri
    >|= fun (r, _) -> Code.code_of_status @@ Response.status r

let callback _conn req body =
    body |> Cohttp_lwt_body.to_string 
    >>= (fun body -> 
        let mc = Yojson.Safe.from_string body |> create_of_yojson in
        match mc with
        | Ok c -> 
            insert "users" (create_to_yojson c)
            >>= fun status -> print_endline @@ string_of_int status; 
                Server.respond_string ~status:(`Code status) ~body:(string_of_int status) ()
        | _ -> Server.respond_string ~status:`OK ~body: "Not OK" ())

let timeit _conn req body =
    let start = Unix.gettimeofday () in
    callback _conn req body 
    >>= 
    fun result ->
        let finish = Unix.gettimeofday () in
        Lwt_io.printlf "Execution time took %fms" ((finish -. start) *. 1000.0)
        >|= fun _ -> result

let server =
    Server.create ~mode:(`TCP (`Port 8000)) (Server.make timeit ())

let () = ignore (Lwt_main.run server)

Спасибо!

Answer 1

Ошибка, которую вы видите, происходит из-за непредусмотренного исключения, возникающего, когда клиент неожиданно отключается. Соответствующее исключение передается обработчику асинхронных исключений Lwt ( http://ocsigen.org/lwt/2.6.0/api/Lwt), который по умолчанию Lwt печатает обратную трассировку и выходит из программы с кодом выхода: 2,

В настоящее время ведется дискуссия по этому вопросу на трекере проблем github cohttp: https://github.com/mirage/ocaml-cohttp/issues/511

Короче говоря, если вы определяете пользовательский обработчик исключений для асинхронных /"фоновых" потоков Lwt, то вы можете перехватывать и игнорировать / регистрировать / обрабатывать клиентские ошибки. Добавьте что-то вроде следующего перед запуском вашего cohttp-сервера:

Lwt.async_exception_hook := (function
  | Unix.Unix_error (error, func, arg) ->
    Logs.warn (fun m ->
      m  "Client connection error %s: %s(%S)"
        (Unix.error_message error) func arg
    )
  | exn -> Logs.err (fun m -> m "Unhandled exception: %a" Fmt.exn exn)
);

Взято с https://github.com/mirage/ocaml-cohttp/issues/511 и с использованием logs библиотека для регистрации события: http://erratique.ch/software/logs