Почему Groovy не видит некоторые значения в словаре?

Question

Я начал изучать Groovy, и так как я люблю учиться на практике, я написал это небольшое приложение:

def height = 1; def commands; def floors; def finished = false

def up = { height < 5 ? height++ : println("Can't go higher!") }
def down = { height > -1 ? height-- : println("Can't go lower!") }
def help = { 
    print "Commands are " 
    commands.each{key, val -> print "'$key' "}
    println() 
}
def printFloors = {
    println "Floors are "
    floors.each{key,val -> println "'$key' -> '$val'"}
    println()
}
def exit = { finished = true }
def prompt = { print floors["$height"] }

commands = [ 'u': up, 
             'up': up,
             'd': down,
             'down': down,
             'help': help,
             '': help,
             'exit': exit,
             'pf': printFloors]

floors = [ "-1": "Basement : " ,
           "0": "Ground : " ,
           "5": "Penthouse : " ]
(1..4).each{floors += ["${it}" : "Floor ${it} : " ] }

bR = new BufferedReader(new InputStreamReader(System.in))

while(!finished){
    prompt()
    def cmd = bR.readLine()
    def code = commands[cmd]
    if(code != null){
        code()
    }
}

Все отлично работает, кроме печати на том этаже, на котором вы находитесь (функция подсказки). Он печатается, если вы находитесь в подвале, на первом этаже или в пентхаусе, но не берет "Этаж i: " и вместо этого печатает ноль:/ Когда я печатаю "pf" для печати словаря этажей, значения есть... Любые идеи? Спасибо

Answer 1

Вы добавляете GString экземпляры в качестве ключей на вашей карте, а затем поиск их с помощью String экземпляров.

Они не одинаковы (несмотря на то, что они выглядят одинаково - см. Раздел "GStrings - это не строки" на этой странице)

Попробуйте изменить:

(1..4).each{floors += ["${it}" : "Floor ${it} : " ] }

в

(1..4).each{floors += [ ("${it}".toString()): "Floor ${it} : " ] }