Рекурсивное числовое равенство в схеме

Question

Кажется, что Схема считает, что целочисленные версии и версии числа с плавающей запятой различаются при использовании равенства?, но одинаково при использовании = для их сравнения:

(equal? 2 2.0)  ; => #f
(= 2 2.0)       ; => #t

Однако, если у меня есть рекурсивная структура с некоторыми числовыми частями (или даже простым списком чисел), есть ли способ для их сравнения, который использует = для числовых сравнений?

(equal? '(2 3) '(2.0 3.0))  ; => #f
(= '(2 3) '(2.0 3.0))       ; error: contract violation

Я могу написать свою собственную проверку равенства, что-то вроде этого:

(define myequal?
  (lambda (x y)
    (cond ((and (null? x) (null? y)) #t)
          ((or (null? x) (null? y)) #f)
          ((and (pair? x) (pair? y))
           (and (myequal? (car x) (car y))
                (myequal? (cdr x) (cdr y))))
          ((or (pair? x) (pair? y)) #f)
          ((and (number? x) (number? y)) (= x y))
          ((or (number? x) (number? y)) #f)
          (else (equal? x y)))))

Но кажется, что это будет достаточно распространенной задачей, чтобы в Scheme был встроенный метод для этого.

Answer 1

В Racket вы можете построить понятие равенства, которое вы хотите с помощью equal?/recur встроенная процедура:

;; equalish? : Any Any -> Boolean
;; Like equal?, but use = for numbers (including within compound data)
(define (equalish? a b)
  (if (and (number? a) (number? b))
      (= a b)
      (equal?/recur a b equalish?)))

(equalish? '(2 3) '(2.0 3.0))
;; => #t

equal?/recur процедура обрабатывает повторяющиеся пары, структуры и т. д.

Answer 2

Схема является минималистичным языком и имеет очень мало примитивов. 2 а также 2.0 не то же самое число, потому что 2.0 может быть ниже и выше, чем 2 которая является точной суммой 2,

Если у вас есть список с номерами и вы хотите проверить, все ли совпадают с = Вы можете сделать это с помощью every из библиотеки списка SRFI-1:

;; include the library. In R5RS this is impleentation specific
;; and worst case you need to load of external file to be portable.
(load "srfi1.scm") 

(every = '(2 3) '(2.0 3.0)) ; ==> #t

В R6RS это становится проще:

#!r6rs

(import (rnrs base)
        (only (srfi :1) every))

(every = '(2 3) '(2.0 3.0)) ; ==> #t

И так как вы пометили Racket, есть вероятность, что вы можете не написать Scheme, но, возможно, #lang racket которая имеет как поддержку SRFI-1, так и собственную версию every это называется andmap:

#lang racket

(andmap = '(2 3) '(2.0 3.0)) ; ==> #t

(require srfi/1)
(every = '(2 3) '(2.0 3.0)) ; ==> #t

РЕДАКТИРОВАТЬ

Общее решение для всех древовидных структур, которые используют себя для древовидной структуры и equal? когда больше нет конкретных опций:

(define (make-equal . predicates-and-equal-procedures)
  (when (odd? (length predicates-and-equal-procedures))
    (error "make-equal needs an even number of predicate and equal function arguments"))

  (define (mequal? a b)
    (if (pair? a)
        (and (pair? b)
             (mequal? (car a) (car b))
             (mequal? (cdr a) (cdr b)))
        (let loop ((pe predicates-and-equal-procedures))
          (if (null? pe)
              (equal? a b)
              (let ((p? (car pe)))
                (if (p? a)
                    (and (p? b)
                         ((cadr pe) a b))
                    (loop (cddr pe))))))))
  mequal?)

(define list=?
  (make-equal number? =))

(list=? '(1 2 a b "test") '(1.0 2 a b "test")) ; ==> #t

(define equal-ci?
  (make-equal string? string-ci=? char? char-ci=?))

(equal-ci? '(1 2 a b "Test") '(1 2 a b "test")) ; ==> #t

(define inexact-eq-ci?
  (make-equal number? = string? string-ci=? char? char-ci=?))

(inexact-eq-ci? '(1 2 a b "test") '(1.0 2 a b "TEST")) ; ==> #t