Обращаясь к цепочке хеш-ключей в хеше Perl

Question

У меня есть хэш хэшей, хранящий данные вроде

our %deviceSettings = (
  BB => {
          EUTRA => {
            DL => { CPC => "NORM", PLCI => { CID => 88 }, ULCPc => "NORM" },
            UL => {
                    REFSig  => { DSSHift => 2, GRPHopping => 1, SEQHopping => 1 },
                    SOFFset => 0,
                  },
          },
        },
  ...
);

Я могу пройтись по структуре и найти конкретный ключ, скажем, CIDи получить его значение и сохранить "путь" в массиве ('BB', 'EUTRA', 'DL', 'PLCI'),

Я также могу явно установить значение, как это

$deviceSettings_ref->{BB}{EUTRA}{DL}{PLCI}{CID} = 99

Но я хочу знать, как программно установить значение, используя обнаруженный путь.

Answer 1

Вы можете пройтись по хешу, используя заполнитель $hashref:

my $hashref = \%deviceSettings;

$hashref = $hashref->{$_} for qw(BB EUTRA DL PLCI);
$hashref->{CID} = 'My New Path';

use Data::Dump;
dd \%deviceSettings;

Выходы:

{
  BB => {
          EUTRA => {
            DL => { CPC => "NORM", PLCI => { CID => "My New Path" }, ULCPc => "NORM" },
            UL => {
                    REFSig  => { DSSHift => 2, GRPHopping => 1, SEQHopping => 1 },
                    SOFFset => 0,
                  },
          },
        },
}

Answer 2

Data::Diver - это модуль для доступа к вложенным структурам с использованием путей.

use Data::Diver 'DiveVal';

my $device_settings_rf = {};
my @path = ( 'BB', 'EUTRA', 'DL', 'PLCI', 'CID' );
DiveVal( $device_settings_rf, @path ) = 99;