Смешанный шаблон для определения структур с одинаковым элементом

Question

Я хочу определить количество структур, каждая из которых начинается с одного и того же члена:

struct A {
    S s; // same member
    X x; // other members
}

struct B {
    S s; // same member
    Y y; // other members
}

Что такое миксин шаблон для этого?

Answer 1

import std.array;

struct S {}
struct X {}
struct Y {}

mixin template Common() {
   S s; // same member
}

string struct_factory(string name, string[] args...) {
    return `struct ` ~ name ~ ` { 
                mixin Common;
            ` ~ args.join("\n") ~ `
            }`;
}

mixin(struct_factory("A", "X x;"));
mixin(struct_factory("B", "Y y;"));

void main() {
    A a;
    B b;
}

Или (скрыть строку-миксин):

import std.array;

struct S {}
struct X {}
struct Y {}

private string struct_factory(string name, string[] args...) {
    return `struct ` ~ name ~ ` { 
                mixin Common;
            ` ~ args.join("\n") ~ `
            }`;
}

mixin template Common() {
    S s;
}

mixin template Struct(string name, Args...) {
    mixin(struct_factory(name, [Args]));
}

mixin Struct!("A", "X x;");
mixin Struct!("B", "Y y;");


void main() {
    A a;
    B b;
}

Answer 2

mixin template Common() {
   S s; // same member
}

struct A {
   mixin Common;
   X x;
}

struct B {
   mixin Common;
   Y y;
}

См. Шаблон Mixin

Answer 3

Немного другой взгляд на ответ Дэвида:

//The actual building of the struct
mixin template PrefilledImpl(string name, string common, string individual)
{
    mixin("struct " ~ name ~ "{" ~ common ~ individual ~ "}");
}

//A sort of template currying
mixin template Prefilled(string templateName, string common)
{
    mixin("mixin template " ~ templateName ~ 
          "(string name, string individual) {mixin PrefilledImpl!(name, \""
          ~ common ~ "\", individual);}");
}

//declare the "prototype" for the struct
mixin Prefilled!("StructWithInt", q{int a;});

//declare the actual struct type
mixin StructWithInt!("MyStructA", q{double b;});


//and again for a different struct
mixin Prefilled!("StructWithLots", q{float z; char[][] ns; ulong id;});
mixin StructWithLots!("MyStructB", q{void* data;});

void main()
{
    MyStructA foo;
    foo.a = 2;
    foo.b = 4.65;

    MyStructB bar;
    bar.z = 3.2;
    //etc.....
}

К сведению, синтаксис q{} является необязательным, вместо него можно просто передать обычные строки.