Списки церквей в Хаскеле

Question

Мне пришлось реализовать функцию карты haskell для работы со списками церквей, которые определены следующим образом:

type Churchlist t u = (t->u->u)->u->u

В лямбда-исчислении списки кодируются следующим образом:

[] := λc. λn. n
[1,2,3] := λc. λn. c 1 (c 2 (c 3 n))

Пример решения этого упражнения:

mapChurch :: (t->s) -> (Churchlist t u) -> (Churchlist s u)
mapChurch f l = \c n -> l (c.f) n

Я понятия не имею, как работает это решение, и я не знаю, как создать такую ​​функцию. Я уже имел опыт работы с лямбда-исчислением и церковными цифрами, но это упражнение стало для меня большой головной болью, и я должен быть в состоянии понять и решить такие проблемы для моего экзамена на следующей неделе. Может ли кто-нибудь дать мне хороший источник, где я мог бы научиться решать такие проблемы, или дать мне небольшое руководство о том, как это работает?

Answer 1

Все структуры данных лямбда-исчисления - это, в общем-то, функции, потому что это все, что есть в лямбда-исчислении. Это означает, что представление для логического значения, кортежа, списка, числа или чего-либо еще должно быть некоторой функцией, которая представляет активное поведение этой вещи.

Для списков это "сгиб". Неизменяемые односвязные списки обычно определяются List a = Cons a (List a) | NilЭто означает, что единственный способ создать список Nil или же Cons anElement anotherList, Если вы напишите это в стиле LISP, где c является Cons а также n является Nilзатем список [1,2,3] выглядит так:

(c 1 (c 2 (c 3 n)))

Когда вы выполняете сгиб по списку, вы просто предоставляете свой собственный "Cons" а также "Nil"заменить список из них. В Haskell библиотечная функция для этого foldr

foldr :: (a -> b -> b) -> b -> [a] -> b

Выглядит знакомо? Вынуть [a] и у вас точно такой же тип, как Churchlist a b, Как я уже сказал, церковное кодирование представляет списки как их функцию свертывания.

---

Таким образом, пример определяет map, Обратите внимание, как l используется как функция: в конце концов, это функция, которая сворачивает некоторый список. \c n -> l (c.f) n в основном говорит "заменить каждый c с c . f и каждый n с n".

(c 1 (c 2 (c 3 n)))
-- replace `c` with `(c . f)`, and `n` with `n`
((c . f) 1 ((c . f) 2) ((c . f) 3 n)))
-- simplify `(foo . bar) baz` to `foo (bar baz)`
(c (f 1) (c (f 2) (c (f 3) n))

Теперь должно быть очевидно, что это действительно функция отображения, потому что она выглядит так же, как оригинал, за исключением 1 превратился в (f 1), 2 в (f 2), а также 3 в (f 3),

Answer 2

Итак, начнем с кодирования двух конструкторов списка, используя ваш пример в качестве ссылки:

[] := λc. λn. n
[1,2,3] := λc. λn. c 1 (c 2 (c 3 n))

[] это конец конструктора списка, и мы можем поднять это прямо из примера. [] уже имеет значение в haskell, поэтому давайте назовем наш nil:

nil = \c n -> n

Другой необходимый нам конструктор берет элемент и существующий список и создает новый список. Канонически это называется consс определением:

cons x xs = \c n -> c x (xs c n)

Мы можем проверить, что это согласуется с примером выше, так как

cons 1 (cons 2 (cons 3 nil))) =
cons 1 (cons 2 (cons 3 (\c n -> n)) = 
cons 1 (cons 2 (\c n -> c 3 ((\c' n' -> n') c n))) =
cons 1 (cons 2 (\c n -> c 3 n)) =
cons 1 (\c n -> c 2 ((\c' n' -> c' 3 n') c n) ) =
cons 1 (\c n -> c 2 (c 3 n)) =
\c n -> c 1 ((\c' n' -> c' 2 (c' 3 n')) c n) =
\c n -> c 1 (c 2 (c 3 n)) =

Теперь рассмотрим назначение функции map - применить данную функцию к каждому элементу списка. Итак, давайте посмотрим, как это работает для каждого из конструкторов.

nil не имеет элементов, поэтому mapChurch f nil должно быть просто nil:

mapChurch f nil
= \c n -> nil (c.f) n
= \c n -> (\c' n' -> n') (c.f) n
= \c n -> n
= nil

cons имеет элемент и остаток списка, так что для mapChurch f чтобы правильно работать, оно должно применяться f к элементу и mapChurch f до конца списка. То есть, mapChurch f (cons x xs) должен быть таким же, как cons (f x) (mapChurch f xs),

mapChurch f (cons x xs)
= \c n -> (cons x xs) (c.f) n
= \c n -> (\c' n' -> c' x (xs c' n')) (c.f) n
= \c n -> (c.f) x (xs (c.f) n)
-- (c.f) x = c (f x) by definition of (.)
= \c n -> c (f x) (xs (c.f) n)
= \c n -> c (f x) ((\c' n' -> xs (c'.f) n') c n)
= \c n -> c (f x) ((mapChurch f xs) c n)
= cons (f x) (mapChurch f xs)

Так как все списки сделаны из этих двух конструкторов, и mapChurch работает на них обоих, как и ожидалось, mapChurch должен работать как положено во всех списках.

Answer 3

Ну, мы можем прокомментировать тип Churchlist таким образом, чтобы прояснить это:

-- Tell me...
type Churchlist t u = (t -> u -> u) -- ...how to handle a pair
                    -> u            -- ...and how to handle an empty list
                    -> u            -- ...and then I'll transform a list into 
                                    -- the type you want

Обратите внимание, что это тесно связано с foldr функция:

foldr :: (t -> u -> u) -> u -> [t] -> u
foldr k z [] = z
foldr k z (x:xs) = k x (foldr k z xs)

foldr это очень общая функция, которая может реализовывать все виды других функций списка. Тривиальный пример, который поможет вам реализовать копию списка с foldr:

copyList :: [t] -> [t]
copyList xs = foldr (:) [] xs

Используя тип комментария выше, foldr (:) [] означает это: "если вы видите пустой список, возвращайте пустой список, и если вы видите, пара возвращает head:tailResult".

С помощью ChurchlistВы можете легко написать аналог следующим образом:

-- Note that the definitions of nil and cons mirror the two foldr equations!
nil :: Churchlist t u
nil = \k z -> z

cons :: t -> Churchlist t u -> Churchlist t u
cons x xs = \k z -> k x (xs k z)  

copyChurchlist :: ChurchList t u -> Churchlist t u
copyChurchlist xs = xs cons nil

Теперь, чтобы реализовать mapнужно просто заменить cons с подходящей функцией, например:

map :: (a -> b) -> [a] -> [b]
map f xs = foldr (\x xs' -> f x:xs') [] xs

Сопоставление похоже на копирование списка, за исключением того, что вместо простого дословного копирования элементов вы применяете f каждому из них.

Изучите все это внимательно, и вы сможете написать mapChurchlist :: (t -> t') -> Churchlist t u -> Churchlist t' u самостоятельно.

Дополнительное упражнение (простое): напишите эти функции списка с точки зрения foldrи напишите аналоги для Churchlist:

filter :: (a -> Bool) -> [a] -> [a]
append :: [a] -> [a] -> [a]

-- Return first element of list that satisfies predicate, or Nothing
find :: (a -> Bool) -> [a] -> Maybe a

Если вам хочется заняться чем-то сложнее, попробуйте написать tail за Churchlist, (Начните с написания tail за [a] с помощью foldr.)