Вызвать функцию ColdFusion с помощью AJAX

Мне нужно вызвать функцию ColdFusion (присутствует в файле.cfm), когда пользователь нажимает на ссылку. И я хотел бы сделать это с помощью jQuery. У меня есть фрагмент JQuery, который выглядит как

<script type="text/javascript">
$(document).ready(function(){
       $("td.ViewLink a").click(function(event){
         event.preventDefault();

)}

Я новичок как в jQuery, так и в AJAX, поэтому я могу показаться наивным здесь. Должен ли я использовать AJAX для вызова функции ColdFusion? Что-то вроде запроса на выполнение определенной функции на сервере.

Любая помощь в этом отношении приветствуется.

Приветствия.

Источник

6 ответов

Решение

Если у вас есть несколько функций в вашем cfm(даже если у вас их нет), поместите их в cfc. Затем вы можете использовать следующий шаблон URL для вызова определенного метода.

CFC по имени myEntityWS.cfc

<cfcomponent>
  <cffunction name="updateDescription" access="remote" returntype="string">
    <cfargument name="value" type="string" required="yes">
    <cftry>
      your code here
    <cfcatch>
      <cfoutput>
        #cfcatch.Detail#<br />
        #cfcatch.Message#<br />
        #cfcatch.tagcontext[1].line#:#cfcatch.tagcontext[1].template#
      </cfoutput>
    </cfcatch>
    </cftry>
  </cffunction>
</cfcomponent>

Javascript

$.get('myEntityWS.cfc?method=updateDescription&value=someValue');
Источник

Вы не можете сделать именно то, что вы пытаетесь в своем примере кода. У вас есть несколько вариантов, хотя.

Метод 1: Удаленно доступный объект

Переместите свои функции в CFC и получите к ним доступ через URL-адрес CFC. Этот метод доступа требует, чтобы функция использовала атрибут разрешения access='remote' - если установлено значение public (по умолчанию) или private, (или package, или любые уровни роли и т. д.), то при попытке удаленного доступа к нему вы получите ошибку метода not found.

Делая это, вы создаете веб-сервис SOAP и используете его через AJAX. Вы делаете это, используя следующий формат в вашем запросе jQuery:

http://domain.com/path/to/your.cfc?method=functionName&argument1=arg1Val&foo=bar&...

Если у вас есть ColdFusion 8, вы также можете указать returnFormat='format' Аргумент url, который на лету преобразует любые собственные объекты данных ColdFusion, которые вы возвращаете, в запрошенный формат. Он поддерживает JSON, XML и WDDX.

foo.cfc

<cfcomponent output="false">
  <cffunction name="foobar" output="false" access="remote" hint="...">
    <cfargument name="arg1" type="string" required="true" />
    ...
    <cfreturn someVar />
  </cffunction>
</cfcomponent>

Доступ по URL:

http://domain.com/path/to/foo.cfc?method=foobar&arg1=some%20value&returnFormat=JSON



Способ 2: удаленный прокси-объект

Негативная сторона подхода № 1 заключается в том, что при создании экземпляров CFC наблюдается незначительное снижение эффективности, поэтому, если этот конкретный метод AJAX будет выполняться очень часто, и / или ваш CFC будет содержать несколько методов или длиннее, чем пара сотен строк Вы не хотите создавать его снова и снова для каждого запроса. Вместо этого вы захотите взглянуть на шаблон удаленного прокси, где вы кэшируете CFC, который реализует функциональность в области приложения, и имеете отдельный CFC "удаленный прокси", который намного легче и просто действует как прокси (следовательно, имя) между запросом http и кэшированным CFC.

В этом шаблоне ваш бизнес-объект (тот, у которого есть функция, выполняющая реальную работу) может иметь access=public (или пакет и т. д.), если прокси имеет доступ к нему. Сам прокси должен иметь access=remote, хоть.

proxy.cfc

<cfcomponent output="false">
  <cffunction name="foobar" output="false" access="remote" hint="...">
    <cfargument name="arg1" type="string" required="true" />
    <!--- Application.foo is an instantiated object of foo.cfc --->
    <cfreturn Application.foo.foobar(argumentCollection=arguments) />
  </cffunction>
</cfcomponent>

Доступ по URL:

http://domain.com/path/to/proxy.cfc?method=foobar&arg1=some%20value&returnFormat=JSON



Способ 3: сделай сам

Наконец, вы можете вручную реализовать вызов функции и вернуться в шаблон CFM. Этот метод не включает (незначительное) снижение производительности при написании CFC, но будет более типичным для вас и дополнительными потенциальными точками отказа. Для этого включите ваши функции в шаблон CFM и обработайте выходной поток только как поток текста, который будет возвращен браузеру.

Вы должны быть осторожны, чтобы управлять пробелами в возвращаемом значении (используйте output=false на определения функций, рассмотреть вопрос об использовании <cfsetting enableCFOutputOnly='true'и просто будьте осторожны с расстоянием в целом). Если ваш запрос jQuery ожидает возвращения JSON, вам нужно его сериализовать. (Если вам нужно сериализовать данные в JSON в ColdFusion 6 или 7, я рекомендую JSONUtil)

При таком подходе вы указываете свой запрос AJAX на файл.cfm с параметрами URL, а затем вам нужно написать код, который принимает эти параметры URL и передает их в функцию, а затем отображает (по существу, возвращает в запрос AJAX) результат функции.

foo.cfm

<cfsetting enableCFOutputOnly="true">
<cfparam name="arg1" default="defaultVal"/>

<cffunction name="foobar" output="false" access="remote" hint="...">
  <cfargument name="arg1" type="string" required="true" />
  ...
  <cfreturn someVar />
</cffunction>

<cfset variables.result = foobar(url.arg1) />
<cfoutput>#serializeJSON(variables.result)#</cfoutput>
Источник

Только что увидел этот пост. Я использую cfc и jquery ajax для отображения набора рассчитанных значений. Мой CFC имеет следующее:

<cfcomponent output="true">
<cfscript>
    this.init();
</cfscript>
     <cffunction name="init" access="public" returntype="any">
       <cfset variables.dsn = application.dsn>
        <cfreturn variables.dsn> 
     </cffunction>
     <cffunction name="getFinanceTerms" access="remote" output="true" returntype="void">
         <cfargument name="sales_price" type="numeric" required="yes">
         <cfargument name="interestRate" type="numeric" required="yes">
           <!--- some calculations here --->
         #arguments.salesPrice# <!--- just to have something displayed --->
         <cfreturn>
     </cffunction>
 </cfcomponent>

Я использую JQuery.ajax:

  $.ajax({
      type:"POST",
      url:"financeTerms.cfc?method=getFinanceTerms",
      data: "sales_price=55000&interestRate=5.99",
      cache:false,
      success: function(msg) {
      $("#someDiv").html(msg);
      }
  });

Возможно, это будет полезно кому-то еще...

Источник

Вам не обязательно использовать "AJAX" (в частности, часть XML), но вы можете использовать вызов удаленного сервера:

$.get('/execute-function.cfm?func=whatever', function (result) { $('#result').html(result); });

Реально зависит от того, что вам нужно сделать с результатом. Приведенный выше код поместит результат HTML в div на вашей странице:

<div id="result"></div>

Вы можете использовать асинхронный вызов и анализировать XML, но я обнаружил, что мне это тоже редко нужно.

Источник

Вы можете попробовать <cfajaxproxy> тег в CF8, если хотите.

Источник

Использование переменной ColdFusion в JavaScript очень полезно! Обязательно используйте

<cfoutput> var #toScript(ColdFusionVAR, 'javascriptVar')# </cfoutput>

Теперь вы можете ссылаться на вашу переменную как javaScriptVar используя CFAJAXPROXY

Не забудьте включить это в свой шаблон

<head> 
<cfajaxproxy cfc="cfc.yourclassname" jsclassname="jsCFCclassName">
</head>

Использование вашего класса на стороне JavaScript.

Вы бы нам так понравились.

var JS_CFC_Obj;

JS_CFC_Obj = new jsCFCclassName()

Теперь вы можете вызывать функции внутри этого cfc.

jsCFCclassName.functionName(javascript var);
Источник
Другие вопросы по тегам