GetStrValue возвращает пустую строку в редакторе пользовательских свойств

Question

Я хочу написать собственный редактор свойств для моего пользовательского компонента. У меня есть объявление компонента, как показано ниже:

type
   TEJsonQuery = class(TComponent)
   private
      FSql: TStrings;

      procedure SetSQL(const Value: TStrings);
      { Private declarations }
   protected
      { Protected declarations }
   public
      constructor Create(AOwner: TComponent); override;
      destructor Destroy; override;
      { Public declarations }
   published
      property SQL: TStrings read FSql write SetSQL;
      { Published declarations }
   end;

constructor TEJsonQuery.Create;
begin
   inherited Create(AOwner);
   FSql := TStringList.Create;
end;

procedure TEJsonQuery.SetSQL(const Value: TStrings);
begin
   if SQL.Text <> Value.Text then
   begin
      //Close;
      SQL.BeginUpdate;
      try
         SQL.Assign(Value);
      finally
         SQL.EndUpdate;
      end;
   end;
end;

destructor TEJsonQuery.Destroy;
begin
   inherited Destroy;
   FSql.Free;
end;

И объявление редактора свойств, как показано ниже:

type
   TQuerySQLProperty = class(TStringProperty)
   public
      function GetAttributes: TPropertyAttributes; override;
      procedure Edit; override;
   end;

   Tfrm_JsonQuerySQL = class(TForm)
      btn_JsonQuerySQL: TButton;
      mem_SQL: TMemo;
    btn_OK: TButton;
    btn_Cancel: TButton;
   private
      { Private declarations }
   public
      { Public declarations }
   end;

var
   frm_JsonQuerySQL: Tfrm_JsonQuerySQL;

procedure Register;

implementation

{$R *.dfm}

procedure Register;
begin
   RegisterComponents('MyComponents', [TEJsonQuery]);
   RegisterPropertyEditor(TypeInfo(TStrings), TEJsonQuery, 'SQL', TQuerySQLProperty);
end;

procedure TQuerySqlProperty.Edit;
begin
   frm_Ekol_JsonQuerySQL := Tfrm_Ekol_JsonQuerySQL.Create(Application);
   try
      Assert(False, '"' + GetStrValue + '"');
      frm_Ekol_JsonQuerySQL.mem_SQL.Lines.Text := GetStrValue;
      // show the dialog box
      if frm_Ekol_JsonQuerySQL.ShowModal = mrOK then
      begin
         SetStrValue(frm_Ekol_JsonQuerySQL.mem_SQL.Lines.Text);
      end;
   finally
      frm_Ekol_JsonQuerySQL.Free;
   end;
end;

function TQuerySQLProperty.GetAttributes: TPropertyAttributes;
begin
   // editor, sorted list, multiple selection
   // Result := [paDialog, paMultiSelect, paValueList, paSortList];
   Result := [paDialog];
end;

Редактор свойств открывается, если Assert(False, '"' + GetStrValue + '"'); комментируется пустой запиской, потому что GetStrValue возвращает пустую строку.

Answer 1

Свойство SQL является свойством TStrings, а не строковым свойством, и GetStrValue работает только со строковыми свойствами, и, если выбрано более одного компонента, он возвращает значение GetComponent(0). GetStrValue - это виртуальное свойство, поэтому вы можете реализовать свое собственное.

Вот что я имею в виду:

type
  TQuerySqlProperty = ...
  public
    function GetStrValue : string; override;
    ...
  end;
  ...

function TQuerySqlProperty.GetStrValue : string;
begin
  if GetComponent(0) is TEJsonQuery then
  begin
    Result := (GetComponent(0) as TEJsonQuery ).SQL.Text;
  end
  else
  begin
    Result := inherited;
  end;
end;